opengl - GLSL シェーダをデバッグするには?

Question

GLSL プログラムをデバッグする必要がありますが、中間結果を出力する方法がわかりません。GLSL で (printf のような) デバッグ トレースを作成することは可能ですか?

Answer 1

GLSL 内から CPU に簡単に通信することはできません。glslDevil またはその他のツールを使用するのが最善の策です。

printf では、GLSL コードを実行している GPU から CPU に戻ろうとする必要があります。代わりに、ディスプレイに向かって押してみることができます。テキストを出力しようとする代わりに、視覚的に特徴的なものを画面に出力します。たとえば、printf を追加するコードのポイントに到達した場合にのみ、何かを特定の色でペイントできます。値を印刷する必要がある場合は、その値に従って色を設定できます。

Answer 2

void main(){
  float bug=0.0;
  vec3 tile=texture2D(colMap, coords.st).xyz;
  vec4 col=vec4(tile, 1.0);

  if(something) bug=1.0;

  col.x+=bug;

  gl_FragColor=col;
}

Answer 3

トランスフォーム フィードバックは、頂点シェーダーのデバッグに役立つツールであることがわかりました。これを使用して VS 出力の値をキャプチャし、ラスタライザーを経由せずに CPU 側で読み返すことができます。

フィードバックの変換に関するチュートリアルへの別のリンクを次に示します。

Answer 4

GLSL Sandboxは、シェーダーに関して私にとって非常に便利でした。

それ自体をデバッグするわけではありませんが（これはできないと回答されています）、出力の変化をすばやく確認するのに便利です。

Answer 5

画面全体の値の変化を視覚化する場合は、次のようなヒートマップ関数を使用できます (これは hlsl で記述しましたが、glsl に適応するのは簡単です)。

float4 HeatMapColor(float value, float minValue, float maxValue)
{
    #define HEATMAP_COLORS_COUNT 6
    float4 colors[HEATMAP_COLORS_COUNT] =
    {
        float4(0.32, 0.00, 0.32, 1.00),
        float4(0.00, 0.00, 1.00, 1.00),
        float4(0.00, 1.00, 0.00, 1.00),
        float4(1.00, 1.00, 0.00, 1.00),
        float4(1.00, 0.60, 0.00, 1.00),
        float4(1.00, 0.00, 0.00, 1.00),
    };
    float ratio=(HEATMAP_COLORS_COUNT-1.0)*saturate((value-minValue)/(maxValue-minValue));
    float indexMin=floor(ratio);
    float indexMax=min(indexMin+1,HEATMAP_COLORS_COUNT-1);
    return lerp(colors[indexMin], colors[indexMax], ratio-indexMin);
}

次に、ピクセル シェーダーで次のような出力を行います。

return HeatMapColor(myValue, 0.00, 50.00);

また、ピクセル間でどのように変化するかを把握できます。

もちろん、好きな色のセットを使用することもできます。

Answer 6

この回答の最後に、floatIEEE 754 をエンコードして、完全な値を色として出力できる GLSL コードの例がありますbinary32。私は次のように使用します（このスニペットはyyモデルビューマトリックスのコンポーネントを提供します）：

vec4 xAsColor=toColor(gl_ModelViewMatrix[1][1]);
if(bool(1)) // put 0 here to get lowest byte instead of three highest
    gl_FrontColor=vec4(xAsColor.rgb,1);
else
    gl_FrontColor=vec4(xAsColor.a,0,0,1);

これを画面に表示したら、任意のカラー ピッカーを使用して、色を HTML としてフォーマットします (より高い精度が必要ない場合は値に追加00し、必要な場合は 2 番目のパスを実行して下位バイトを取得します)。 IEEE 754 としてrgbの 16 進表現を取得します。floatbinary32

の実際の実装は次のtoColor()とおりです。

const int emax=127;
// Input: x>=0
// Output: base 2 exponent of x if (x!=0 && !isnan(x) && !isinf(x))
//         -emax if x==0
//         emax+1 otherwise
int floorLog2(float x)
{
    if(x==0.) return -emax;
    // NOTE: there exist values of x, for which floor(log2(x)) will give wrong
    // (off by one) result as compared to the one calculated with infinite precision.
    // Thus we do it in a brute-force way.
    for(int e=emax;e>=1-emax;--e)
        if(x>=exp2(float(e))) return e;
    // If we are here, x must be infinity or NaN
    return emax+1;
}

// Input: any x
// Output: IEEE 754 biased exponent with bias=emax
int biasedExp(float x) { return emax+floorLog2(abs(x)); }

// Input: any x such that (!isnan(x) && !isinf(x))
// Output: significand AKA mantissa of x if !isnan(x) && !isinf(x)
//         undefined otherwise
float significand(float x)
{
    // converting int to float so that exp2(genType) gets correctly-typed value
    float expo=float(floorLog2(abs(x)));
    return abs(x)/exp2(expo);
}

