0

私は VBS スクリプトの初心者です。以下のスクリプトの 54 行目、文字 5 で上記のエラーが発生しています。このエラーは、「オブジェクトはこのプロパティまたはメソッドをサポートしていません: 'MimeMapArray'」と表示されます。

そして、それが参照している行は次のとおりです: MimeMapArray(i) = CreateObject("MimeMap")

私が間違っていることを教えてもらえますか？これがスクリプト全体です。注: この VBS ファイルをダブルクリックして、XP OS でこれを実行しようとしています。

' This script adds the necessary Windows Presentation Foundation MIME types 
' to an IIS Server.
' To use this script, just double-click or execute it from a command line.
' Running this script multiple times results in multiple entries in the IIS MimeMap.
' Set the MIME types to be added
Dim MimeMapObj
Dim MimeMapArray
Dim WshShell
Dim oExec
Const ADS_PROPERTY_UPDATE = 2

Dim MimeTypesToAddArray
MimeTypesToAddArray = Array(".manifest", "application/manifest", ".xaml", _
    "application/xaml+xml", ".application", "application/x-ms-application", _
    ".deploy", "application/octet-stream", ".xbap", "application/x-ms-xbap", _
    ".xps", "application/vnd.ms-xpsdocument")

' Get the mimemap object 
Set MimeMapObj = GetObject("IIS://LocalHost/MimeMap")

' Call AddMimeType for every pair of extension/MIME type
For counter = 0 to UBound(MimeTypesToAddArray) Step 2
    AddMimeType MimeTypesToAddArray(counter), MimeTypesToAddArray(counter+1)
Next

' Create a Shell object
Set WshShell = CreateObject("WScript.Shell")

' Stop and Start the IIS Service
Set oExec = WshShell.Exec("net stop w3svc")
Do While oExec.Status = 0
    WScript.Sleep 100
Loop

Set oExec = WshShell.Exec("net start w3svc")
Do While oExec.Status = 0
    WScript.Sleep 100
Loop

Set oExec = Nothing

' Report status to user
WScript.Echo "Windows Presentation Foundation MIME types have been registered."

' AddMimeType Sub
Sub AddMimeType(ByVal Ext, ByVal MType)

    ' Get the mappings from the MimeMap property. 
    MimeMapArray = MimeMapObj.GetEx("MimeMap")

    ' Add a new mapping. 
    i = UBound(MimeMapArray) + 1
    ReDim Preserve MimeMapArray(i)
    MimeMapArray(i) = CreateObject("MimeMap")
    MimeMapArray(i).Extension = Ext
    MimeMapArray(i).MimeType = MType
    MimeMapObj.PutEx ADS_PROPERTY_UPDATE, "MimeMap", MimeMapArray
    MimeMapObj.SetInfo()

End Sub
4

1 に答える 1

2

私が最初に提案できることは、cscriptを使用して実行することです。メッセージボックスのように消えない情報をさらに得ることができます。

  1. コマンドプロンプトを開きます（開始、実行、CMDと入力します）。
  2. スクリプトがある場所に移動し、次のように入力します。

cscript scriptname.vbs

...ここで、scriptname.vbsはスクリプトの名前です。

次に、createobject行の前にある「セット」が欠落しているように見えます。参考までにこちらをご覧ください。

その行は次のようになります。

set MimeMapArray(i) = CreateObject("MimeMap")
于 2010-03-15T03:01:27.313 に答える