15

バックグラウンド

2つのサブプロジェクトを持つ基本的なC++サンプルプロジェクトを設定して、Sconsを試しています。

  • Prj1はPrj2に依存するEXEです
  • Prj2は、いくつかの関数をエクスポートするDLLです。

私が遭遇している問題は、ライブラリがその.obj、.pdb、.lib、.dllなどのファイルをSConscriptファイルと同じディレクトリに構築し、EXEがそのファイルをSConscriptと同じディレクトリに構築することです。アプリケーションは、Prj2依存関係とそれ自体の両方を正常に構築します。ただし、他のディレクトリにあるために必要なライブラリが見つからないため、結果のEXEを実行することはできません。

質問

バイナリとデバッグ情報を共通のディレクトリに出力して実行およびデバッグできるようにするために、依存関係のある複数のプロジェクトを取得するにはどうすればよいですか?

考えられる解決策

これは私がこれまで考えてきたことです:

  • VariantDir(以前はBuildDirと呼ばれていました)を使用してみましたが、これは機能しないようです。おそらく私はここで何かを台無しにしています。
  • コンパイラとリンカに(たとえばFo / Fdを介して)ファイルをドロップする場所を明示的に伝えることができる可能性があります(これが最善または唯一の解決策ですか?)
  • 結果のバイナリに対してコピーコマンドを実行します(これはハックのようであり、管理/保守するのが非常に面倒です)

アップデート

以下のファイル構造とファイルの内容を更新して、実用的なソリューション全体を反映させました。彼の洞察に悲しんでくれてありがとう。

指示

この構成では、残念ながら、ビルドディレクトリにcdしてから、以下のコマンドを実行してビルドを実行する必要があります。これを回避するには、適切に機能するエイリアス設定を取得する必要があります。


build> scons ../bin/project1.exe

ファイル構造

    /scons-sample
       /bin
          /release
          /debug
       /build
           SConstruct
           scons_helper.py
       /prj1
           SConscript
           /include
           /src
              main.cpp
       /prj2
          SConscript
          /include
             functions.h
          /src
             functions.cpp        

SConstruct


import os.path

BIN_DIR = '../bin'
OBJ_DIR = './obj'

#--------------------------------------
#            CxxTest Options
#--------------------------------------
CXXTEST_DIR = '../extern/CxxTest/CxxTest-latest'
PERL = 'perl -w'
TESTS = '*.h'
TESTGEN = PERL + CXXTEST_DIR + '/cxxtestgen.pl'
CXXTESTGEN_FLAGS = '--runner=ParenPrinter \
                    --abort-on-fail \
                    --have-eh'

#--------------------------------------
#            Options
#--------------------------------------
SetOption( 'implicit_cache', 1 )

# command line options
opts = Options()
opts.AddOptions(
EnumOption(
            'debug',
            'Debug version (useful for developers only)',
            'no',
            allowed_values = ('yes', 'no'),
            map = { },
            ignorecase = 1
        )
)

#--------------------------------------
#           Environment
#--------------------------------------
env = Environment( 

    options = opts,

    #--------------------------------------
    #           Linker Options
    #--------------------------------------
    LIBPATH = [
                '../extern/wxWidgets/wxWidgets-latest/lib/vc_dll'
              ],

    LIBS =  [
               # 'wxmsw28d_core.lib',
               # 'wxbase28d.lib',
               # 'wxbase28d_odbc.lib',
               # 'wxbase28d_net.lib',
                'kernel32.lib',
                'user32.lib',
                'gdi32.lib',
                'winspool.lib',
                'comdlg32.lib',
                'advapi32.lib',
                'shell32.lib',
                'ole32.lib',
                'oleaut32.lib',
                'uuid.lib',
                'odbc32.lib',
                'odbccp32.lib'
            ],

    LINKFLAGS = '/nologo /subsystem:console /incremental:yes /debug /machine:I386',

    #--------------------------------------
    #           Compiler Options
    #--------------------------------------
    CPPPATH = [
                './include/', 
                '../extern/wxWidgets/wxWidgets-latest/include',
                '../extern/wxWidgets/wxWidgets-latest/vc_dll/mswd'
               ],

    CPPDEFINES = [ 
                    'WIN32',
                    '_DEBUG',
                    '_CONSOLE',
                    '_MBCS',
                    'WXUSINGDLL',
                    '__WXDEBUG__'
                 ],

    CCFLAGS = '/W4 /EHsc /RTC1 /MDd /nologo /Zi /TP /errorReport:prompt'
)

env.Decider( 'MD5-timestamp' )        # For speed, use timestamps for change, followed by MD5
Export( 'env', 'BIN_DIR' )          # Export this environment for use by the SConscript files

#--------------------------------------
#           Builders
#--------------------------------------
SConscript( '../prj1/SConscript' )
SConscript( '../prj2/SConscript' )
Default( 'prj1' )

scons_helper.py


import os.path

#--------------------------------------
#            Functions
#--------------------------------------

