88

Emacsのどのコマンドを使用して、ファイルのテキストバッファに現在の日付と時刻を挿入できますか？

（たとえば、メモ帳の同等の機能は、メモ帳の唯一の便利な機能であるF5を押すだけです！）

4

11 に答える 11

141 
C-u M-! date
于 2008-11-09T11:44:03.250 に答える
44

.emacs ファイルに入れます:

;; ====================
;; insert date and time

(defvar current-date-time-format "%a %b %d %H:%M:%S %Z %Y"
  "Format of date to insert with `insert-current-date-time' func
See help of `format-time-string' for possible replacements")

(defvar current-time-format "%a %H:%M:%S"
  "Format of date to insert with `insert-current-time' func.
Note the weekly scope of the command's precision.")

(defun insert-current-date-time ()
  "insert the current date and time into current buffer.
Uses `current-date-time-format' for the formatting the date/time."
       (interactive)
       (insert "==========\n")
;       (insert (let () (comment-start)))
       (insert (format-time-string current-date-time-format (current-time)))
       (insert "\n")
       )

(defun insert-current-time ()
  "insert the current time (1-week scope) into the current buffer."
       (interactive)
       (insert (format-time-string current-time-format (current-time)))
       (insert "\n")
       )

(global-set-key "\C-c\C-d" 'insert-current-date-time)
(global-set-key "\C-c\C-t" 'insert-current-time)

参照

于 2008-10-30T22:01:24.710 に答える
33

私はこれらの短いスニペットを使用しました：

(defun now ()
  "Insert string for the current time formatted like '2:34 PM'."
  (interactive)                 ; permit invocation in minibuffer
  (insert (format-time-string "%D %-I:%M %p")))

(defun today ()
  "Insert string for today's date nicely formatted in American style,
e.g. Sunday, September 17, 2000."
  (interactive)                 ; permit invocation in minibuffer
  (insert (format-time-string "%A, %B %e, %Y")))

それらはもともとjournal.elから来ました

于 2009-03-06T16:41:40.330 に答える
27

挿入日:

M-x org-time-stamp

挿入日時の場合:

C-u M-x org-time-stamp

このコマンドのグローバル キーをバインドできます。

org-modeのメソッドは非常にユーザー フレンドリーで、カレンダーから任意の日付を選択できます。

于 2013-06-13T03:23:21.603 に答える
15

yasnippetをインストールすると、「time」とタブ キーを入力できるようになり、さらに多くのことができます。current-time-string舞台裏で呼び出すだけなので、を使用してフォーマットを制御できますformat-time-string。

于 2008-10-30T23:07:25.373 に答える
5

これは、あなたが求めていることを行う、少し前に書いたパッケージです。

http://github.com/rmm5t/insert-time.el/tree/master/insert-time.el

(require 'insert-time)
(define-key global-map [(control c)(d)] 'insert-date-time)
(define-key global-map [(control c)(control v)(d)] 'insert-personal-time-stamp)
于 2008-10-30T22:06:52.470 に答える
2

M-1M-！日にち

これにより、実行するシェル コマンドが、新しいバッファではなく、現在編集中のバッファに挿入されます。

于 2010-03-02T08:59:04.833 に答える
1

ありがとう、CMS！私のバリエーションは、それが価値があるもののために-私を十分に幸せにします：

(defvar bjk-timestamp-format "%Y-%m-%d %H:%M"
  "Format of date to insert with `bjk-timestamp' function
%Y-%m-%d %H:%M will produce something of the form YYYY-MM-DD HH:MM
Do C-h f on `format-time-string' for more info")


(defun bjk-timestamp ()
  "Insert a timestamp at the current point.
Note no attempt to go to beginning of line and no added carriage return.
Uses `bjk-timestamp-format' for formatting the date/time."
       (interactive)
       (insert (format-time-string bjk-timestamp-format (current-time)))
       )

私はこれを私の.emacsによって呼び出されるファイルに入れました：

(load "c:/bjk/elisp/bjk-timestamp.el")

これにより、.emacsで他の何かを壊すリスクを冒さずに簡単に変更できるようになり、いつかこのEmacsLispプログラミングが何であるかを実際に学ぶための簡単なエントリポイントが得られました。

私のn00bテクニックに関するPS批評は大歓迎です。

于 2010-08-18T05:54:06.430 に答える
0

これが私の見解です。

(defun modi/insert-time-stamp (option)
  "Insert date, time, user name - DWIM.

If the point is NOT in a comment/string, the time stamp is inserted prefixed
with `comment-start' characters.

If the point is IN a comment/string, the time stamp is inserted without the
`comment-start' characters. If the time stamp is not being inserted immediately
after the `comment-start' characters (followed by optional space),
the time stamp is inserted with “--” prefix.

If the buffer is in a major mode where `comment-start' var is nil, no prefix is
added regardless.

Additional control:

        C-u -> Only `comment-start'/`--' prefixes are NOT inserted
    C-u C-u -> Only user name is NOT inserted
C-u C-u C-u -> Both prefix and user name are not inserted."
  (interactive "P")
  (let ((current-date-time-format "%a %b %d %H:%M:%S %Z %Y"))
    ;; Insert a space if there is no space to the left of the current point
    ;; and it's not at the beginning of a line
    (when (and (not (looking-back "^ *"))
               (not (looking-back " ")))
      (insert " "))
    ;; Insert prefix only if `comment-start' is defined for the major mode
    (when (stringp comment-start)
      (if (or (nth 3 (syntax-ppss)) ; string
              (nth 4 (syntax-ppss))) ; comment
          ;; If the point is already in a comment/string
          (progn
            ;; If the point is not immediately after `comment-start' chars
            ;; (followed by optional space)
            (when (and (not (or (equal option '(4)) ; C-u or C-u C-u C-u
                                (equal option '(64))))
                       (not (looking-back (concat comment-start " *")))
                       (not (looking-back "^ *")))
              (insert "--")))
        ;; If the point is NOT in a comment
        (progn
          (when (not (or (equal option '(4)) ; C-u or C-u C-u C-u
                         (equal option '(64))))
            (insert comment-start)))))
    ;; Insert a space if there is no space to the left of the current point
    ;; and it's not at the beginning of a line
    (when (and (not (looking-back "^ *"))
               (not (looking-back " ")))
      (insert " "))
    (insert (format-time-string current-date-time-format (current-time)))
    (when (not (equal option '(16))) ; C-u C-u
      (insert (concat " - " (getenv "USER"))))
    ;; Insert a space after the time stamp if not at the end of the line
    (when (not (looking-at " *$"))
      (insert " "))))

これを にバインドすることを好みC-c dます。

于 2015-03-31T17:35:16.750 に答える