delphi - cxgrid でレコードをループする方法 - Delphi xe2

Question

cxgrids レコードをどのようにループしますか? つまり、Delphi プログラムで cxgrid の各レコードを上から下に調べます。

とにかくこれが役立つ場合、データベーステーブルと通信しているtadqueryからのレコードを表示しているcxgridがあります。

Answer 1

グリッド内のすべてのレコードがどこにあるのか、または表示されているレコードだけがどこにあるのかは言いませんでした:

Any how heres は、両方を実行する例です。

この例では、cxGrid、cxButton、および cxMemo を含むフォームを使用しています。プラス dxMemdataset

DFM コードは次のとおりです。

object Form20: TForm20
  Left = 0
  Top = 0
  Caption = 'Form20'
  ClientHeight = 299
  ClientWidth = 462
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  OnCreate = FormCreate
  DesignSize = (
    462
    299)
  PixelsPerInch = 96
  TextHeight = 13
  object cxGrid1: TcxGrid
    Left = 0
    Top = 0
    Width = 299
    Height = 299
    Align = alLeft
    TabOrder = 0
    ExplicitHeight = 635
    object cxGrid1DBTableView1: TcxGridDBTableView
      Navigator.Buttons.CustomButtons = <>
      DataController.DataSource = DataSource1
      DataController.Summary.DefaultGroupSummaryItems = <>
      DataController.Summary.FooterSummaryItems = <>
      DataController.Summary.SummaryGroups = <>
      object cxGrid1DBTableView1RecId: TcxGridDBColumn
        DataBinding.FieldName = 'RecId'
        Visible = False
      end
      object cxGrid1DBTableView1Field1: TcxGridDBColumn
        DataBinding.FieldName = 'Field1'
      end
      object cxGrid1DBTableView1Field2: TcxGridDBColumn
        DataBinding.FieldName = 'Field2'
      end
    end
    object cxGrid1Level1: TcxGridLevel
      GridView = cxGrid1DBTableView1
    end
  end
  object cxButton1: TcxButton
    Left = 305
    Top = 8
    Width = 154
    Height = 25
    Caption = 'Do the trick'
    TabOrder = 1
    OnClick = cxButton1Click
  end
  object cxMemo1: TcxMemo
    Left = 305
    Top = 39
    Anchors = [akLeft, akTop, akRight, akBottom]
    Lines.Strings = (
      'cxMemo1')
    TabOrder = 2
    Height = 260
    Width = 154
  end
  object dxMemData1: TdxMemData
    Indexes = <>
    SortOptions = []
    Left = 160
    Top = 144
    object dxMemData1Field1: TIntegerField
      FieldName = 'Field1'
    end
    object dxMemData1Field2: TIntegerField
      FieldName = 'Field2'
    end
  end
  object DataSource1: TDataSource
    DataSet = dxMemData1
    Left = 168
    Top = 152
  end
end

フォームの作成時にまず最初に、ランダムなデータを生成します。

procedure TForm20.FormCreate(Sender: TObject);
var
  i: Integer;
begin
  randomize;
  dxMemData1.DisableControls;
  try
    dxMemData1.Open;
    for i := 0 to 999 do
      dxMemData1.AppendRecord([i, Random(500), Random(500)]);
  finally
    dxMemData1.EnableControls;
  end;
end;

私のグリッドはデータセットにバインドされているため、データが画面に表示されます。

ここに私のフォーム定義があります:

type
  TForm20 = class(TForm)
    dxMemData1: TdxMemData;
    dxMemData1Field1: TIntegerField;
    dxMemData1Field2: TIntegerField;
    cxGrid1DBTableView1: TcxGridDBTableView;
    cxGrid1Level1: TcxGridLevel;
    cxGrid1: TcxGrid;
    DataSource1: TDataSource;
    cxGrid1DBTableView1RecId: TcxGridDBColumn;
    cxGrid1DBTableView1Field1: TcxGridDBColumn;
    cxGrid1DBTableView1Field2: TcxGridDBColumn;
    cxButton1: TcxButton;
    cxMemo1: TcxMemo;
    procedure FormCreate(Sender: TObject);
    procedure cxButton1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

次に、ボタンを押すだけです。

procedure TForm20.cxButton1Click(Sender: TObject);
var
  RecNo, i: Integer;
  cxCustomGridRecordViewInfo: TcxCustomGridRecordViewInfo;
  s: string;
begin
  s := Format(
    'You have' + sLineBreak +
    '  %d records in your Dataset' + sLineBreak +
    '  %d records in your grid' + sLineBreak +
    '  %d VISIBLE records in your grid'
    , [
    cxGrid1DBTableView1.DataController.RecordCount,
      cxGrid1DBTableView1.DataController.FilteredRecordCount,
      cxGrid1DBTableView1.ViewInfo.VisibleRecordCount
      ]
      );

  MessageDlg(s, mtInformation, [mbOK], 0);

  cxMemo1.Lines.BeginUpdate;
  cxMemo1.Lines.Clear;

  cxMemo1.Lines.Add(' *** Filtered Records ***');

  for i := 0 to cxGrid1DBTableView1.DataController.FilteredRecordCount - 1 do
  begin
    RecNo := cxGrid1DBTableView1.DataController.FilteredRecordIndex[i];
    cxMemo1.Lines.Add(cxGrid1DBTableView1.DataController.Values[RecNo, 1]);
  end;

  cxMemo1.Lines.Add(' *** Visible Records ***');

  for i := 0 to cxGrid1DBTableView1.ViewInfo.VisibleRecordCount - 1 do
  begin
    cxCustomGridRecordViewInfo := cxGrid1DBTableView1.ViewInfo.RecordsViewInfo[i];
    cxMemo1.Lines.Add(cxCustomGridRecordViewInfo.GridRecord.Values[1]);
  end;

  cxMemo1.Lines.EndUpdate;
end;

フィルターされたレコードは、おそらくフィルターが適用された後にグリッドにあるレコードであることがわかります。可視レコードは、実際に画面に表示されるレコードです。