4

RTTIを使用して、イベントハンドラーが既に設定されている可能性のあるコントロールにイベントハンドラーを追加しようとしています。コードは次のようになります。

var
  prop: TRttiProperty;
  val: TValue;
begin
  prop := FContext.GetType(MyControl.ClassInfo).GetProperty('OnChange');
  val := prop.GetValue(MyControl);
  FOldOnChange := val.AsType<TNotifyEvent>;
  prop.SetValue(MyControl, TValue.From<TNotifyEvent>(self.MyOnChange));
end;

MyOnChangeでこれを実行できるように、これが必要です。

begin
  if assigned(FOldOnChange) then
    FOldOnChange(Sender);
  //additional code here
end;

残念ながら、コンパイラはこの行を気に入らないようですFOldOnChange := val.AsType<TNotifyEvent>;。それは言う

E2010互換性のないタイプ：'プロシージャ、型指定されていないポインタ、または型指定されていないパラメータ'および' TNotifyEvent '

それがなぜなのか、それを修正する方法を知っている人はいますか？それは私には正しく見えます...

4

2 に答える 2

9

FOldOnChangeはメソッドポインタ型AsType<TNotifyEvent>ですが、 はメソッドです。コンパイラは、メソッドをメソッド ポインターに割り当てようとしていると見なします。解決策は、メソッド呼び出しに追加()して強制し、メソッドの戻り値を に割り当てる値として使用することFOldOnChangeです。

完全な例を次に示します。

uses SysUtils, Rtti;

type
  TEv = procedure(Sender: TObject) of object;

  TObj = class
  private
    FEv: TEv;
  public
    property Ev: TEv read FEv write FEv;
    class procedure Meth(Sender: TObject);
  end;

class procedure TObj.Meth(Sender: TObject);
begin
end;

procedure P;
var
  ctx: TRttiContext;
  t: TRttiType;
  p: TRttiProperty;
  v: TValue;
  o: TObj;
  e: TEv;
begin
  t := ctx.GetType(TObj);
  p := t.GetProperty('Ev');
  o := TObj.Create;
  try
    // Set value explicitly
    o.Ev := TObj.Meth;
    // Get value via RTTI
    v := p.GetValue(o);
    //e := v.AsType<TEv>; // doesn't work
    e := v.AsType<TEv>(); // works
  finally
    o.Free;
  end;
end;

begin
  try
    P;
  except
    on e: Exception do
      Writeln(e.Message);
  end;
end.
于 2010-03-11T10:14:17.830 に答える
1

2010 年に導入された新しい RTTI は、基本的には古い TypInfo RTTI の高度なラッパーです (今のところ)。TypInfo では、イベント ハンドラは TMethod レコードによって表されます。これを試してください（テストされていません）：

var 
  prop: TRttiProperty;
  val: TValue;
  evt: TNotifyEvent;
begin
  prop := FContext.GetType(MyControl.ClassInfo).GetProperty('OnChange');
  val := prop.GetValue(MyControl);
  TMethod(FOldOnChange) := val.AsType<TMethod>;
  evt := Self.MyOnChange;
  prop.SetValue(MyControl, TValue.From<TMethod>(TMethod(evt));
end;
于 2010-03-10T20:24:31.077 に答える