313

私はこのSQLを持っています:

ALTER TABLE dbo.ChannelPlayerSkins
    DROP CONSTRAINT FK_ChannelPlayerSkins_Channels

しかし、私たちが使用している他のデータベースでは、制約の名前が異なっているようです。name という制約があるかどうかを確認するにはどうすればよいですかFK_ChannelPlayerSkins_Channels。

4

14 に答える 14

403

これを試して：

SELECT
    * 
    FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS 
    WHERE CONSTRAINT_NAME ='FK_ChannelPlayerSkins_Channels'

- 編集 -

私が最初にこの質問に答えたとき、元の質問は「FK_ChannelPlayerSkins_Channels」を見つけることについて尋ねたので、私は「外部キー」を考えていました。それ以来、多くの人々が他の「制約」を見つけることについてコメントしています。ここに他のいくつかの質問があります。

--Returns one row for each CHECK, UNIQUE, PRIMARY KEY, and/or FOREIGN KEY
SELECT * 
    FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS
    WHERE CONSTRAINT_NAME='XYZ'  


--Returns one row for each FOREIGN KEY constrain
SELECT * 
    FROM INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS 
    WHERE CONSTRAINT_NAME='XYZ'


--Returns one row for each CHECK constraint 
SELECT * 
    FROM INFORMATION_SCHEMA.CHECK_CONSTRAINTS
    WHERE CONSTRAINT_NAME='XYZ'

これは別の方法です

--Returns 1 row for each CHECK, UNIQUE, PRIMARY KEY, FOREIGN KEY, and/or DEFAULT
SELECT 
    OBJECT_NAME(OBJECT_ID) AS NameofConstraint
        ,SCHEMA_NAME(schema_id) AS SchemaName
        ,OBJECT_NAME(parent_object_id) AS TableName
        ,type_desc AS ConstraintType
    FROM sys.objects
    WHERE type_desc LIKE '%CONSTRAINT'
        AND OBJECT_NAME(OBJECT_ID)='XYZ'

さらに多くの制約情報が必要な場合は、システムストアドプロシージャの内部を調べmaster.sys.sp_helpconstraintて、特定の情報を取得する方法を確認してください。SQL Server Management Studioを使用してソースコードを表示するには、「オブジェクトエクスプローラー」にアクセスします。そこから、「マスター」データベースを展開し、次に「プログラマビリティ」、「ストアドプロシージャ」、「システムストアドプロシージャ」の順に展開します。次に、「sys.sp_helpconstraint」を見つけて右クリックし、「変更」を選択します。変更を保存しないように注意してください。また、このシステムストアドプロシージャは、のように使用することで、任意のテーブルで使用できますEXEC sp_helpconstraint YourTableNameHere。

于 2010-03-23T11:23:56.917 に答える
290

制約の存在を確認する最も簡単な方法 (そして、存在する場合は削除するなど) は、OBJECT_ID() 関数を使用することです...

IF OBJECT_ID('dbo.[CK_ConstraintName]', 'C') IS NOT NULL 
    ALTER TABLE dbo.[tablename] DROP CONSTRAINT CK_ConstraintName

OBJECT_ID は 2 番目のパラメーター (チェック制約のみの場合は 'C') なしで使用でき、それも機能する可能性がありますが、制約名がデータベース内の他のオブジェクトの名前と一致する場合、予期しない結果が生じる可能性があります。 

IF OBJECT_ID('dbo.[CK_ConstraintName]') IS NOT NULL 
    ALTER TABLE dbo.[tablename] DROP CONSTRAINT CK_ConstraintName

OBJECT_ID は、外部キー制約や主キー制約などの他の「制約」と共に使用することもできます。最良の結果を得るには、常に適切なオブジェクト タイプを OBJECT_ID 関数の 2 番目のパラメーターとして含めます。

制約オブジェクト タイプ:

  • C = CHECK 制約
  • D = DEFAULT (制約またはスタンドアロン)
  • F = FOREIGN KEY 制約
  • PK = PRIMARY KEY 制約
  • R = ルール (古いスタイル、スタンドアロン)
  • UQ = UNIQUE 制約

多くの場合、スキーマが必要になることにも注意してください。制約のスキーマは通常、親テーブルのスキーマを取ります。

このメソッドを使用するときに、制約 (またはチェック対象のもの) を括弧で囲まないと、偽陰性が発生する可能性があります。オブジェクトで通常とは異なる文字 (. など) が使用されている場合は、括弧が必要です。

于 2013-03-25T22:08:50.323 に答える
47

デフォルトなど、他のタイプの制約を探している場合は、別のクエリを使用する必要があります ( INFORMATION_SCHEMA を使用してデフォルトの制約を見つけるにはどうすればよいですか? devioが回答)。使用する：

SELECT * FROM sys.objects WHERE type = 'D' AND name = @name

名前でデフォルトの制約を見つけます。

「SQL スクリプトを再実行可能にするための DDL 'IF not Exists」条件」に、さまざまな「IF not Exists」チェックをまとめました。

于 2011-07-27T04:49:01.620 に答える
31 
IF (OBJECT_ID('FK_ChannelPlayerSkins_Channels') IS NOT NULL)
于 2012-05-31T14:24:42.190 に答える
20

このようなものを見ていますか、以下はSQL Server 2005でテストされています

SELECT * FROM sys.check_constraints WHERE 
object_id = OBJECT_ID(N'[dbo].[CK_accounts]') AND 
parent_object_id = OBJECT_ID(N'[dbo]. [accounts]')
于 2010-03-23T11:18:52.220 に答える
10

