0

XSL を使用して xml レコードを 2 回コピーする必要があります。XMLは次のようになります

<data> <record> <a>ABC</a> <b>ABC</b> <c>ARUN</c> <d>JAY</d> <e>SHREE</e> <f>MAKU</f> <z>MACK</z> </record> </data>

条件は IF(a=b) で、2 つのレコード、つまり a,b,c,d,e,z ​​と 2 番目のレコード、つまり a,b,c,d,f,z を作成する必要があります。および IF(a!=b) は、1 つのレコード、つまり a、b、c、d、f、z よりも優れています。私は後半を完了しましたが、レコードを 2 回書き込むことができません。

私のXSLは次のようになります:-

`<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
<xsl:for-each select="data/record">
<xsl:value-of select='a'/>
<xsl:value-of select='b'/>
<xsl:value-of select='c'/>
<xsl:value-of select='d'/>
<xsl:variable name="A" select='a'/>
<xsl:variable name="B" select='b'/>
<xsl:choose>
<xsl:when test="$A = $B">
<xsl:call-template name="test" />
</xsl:when> 
<xsl:otherwise>
<xsl:value-of select='f'/>
</xsl:otherwise>
</xsl:choose>
<xsl:value-of select='z'/>
</xsl:for-each> 
</xsl:template> 
<xsl:template name="test">
<xsl:value-of select='e'/>
<br/>
<xsl:value-of select='f'/>
</xsl:template>
</xsl:stylesheet>`

レコードを2回書くのを手伝ってくれませんか。

4

2 に答える 2

0

私の予想される出力は次のようになります:-最初のレコード ABC、ABC、ARUN、JAY、SHREE、MACK。2nd Record ABC、ABC、ARUN、JAY、MAKU、MACK。

それは私の質問の答えにはなりません。出力がテキストで、各レコードがそれぞれの行にあると仮定すると、次のことができます。

XSLT1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:template match="/">
    <xsl:for-each select="data/record">
        <xsl:if test="a = b">
            <xsl:value-of select="concat(a, b, c, d, e, z)"/>
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
        <xsl:value-of select="concat(a, b, c, d, f, z)"/>
        <xsl:if test="position != last()">
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

その結果：

ABCABCARUNJAYSHREEMACK
ABCABCARUNJAYMAKUMACK

あなたの例では。

編集：

連結は些細なことですが、2 つのレコードの共通部分を事前に計算することで、労力を最小限に抑えることができます。

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:variable name="sep">, </xsl:variable>

<xsl:template match="/">
    <xsl:for-each select="data/record">
        <xsl:variable name="common-start">
             <xsl:value-of select="concat(a, $sep, b, $sep, c, $sep, d, $sep)"/>
        </xsl:variable>
        <xsl:variable name="common-end">
             <xsl:value-of select="concat($sep, z, '&#10;')"/>
        </xsl:variable>
        <xsl:if test="a = b">
            <xsl:value-of select="concat($common-start, e, $common-end)"/>
        </xsl:if>
            <xsl:value-of select="concat($common-start, f, $common-end)"/>
        <xsl:if test="position != last()">
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>
于 2014-07-15T12:28:57.543 に答える
0

本当に「呼び出しテンプレート」を使用したい場合は、次の XSLT を使用できます。各レコードに表示するノードを渡す名前付きテンプレートを使用します。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="data">
   <xsl:for-each select="record">
       <xsl:if test="a=b">
           <xsl:call-template name="record">
               <xsl:with-param name="fields" select="a|b|c|d|e|z" />
           </xsl:call-template>
       </xsl:if>
       <xsl:call-template name="record">
           <xsl:with-param name="fields" select="a|b|c|d|f|z" />
       </xsl:call-template>
   </xsl:for-each> 
</xsl:template> 

<xsl:template name="record">
   <xsl:param name="fields" />
   <xsl:for-each select="$fields">
       <xsl:if test="position() != 1">,</xsl:if>
       <xsl:value-of select="." />
   </xsl:for-each>
   <xsl:value-of select="'&#10;'" />
</xsl:template>
</xsl:stylesheet>

これは、 xsl:with-paramで「選択」した順序に関係なく、ドキュメントの順序でのみ要素を出力することに注意してください。つまり、これを行う...

 <xsl:with-param name="fields" select="a|b|c|d|e|z" />

...これとまったく同じ出力が得られます....

<xsl:with-param name="fields" select="z|e|d|c|b|a" />

または、次のようにステートメントを記述します

<xsl:with-param name="fields" select="*[not(self::f)]" />
于 2014-07-16T07:47:50.490 に答える