7

*.xlam アドインでユーザー フォームを作成し、IDE で新しいコマンド バーとボタンを作成しましたが、ボタンをクリックすると Excel でユーザー フォームが開かれ、フォーカスが IDE から離れてしまいます。.Net COM アドインを使用せずに、ホスト アプリケーションではなく IDE でユーザー フォームを開く方法はありますか?

コマンドバーとボタンを作成し、ボタン クリック イベントを処理するコードを次に示します。

Option Explicit

Public WithEvents cmdBarEvents As VBIDE.CommandBarEvents

Private Sub Class_Initialize()
    CreateCommandBar
End Sub

Private Sub Class_Terminate()
    Application.VBE.CommandBars("VBIDE").Delete
End Sub

Private Sub CreateCommandBar()

    Dim bar As CommandBar
    Set bar = Application.VBE.CommandBars.Add("VBIDE", MsoBarPosition.msoBarFloating, False, True)
    bar.Visible = True

    Dim btn As CommandBarButton
    Set btn = bar.Controls.Add(msoControlButton, , , , True)
    btn.Caption = "Show Form"
    btn.OnAction = "ShowForm"
    btn.FaceId = 59

    Set cmdBarEvents = Application.VBE.Events.CommandBarEvents(btn)

End Sub

Private Sub cmdBarEvents_Click(ByVal CommandBarControl As Object, handled As Boolean, CancelDefault As Boolean)

    CallByName Me, CommandBarControl.OnAction, VbMethod

End Sub

Public Sub ShowForm()
    Dim frm As New UserForm1
    frm.Show
End Sub

PSコマンドバーを削除するには、このコード行が必要になる場合があります...

Application.VBE.CommandBars("VBIDE").Delete
4

1 に答える 1

7

これが代替案です。

ユーザーフォームにボタンを配置します。デモンストレーションの目的で、これを使用しています

ここに画像の説明を入力

次に、このコードをユーザーフォームに入れます

Private Sub CommandButton1_Click()
    Unload Me
    Application.Visible = True
End Sub

次に、これをクラス モジュールの上に貼り付けます

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
(ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Dim Ret As Long, ChildRet As Long

Private Declare Function SetWindowPos Lib "user32" (ByVal hwnd As Long, _
ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, _
ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Private Const HWND_TOPMOST = -1
Private Const SWP_NOACTIVATE = &H10
Private Const SWP_SHOWWINDOW = &H40

最後にこれに変更Sub ShowForm()します

Public Sub ShowForm()
    Dim frm As New UserForm1
    Dim Ret As Long

    frm.Show vbModeless

    Application.Visible = False

    Ret = FindWindow("ThunderDFrame", frm.Caption)

    SetWindowPos Ret, HWND_TOPMOST, 100, 100, 250, 200, _
    SWP_NOACTIVATE Or SWP_SHOWWINDOW
End Sub

これはあなたが得るものです

ここに画像の説明を入力

編集

より多くの考え。ユーザーがスマイリーをクリックしたときにユーザーがそれ以上ユーザーフォームを作成できないようにするには、 を以下のように変更しSub ShowForm()ます。(代わりに、スマイリーを無効にして、フォームのアンロード時に再度有効にすることもできますか? )

Public Sub ShowForm()
    Dim frm As New UserForm1
    Dim Ret As Long
    Dim formCaption As String

    '~~> Set Userform Caption
    formCaption = "Blah Blah"

    On Error Resume Next
    Ret = FindWindow("ThunderDFrame", formCaption)
    On Error GoTo 0

    '~~> If already there in an instance then exit sub
    If Ret <> 0 Then Exit Sub

    frm.Show vbModeless
    frm.Caption = formCaption

    Application.Visible = False

    Ret = FindWindow("ThunderDFrame", frm.Caption)

    SetWindowPos Ret, HWND_TOPMOST, 100, 100, 250, 200, _
    SWP_NOACTIVATE Or SWP_SHOWWINDOW
End Sub
于 2014-11-03T21:56:40.467 に答える