3

Common Lisp で、他の Lisp ファイルを動的に作成するプログラムを作成しようとしています。Common Lisp のprint関数は、この目的に非常に役立つようです。残念ながら、この関数はデータを 1 行で出力します。例（標準出力に出力するだけ）：

(print '(let ((a 1) (b 2) (c 3)) (+ a b c)))
>> (let ((a 1) (b 2) (c 3)) (+ a b c))

生成された Lisp ファイルは人間が読める必要があるため、空白を最小限に抑えるべきではありません。pprint関数が私の問題の解決策であるようです。pprint*pretty-print*が true に設定されているため、関数は複数行に出力する必要があります。言い換えると：

(pprint '(let ((a 1) (b 2) (c 3)) (+ a b c)))
>>  (let ((a 1)
>>        (b 2)
>>        (c 3))
>>    (+ a b c))

ただし、Allegro CL では、pprint は print と同じように動作するようです。出力は 1 行のみです。関数に s 式を「きれいな」方法で出力させる方法はありますか? 関数が正しく出力される前に設定する必要がある他のグローバルはありますか? 私が探している代替関数/マクロはありますか? 助けてくれてありがとう！

4

1 に答える 1

3

pretty プリンターは、単なる *print-pretty* 以上のものによって制御されます。たとえば、 SBCL (SLIME の下) での *print-right-margin*との相互作用を見てください:

CL-USER> (pprint '(let ((a 1) (b 2) (c 3)) (+ a b c)))

(LET ((A 1) (B 2) (C 3))
  (+ A B C))
; No value
CL-USER> (let ((*print-right-margin* 10))
           (pprint '(let ((a 1) (b 2) (c 3)) (+ a b c))))

(LET ((A
       1)
      (B
       2)
      (C
       3))
  (+ A B
     C))
; No value
CL-USER> (let ((*print-right-margin* 20))
           (pprint '(let ((a 1) (b 2) (c 3)) (+ a b c))))

(LET ((A 1)
      (B 2)
      (C 3))
  (+ A B C))
; No value

その変数を設定するだけで満足のいく結果が得られるかもしれませんが、一般的には22.2 The Lisp Pretty Printerを見たいと思うでしょう。きれいな印刷関数には、オプションの改行などのための多くの場所があり、それらが置かれる場所は多くのもの (*print-right-margin* や *print-miser-width* など) に依存します。プリティ プリンタを使用して Lisp ソース コードをフォーマットする例が 22.2.2 プリティ プリンタの使用例 にあります。すべてを引用するには多すぎますが、次のきれいな印刷コードがコンテキストに応じてこれらすべての出力を生成する方法を示しています。

(defun simple-pprint-defun (*standard-output* list)
  (pprint-logical-block (*standard-output* list :prefix "(" :suffix ")")
    (write (first list))
    (write-char #\Space)
    (pprint-newline :miser)
    (pprint-indent :current 0)
    (write (second list))
    (write-char #\Space)
    (pprint-newline :fill)
    (write (third list))
    (pprint-indent :block 1)
    (write-char #\Space)
    (pprint-newline :linear)
    (write (fourth list))))

 (DEFUN PROD (X Y) 
   (* X Y))

(DEFUN PROD
       (X Y)
  (* X Y))

 (DEFUN
  PROD
  (X Y)
  (* X Y))

 ;;; (DEFUN PROD
 ;;;        (X Y)
 ;;;   (* X Y))
于 2014-06-18T21:37:34.760 に答える