# Prepends the full path information to the output directory so that the build
# files are dropped into the directory specified by trgt rather than in the 
# same directory as the SConscript file.
# 
# Parameters:
#   env     - The environment to assign the Program value for
#   outdir  - The relative path to the location you want the Program binary to be placed
#   trgt    - The target application name (without extension)
#   srcs    - The list of source files
# Ref:
#   Credit grieve and his local SCons guru for this: 
#   http://stackoverflow.com/questions/279860/how-do-i-get-projects-to-place-their-build-output-into-the-same-directory-with
def PrefixProgram(env, outdir, trgt, srcs):
    env.Program(target = os.path.join(outdir, trgt), source = srcs)

# Similar to PrefixProgram above, except for SharedLibrary
def PrefixSharedLibrary(env, outdir, trgt, srcs):
    env.SharedLibrary(target = os.path.join(outdir, trgt), source = srcs)

def PrefixFilename(filename, extensions):
    return [(filename + ext) for ext in extensions]

# Prefix the source files names with the source directory
def PrefixSources(srcdir, srcs):
    return  [os.path.join(srcdir, x) for x in srcs]

Prj1のSConscript


import os.path
import sys
sys.path.append( '../build' )
from scons_helper import *

Import( 'env', 'BIN_DIR' )        # Import the common environment

prj1_env = env.Clone()          # Clone it so we don't make changes to the global one

#--------------------------------------
#           Project Options
#--------------------------------------
PROG = 'project1'

#--------------------------------------
#            Header Files
#--------------------------------------
INC_DIR = [
            '../prj2/include'
          ]

HEADERS = [
            ''
          ]

#--------------------------------------
#            Source Files
#--------------------------------------
SRC_DIR = './src'
SOURCES = [
            'main.cpp'
          ]
# Prefix the source files names with the source directory
SOURCES = PrefixSources( SRC_DIR, SOURCES )

#--------------------------------------
#      Compiler and Linker Overrides
#--------------------------------------
prj1_env.Append(
    CPPPATH = INC_DIR,
    LIBS = 'project2',
    LIBPATH = BIN_DIR,

    # Microsoft Visual Studio Specific
    PDB = os.path.join( BIN_DIR, PROG + '.pdb' )
)

#--------------------------------------
#            Builders
#--------------------------------------
PrefixProgram( prj1_env, BIN_DIR, PROG, SOURCES )

Prj2のSConscript


import os.path   
import sys
sys.path.append( '../build' )
from scons_helper import *

Import( 'env', 'BIN_DIR' )        # Import the common environment

prj2_env = env.Clone()          # Clone it so we don't make changes to the global one

#--------------------------------------
#           Project Options
#--------------------------------------
PROG = 'project2'

#--------------------------------------
#            Header Files
#--------------------------------------
INC_DIR = [
             ''
          ]
HEADERS = [
            'functions.h'
          ]

#--------------------------------------
#            Source Files
#--------------------------------------
SRC_DIR = './src/'
SOURCES = [
            'functions.cpp'
          ]
# Prefix the source files names with the source directory
SOURCES = PrefixSources( SRC_DIR, SOURCES )

#--------------------------------------
#      Compiler and Linker Overrides
#--------------------------------------
# Update the environment with the project specific information
prj2_env.Append(
    CPPPATH = INC_DIR,

    # Microsoft Visual Studio Specific
    PDB = os.path.join( BIN_DIR, PROG + '.pdb' )
)

#--------------------------------------
#               Builders
#--------------------------------------
PrefixSharedLibrary( prj2_env, BIN_DIR, PROG, SOURCES )
4

2 に答える 2

6

わかりました 3 回目の試行は魅力です。きれいに保つために、これを新しい回答に入れているだけです。地元の scons グルと話をしたところ、インストール方法は機能するはずですが、もっと簡単な方法があるとのことでした。

実行可能ファイル (または dll) を配置するフル パスを定義するだけです。そう:

prj2_env.Program(target = os.path.join(BIN_DIR,PROG), source = SOURCES )

すべての場所でこれを行う必要がない場合は、グローバル関数を作成できます。

def PrefixProgram(env, trgt, srcs):
    env.Program(target = os.path.join(env.["MY_OUTPUT_DIR"], trgt), source = srcs)

次に、SConscript で次のようにします。

import ('PrefixProgram')
# stuff ...
PrefixProgram(prj2_env, PROG, SOURCES)

環境に独自の属性を追加できることに注意してください。

env["MY_OUTPUT_DIR"]

から来た。私はこれをカフから書いたので、いくつかのマイナーな構文エラーとそうでないものを期待してください. 明らかに、共有ライブラリと静的ライブラリに同じトリックを適用できます。

完全な開示のために、私は地元の scons の第一人者に自分でこれに答える機会を提供しましたが、彼はサイトに夢中になるのではないかと恐れ、辞退しました. :)

于 2008-11-11T14:54:45.797 に答える
3

VariantDirはこれを行う方法です。SconstructはSconscriptファイルをどのように呼び出しますか?また、ドキュメントのこのセクションを読んだことがありますか:http ://www.scons.org/doc/1.1.0/HTML/scons-user/c3271.html (私はあなたが持っていると思います)。


考えれば考えるほど、デフォルトインストールの組み合わせを使いたいと思います

SConscriptsの呼び出しで

env.Install("../bin", <your target exe or dll>)

次に、Sconstructの呼び出しで

env.Alias('install', "../bin")
Default('install')

それでうまくいくはずです。リンクによって、すべてがどのように連携するかが明確になると思います。

于 2008-11-11T02:58:19.097 に答える