0

複数の null 許容文字列フィールドを持つテーブルがあります。

レポートのために、それらをすべてのフィールドをスペースで区切った単一の文字列に結合したいと思います。右側をトリミングする必要があります。

テストデータ：

DECLARE
  @test 
TABLE
(
    f1 NVARCHAR(100)
  , f2 NVARCHAR(100)
  , f3 NVARCHAR(100)
)

INSERT INTO @test 
-- NULL values must be skipped
      SELECT NULL       , NULL , NULL
UNION SELECT NULL       , NULL , 'foo'
UNION SELECT NULL       , 'foo', NULL
UNION SELECT 'foo'      , NULL , NULL
UNION SELECT NULL       , 'foo', 'bar'
UNION SELECT 'foo'      , 'bar', NULL
UNION SELECT 'foo'      , NULL , 'bar'
UNION SELECT 'foo'      , 'bar', 'baz'
-- Empty string values must be skipped
UNION SELECT 'foo'      , ''   , 'bar'
UNION SELECT ''         , ''   , 'baz' 
-- Spaces in values must be kept
UNION SELECT 'foo   bar', ''   , 'baz'
-- The table should not contain values with surrounding space
-- So this case is not important
UNION SELECT ' foo '    , ' '  , 'baz '

期待される結果:

''
'foo'
'foo'
'foo'
'foo bar'
'foo bar'
'foo bar'
'foo bar baz'
'foo bar'
'baz'
'foo   bar baz'
'foo  baz'
' foo   baz' -- This is optional

私の現在のコード: 

SELECT
  RTRIM(
    CASE WHEN ISNULL(f1, '') = '' THEN '' ELSE f1 + ' ' END
  + CASE WHEN ISNULL(f2, '') = '' THEN '' ELSE f2 + ' ' END
  + CASE WHEN ISNULL(f3, '') = '' THEN '' ELSE f3 + ' ' END
  )
FROM
  @test

これは機能しますが、これを達成するためのより冗長な方法があるかどうか疑問に思っていましたか?

4

3 に答える 3

1

SQL Server 2012 には、CONCAT 関数があります。次のものも使用できます。

SELECT
  RTRIM(CONCAT(  
      NULLIF(f1, '') + ' '
    , NULLIF(f2, '') + ' '
    , NULLIF(f3, '') + ' '
  ))
FROM
  @test
于 2014-06-08T14:27:55.210 に答える