perl - Perlで配列またはハッシュから重複した値を保存するにはどうすればよいですか?

Question

これを非常に簡単にしましょう。私が欲しいもの：

@array = qw/one two one/;
my @duplicates = duplicate(@array);
print "@duplicates"; # This should now print 'one'.

配列/ハッシュの重複値を出力するには?

Answer 1

sub duplicate {
    my @args = @_;
    my %items;
    for my $element(@args) {
        $items{$element}++;
    }
    return grep {$items{$_} > 1} keys %items;
}

Answer 2

# assumes inputs can be hash keys
@a = (1, 2, 3, 3, 4, 4, 5);

# keep count for each unique input
%h = ();
map { $h{$_}++  } @a;

# duplicate inputs have count > 1
@dupes = grep { $h{$_} > 1 } keys %h;

# should print 3, 4
print join(", ", sort @dupes), "\n";

Answer 3

あなたがやりたいことの余分な冗長で読みやすいバージョン：

sub duplicate {
   my %value_hash;
   foreach my $val (@_) {
     $value_hash{$val} +=1;
   }
   my @arr;
   while (my ($val, $num) = each(%value_hash)) {
     if ($num > 1) {
        push(@arr, $val)
     }
   }
  return @arr;
}

これはかなり短縮できますが、理解できるように意図的に冗長にしています。

ただし、私はそれをテストしていないので、タイプミスに気をつけてください。

Answer 4

質問で指定されていないのは、重複が返される順序です。

いくつかの可能性が考えられます。入力リストの最初/2 番目/最後の出現順。並べ替えました。

Answer 5

辞書を使用して、値をキーに、カウントを値に入れます。

ああ、perl としてタグ付けされていることに気付きました

その間 （[...]） {
 $hash{[dbvalue]}++
}

Answer 6

ゴルフに行きます！

sub duplicate {
    my %count;
    grep $count{$_}++, @_;
}

@array = qw/one two one/;
my @duplicates = duplicate(@array);
print "@duplicates"; # This should now print 'one'.

# or if returning *exactly* 1 occurrence of each duplicated item is important
sub duplicate {
    my %count;
    grep ++$count{$_} == 2, @_;
}