// Input: x\in[0,1)
//        N>=0
// Output: Nth byte as counted from the highest byte in the fraction
int part(float x,int N)
{
    // All comments about exactness here assume that underflow and overflow don't occur
    const float byteShift=256.;
    // Multiplication is exact since it's just an increase of exponent by 8
    for(int n=0;n<N;++n)
        x*=byteShift;

    // Cut higher bits away.
    // $q \in [0,1) \cap \mathbb Q'.$
    float q=fract(x);

    // Shift and cut lower bits away. Cutting lower bits prevents potentially unexpected
    // results of rounding by the GPU later in the pipeline when transforming to TrueColor
    // the resulting subpixel value.
    // $c \in [0,255] \cap \mathbb Z.$
    // Multiplication is exact since it's just and increase of exponent by 8
    float c=floor(byteShift*q);
    return int(c);
}

// Input: any x acceptable to significand()
// Output: significand of x split to (8,8,8)-bit data vector
ivec3 significandAsIVec3(float x)
{
    ivec3 result;
    float sig=significand(x)/2.; // shift all bits to fractional part
    result.x=part(sig,0);
    result.y=part(sig,1);
    result.z=part(sig,2);
    return result;
}

// Input: any x such that !isnan(x)
// Output: IEEE 754 defined binary32 number, packed as ivec4(byte3,byte2,byte1,byte0)
ivec4 packIEEE754binary32(float x)
{
    int e = biasedExp(x);
    // sign to bit 7
    int s = x<0. ? 128 : 0;

    ivec4 binary32;
    binary32.yzw=significandAsIVec3(x);
    // clear the implicit integer bit of significand
    if(binary32.y>=128) binary32.y-=128;
    // put lowest bit of exponent into its position, replacing just cleared integer bit
    binary32.y+=128*int(mod(float(e),2.));
    // prepare high bits of exponent for fitting into their positions
    e/=2;
    // pack highest byte
    binary32.x=e+s;

    return binary32;
}

vec4 toColor(float x)
{
    ivec4 binary32=packIEEE754binary32(x);
    // Transform color components to [0,1] range.
    // Division is inexact, but works reliably for all integers from 0 to 255 if
    // the transformation to TrueColor by GPU uses rounding to nearest or upwards.
    // The result will be multiplied by 255 back when transformed
    // to TrueColor subpixel value by OpenGL.
    return vec4(binary32)/255.;
}

Answer 7

フラグメントシェーダーの例を共有しています。実際にデバッグする方法です。

#version 410 core

uniform sampler2D samp;
in VS_OUT
{
    vec4 color;
    vec2 texcoord;
} fs_in;

out vec4 color;

void main(void)
{
    vec4 sampColor;
    if( texture2D(samp, fs_in.texcoord).x > 0.8f)  //Check if Color contains red
        sampColor = vec4(1.0f, 1.0f, 1.0f, 1.0f);  //If yes, set it to white
    else
        sampColor = texture2D(samp, fs_in.texcoord); //else sample from original
    color = sampColor;

}

Answer 8

既存の回答はすべて良いものですが、GLSL シェーダーでトリッキーな精度の問題をデバッグするのに役立つ小さな宝石をもう 1 つ共有したいと思います。非常に大きな int 数値が浮動小数点として表されるため、round() を正確な int に実装するには、floor(n) と floor(n + 0.5) を適切に使用するように注意する必要があります。その後、次のロジックによって正確な int である float 値をレンダリングして、バイト コンポーネントを R、G、および B 出力値にパックすることができます。

  // Break components out of 24 bit float with rounded int value
  // scaledWOB = (offset >> 8) & 0xFFFF
  float scaledWOB = floor(offset / 256.0);
  // c2 = (scaledWOB >> 8) & 0xFF
  float c2 = floor(scaledWOB / 256.0);
  // c0 = offset - (scaledWOB << 8)
  float c0 = offset - floor(scaledWOB * 256.0);
  // c1 = scaledWOB - (c2 << 8)
  float c1 = scaledWOB - floor(c2 * 256.0);

  // Normalize to byte range
  vec4 pix;  
  pix.r = c0 / 255.0;
  pix.g = c1 / 255.0;
  pix.b = c2 / 255.0;
  pix.a = 1.0;
  gl_FragColor = pix;

Answer 9

テクスチャにオフライン レンダリングを実行し、テクスチャのデータを評価します。「render to texture」opengl をグーグルで検索すると、関連するコードを見つけることができます。次に、glReadPixels を使用して出力を配列に読み込み、それに対してアサーションを実行します (デバッガーでこのような巨大な配列を調べることは、通常、あまり役に立ちません)。

また、0 と 1 の間ではない値を出力するクランプを無効にすることもできます。これは、浮動小数点テクスチャでのみサポートされています。

個人的には、しばらくの間、シェーダーを適切にデバッグするという問題に悩まされていました。良い方法はないようです - 誰かが良い（そして時代遅れ/廃止されていない）デバッガを見つけたら、私に知らせてください。