気をつけるべきこと......

SQL Server 2008 R2 SSMSでは、「Script Constraint as-> DROP And CREATE To」コマンドにより、次のようなT-SQLが生成されます。

USE [MyDatabase]
GO

IF  EXISTS (SELECT * FROM dbo.sysobjects WHERE id = OBJECT_ID(N'[DEF_Detail_IsDeleted]') AND type = 'D')
BEGIN
ALTER TABLE [Patient].[Detail] DROP CONSTRAINT [DEF_Detail_IsDeleted]
END

GO

USE [MyDatabase]
GO

ALTER TABLE [Patient].[Detail] ADD  CONSTRAINT [DEF_Detail_IsDeleted]  DEFAULT ((0)) FOR [IsDeleted]
GO

箱から出して、SELECTは0行を返すため、このスクリプトは制約を削除しません。（投稿Microsoft Connectを参照してください）。

デフォルトの制約の名前は間違っていますが、名前を変更しても問題が解決しないため、OBJECT_ID関数とも関係があると思います。

これを修正するために、OBJECT_IDの使用を削除し、代わりにデフォルトの制約名を使用しました。

(SELECT * FROM dbo.sysobjects WHERE [name] = (N'DEF_Detail_IsDeleted') AND type = 'D')
于 2012-06-21T22:04:03.507 に答える
8

次のクエリを使用して、既存の制約を作成する前に確認します。

IF (NOT EXISTS(SELECT 1 FROM sysconstraints WHERE OBJECT_NAME(constid) = 'UX_CONSTRAINT_NAME' AND OBJECT_NAME(id) = 'TABLE_NAME')) BEGIN
...
END

これは、指定されたテーブル名を対象とする名前による制約を照会します。お役に立てれば。

于 2014-06-17T08:46:28.773 に答える
3 
IF EXISTS(SELECT 1 FROM sys.foreign_keys WHERE parent_object_id = OBJECT_ID(N'dbo.TableName'))
 BEGIN 
ALTER TABLE TableName DROP CONSTRAINT CONSTRAINTNAME 
END
于 2014-09-19T07:16:08.167 に答える
3 
IF EXISTS(SELECT TOP 1 1 FROM sys.default_constraints WHERE parent_object_id = OBJECT_ID(N'[dbo].[ChannelPlayerSkins]') AND name = 'FK_ChannelPlayerSkins_Channels')
BEGIN
    DROP CONSTRAINT FK_ChannelPlayerSkins_Channels
END
GO
于 2017-08-22T17:43:24.070 に答える
2

INFORMATION_SCHEMAあなたの友達です。あらゆる種類のスキーマ情報を表示するあらゆる種類のビューがあります。システム ビューを確認します。制約を扱う 3 つのビューがあることがわかります。1 つはCHECK_CONSTRAINTSです。

于 2010-03-23T11:14:31.997 に答える
1

これを使用して、列の制約をチェックし、リモート制約を解除します。必要なものがすべて揃っているはずです。

DECLARE
  @ps_TableName VARCHAR(300)
  , @ps_ColumnName VARCHAR(300)

SET @ps_TableName = 'mytable'
SET @ps_ColumnName = 'mycolumn'

DECLARE c_ConsList CURSOR LOCAL STATIC FORWARD_ONLY FOR
    SELECT
    'ALTER TABLE ' + RTRIM(tb.name) + ' drop constraint ' + sco.name AS csql
    FROM
        sys.Objects tb
        INNER JOIN sys.Columns tc on (tb.Object_id = tc.object_id)
        INNER JOIN sys.sysconstraints sc ON (tc.Object_ID = sc.id and tc.column_id = sc.colid)
        INNER JOIN sys.objects sco ON (sc.Constid = sco.object_id)
    where
        tb.name=@ps_TableName
        AND tc.name=@ps_ColumnName
OPEN c_ConsList
FETCH c_ConsList INTO @ls_SQL
WHILE (@@FETCH_STATUS = 0) BEGIN

    IF RTRIM(ISNULL(@ls_SQL, '')) <> '' BEGIN
        EXECUTE(@ls_SQL)
    END
    FETCH c_ConsList INTO @ls_SQL
END
CLOSE c_ConsList
DEALLOCATE c_ConsList
于 2013-03-21T20:13:10.153 に答える
1

上記のものを使用できますが、1 つの注意事項があります。

IF EXISTS(
    SELECT 1 FROM sys.foreign_keys 
    WHERE parent_object_id = OBJECT_ID(N'dbo.TableName') 
        AND name = 'CONSTRAINTNAME'
)
BEGIN 
    ALTER TABLE TableName DROP CONSTRAINT CONSTRAINTNAME 
END

name = [Constraint name]テーブルには複数の外部キーがあり、まだ外部キーがチェックされていない可能性があるため、を使用する必要があります

于 2017-04-17T18:08:18.093 に答える
0 
SELECT tabla.name as Tabla,

        restriccion.name as Restriccion, 
        restriccion.type as Tipo, 
        restriccion.type_desc as Tipo_Desc
FROM {DATABASE_NAME}.sys.objects tabla 

INNER JOIN {DATABASE_NAME}.sys.objects restriccion

ON tabla.object_id = restriccion.parent_object_id

WHERE tabla.type = 'U' - Solo tablas creadas por el usuario.

AND restriccion.type = 'UQ' --Tipo de Restriccion UNIQUE

ORDER BY tabla.name, restriccion.type_desc
于 2014-10-28T17:46:18.373 に答える