0

XML ファイルを ANT ビルド スクリプトに渡し、ビルド ファイルの親ディレクトリをルートとして使用して、XML のノード構造を模倣するフォルダー構造を作成できるようにしたいと考えています。

使用例：

<root>
    <folder1>
         <folder1-1/>
    </folder1>
    <folder2/>
    <folder3>
         <folder3-1/>
    </folder3>
</root>

ant は以下を作成します。

folder1
   -folder1-1
folder2
folder3
   -folder3-1

ディレクトリの作成方法は知っていますが、ANT で XML を解析する方法がわかりません。

4

1 に答える 1

1

1 つのオプションは、xslt タスクを使用して重い作業を行うことです。たとえば、2 番目の Ant スクリプトを生成して呼び出します。

build.xml:

<project default="mkdirs">
  <target name="mkdirs">
    <xslt style="mkdir.xslt" in="dirs.xml" out="mkdir.build.xml"/>
    <ant antfile="mkdir.build.xml"/>
  </target>
</project>

mkdir.xslt を build.xml と同じディレクトリに配置します。

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:template match="text()"/>

  <xsl:template match="root">
    <project><xsl:text>&#10;</xsl:text>
      <xsl:apply-templates/>
    </project>
  </xsl:template>

  <xsl:template match="*">
    <mkdir>
      <xsl:attribute name="dir">
        <xsl:for-each select="ancestor::*">
          <xsl:if test="position() != 1">
            <xsl:value-of select="name()"/>
            <xsl:text>/</xsl:text>
          </xsl:if>
        </xsl:for-each>
        <xsl:value-of select="name()"/>
      </xsl:attribute>
    </mkdir><xsl:text>&#10;</xsl:text>

    <xsl:apply-templates/>
  </xsl:template>
</xsl:transform>

xslt タスクからの mkdir.build.xml 出力の例:

<?xml version="1.0" encoding="UTF-8"?><project>
<mkdir dir="folder1"/>
<mkdir dir="folder1/folder1-1"/>
<mkdir dir="folder2"/>
<mkdir dir="folder3"/>
<mkdir dir="folder3/folder3-1"/>
</project>

私は XSLT に精通していないので、for-each ループを改善できる可能性があります。

于 2010-04-29T02:50:41.247 に答える