3

これはサンプル スクリプトです。Ctrl+C を押すと、ボットは IRC を終了しますが、しばらくすると再接続します。ボットを正しくシャットダウンするにはどうすればよいですか?

#!/usr/bin/perl

package main;

my $bot = Perlbot->new (server => 'irc.dal.net');

$SIG{'INT'} = 'Handler';
$SIG{'TERM'} = 'Handler';

sub Handler {
print "\nShutting down bot...\n";
$bot->shutdown('Killed.');
};

$bot->run;

package Perlbot;
use base qw(Bot::BasicBot);

sub connected {
my $self = shift;
$self->join('#codetestchan');
}
4

2 に答える 2

2

私は Bot::BasicBot のメンテナーシップを引き継ぎました。バージョン 0.82 の時点で、 で適切にシャットダウンできます$bot->shutdown($quit_message)。

于 2010-07-30T14:41:27.417 に答える
0

Bot::BasicBot のドキュメントとソース コードを調べても、適切にシャットダウンする方法が見つかりません。あなたが示したように、（実際ににイベントを$bot->shutdown()送信する）を呼び出すと、再接続が発生します（ちなみに と同じです）。shutdownPOE::Component::IRCBot::BasicBot$bot->quit()

ユーザーが遭遇したこの制限やその他の制限により、POE::Component::IRC直接使用することをお勧めしました。Bot::BasicBotが作成されたときに欠落していた機能を提供するために、今日では多くのプラグインがありますBot::BasicBot。基本的なボットを起動して実行するには、もう少し入力する必要があるかもしれませんが、はるかに柔軟です。以下は、を使用しない例のようなボットBot::BasicBotです。CTRL+C を押すと IRC サーバーに終了メッセージが送信され、切断されるまで待ってから終了します。

#!/usr/bin/env perl

use strict;
use warnings;
use POE;
use POE::Component::IRC::State;
use POE::Component::IRC::Common qw(parse_user);
use POE::Component::IRC::Plugin::Connector;
use POE::Component::IRC::Plugin::AutoJoin;

# create our session
POE::Session->create(
    package_states => [
        # event handlers
        (__PACKAGE__) => [qw(_start int irc_join irc_disconnected)]
    ]
);

# start the event loop
POE::Kernel->run();

# session start handler
sub _start {
    my ($kernel, $heap) = @_[KERNEL, HEAP];

    # handle CTRL+C
    $kernel->sig(INT => 'int');

    # create bot object
    my $irc = POE::Component::IRC::State->spawn(
        server => 'irc.freenode.net',
        nick   => 'basic123bot',
        debug  => 1,
    );

    # save $irc in our session's storage heap
    $heap->{irc} = $irc;

    # handle reconnects
    $irc->plugin_add('Connector', POE::Component::IRC::Plugin::Connector->new());

    # handle channel joining
    $irc->plugin_add('AutoJoin', POE::Component::IRC::Plugin::AutoJoin->new(
        Channels => ['#foo123bar'],
    ));

    # connect to IRC
    $irc->yield('connect');
}

# interrupt signal handler
sub int {
    my ($kernel, $heap) = @_[KERNEL, HEAP];

    $heap->{irc}->yield('quit', 'Quitting, bye!');
    $heap->{shutting_down} = 1;
    $kernel->sig_handled();
}

# join handler
sub irc_join {
    my ($who, $chan) = @_[ARG0, ARG1];
    my $irc = $_[HEAP]->{irc};

    my ($nick, $user, $host) = parse_user($who);
    if ($nick eq $irc->nick_name()) {
        # say hello to channel members
        $irc->yield('privmsg', $chan, 'Hello everybody');
    }
}

# disconnect handler
sub irc_disconnected {
    my ($heap) = $_[HEAP];

    # shut down if we disconnected voluntarily
    $heap->{irc}->yield('shutdown') if $heap->{shutting_down};
}
于 2010-04-16T11:56:29.183 に答える