2

ディレクトリツリーにperlモジュールまたはスクリプトのHTMLサマリーリストを作成できるツールはありますか？

与えられた

 =head1 NAME

 wibble.pl - does wibble actions

私は次のようなものを見たいです

<a href="docsforwibble">wibble.pl</a> - does wibble actions
<a href="docsforwobble">wobble.pl</a> - does wobble actions
4

2 に答える 2

2

pod2html --recurse --podpath <dirname>

perldocpod2htmlを参照してください

于 2010-03-17T17:50:40.873 に答える
1

Pod::ParserディストリビューションからPod::Findを使用すると、簡単に作成できます。

以下のスクリプトは、myの下にあるものすべての基本的なインデックスファイルを作成しますsite/lib/CGI。これはデモンストレーションとして意図されています。おそらく、の方が良いでしょうpod2htmlが、このスクリプトはまだ役立つかもしれません。

#!/usr/bin/perl

use strict; use warnings;
use autodie;

use File::Spec::Functions qw( canonpath );
use HTML::Template;
use Pod::Find qw(pod_find simplify_name);
use Pod::Select;

my $mod_top = canonpath 'c:/opt/perl/site/lib/CGI';
my $html_top = 'c:/opt/perl/html/site/lib/CGI';

my %pods = pod_find($mod_top);
my @pods;

for my $pod ( sort keys %pods ) {
    (my $link = $pod) =~ s/^\Q$mod_top//;
    $link =~ s/\.\w+\z//;
    $link = "file:///${html_top}${link}.html";

    my $name;
    {
        local *STDOUT;
        open STDOUT, '>', \$name;
        podselect({-sections => [ 'NAME' ] }, $pod);
    }
    $name = '' unless defined $name;
    $name =~ s/^=head1\s+NAME\s+//;
    $name =~ s/\s+\z//;

    push @pods, {
        POD => $pods{$pod},
        NAME => $name,
        LINK => $link,
    };
}

my $tmpl = HTML::Template->new(scalarref => \ <<EO_TMPL
<!DOCTYPE HTML>
<html>
<head><title>Index of Perl Modules</title></head>
<body>
<h1><TMPL_VAR CATEGORY></h1>
<dl>
<TMPL_LOOP PODS>
<dt><a href="<TMPL_VAR LINK>"><TMPL_VAR POD></a></dt>
<dd><TMPL_VAR NAME></dd>
</TMPL_LOOP>
</ul>
</body>
</html>
EO_TMPL
);

$tmpl->param(
    CATEGORY => 'CGI',
    PODS => \@pods,
);
$tmpl->output(print_to => \*STDOUT);
于 2010-03-17T17:50:11.480 に答える