2

C 派生モードでアラインメント ルールを微調整する方法はありますか。

    foreach (file; dirPath.expandTilde()
                          .buildNormalizedPath() 
                          .dirEntries(SpanMode.shallow)()

この場合、私はポイントに合わせたいと思います。

詳細については、https://github.com/Emacs-D-Mode-Maintainers/Emacs-D-Mode/issues/26を参照してください。

4

1 に答える 1

2

arglist-cont-nonemptyのキーの値を変更する必要がありますc-offsets-alist。statement-contまた、キーを変更して、一般的なステートメント (割り当てなど) でも同じインデントを有効にしたい場合があります。

(add-to-list 'c-offsets-alist '(arglist-cont-nonempty . c-lineup-cascaded-calls))
(add-to-list 'c-offsets-alist '(statement-cont . c-lineup-cascaded-calls))

明らかに、次のようなものを使用できます。

(add-hook 'd-mode-hook
                 '(lambda ()
                    (add-to-list 'c-offsets-alist '(arglist-cont-nonempty . c-lineup-cascaded-calls))
                    (add-to-list 'c-offsets-alist '(statement-cont . c-lineup-cascaded-calls))))

すべての d モード バッファでこのアライメントを有効にします。

オプションの括弧を説明したい場合は、組み込みのソリューションが思いつかないので、独自の「並べる」関数を作成する必要があると思います。これは c-lineup-cascaded-calls の汚い書き直しです:

(defun d-lineup-cascaded-calls (langelem)
  "This is a modified `c-lineup-cascaded-calls' function for the
D programming language which accounts for optional parenthesis
and compile-time parameters in function calls."

  (if (and (eq (c-langelem-sym langelem) 'arglist-cont-nonempty)
           (not (eq (c-langelem-2nd-pos c-syntactic-element)
                    (c-most-enclosing-brace (c-parse-state)))))
      ;; The innermost open paren is not our one, so don't do
      ;; anything.  This can occur for arglist-cont-nonempty with
      ;; nested arglist starts on the same line.
      nil

    (save-excursion
      (back-to-indentation)
      (let ((operator (and (looking-at "\\.")
                           (regexp-quote (match-string 0))))
            (stmt-start (c-langelem-pos langelem)) col)

        (when (and operator
                   (looking-at operator)
                   (or (and
                        (zerop (c-backward-token-2 1 t stmt-start))
                        (eq (char-after) ?\()
                        (zerop (c-backward-token-2 2 t stmt-start))
                        (looking-at operator))
                       (and
                        (zerop (c-backward-token-2 1 t stmt-start))
                        (looking-at operator))
                       (and
                        (zerop (c-backward-token-2 1 t stmt-start))
                        (looking-at operator))
                       )
                   )
          (setq col (current-column))

          (while (or (and
                      (zerop (c-backward-token-2 1 t stmt-start))
                      (eq (char-after) ?\()
                      (zerop (c-backward-token-2 2 t stmt-start))
                      (looking-at operator))
                     (and
                      (zerop (c-backward-token-2 1 t stmt-start))
                      (looking-at operator))
                     (and
                      (zerop (c-backward-token-2 1 t stmt-start))
                      (looking-at operator))
                     )
            (setq col (current-column)))

          (vector col))))))

オプションの括弧と二重括弧の呼び出し（つまりcall!(type)(arg)）でも機能するようです。しかし、まれなケースもあるかもしれないので、あまり当てにしないでください。

于 2014-09-15T07:53:17.523 に答える