2

(私は Antlr の Noob です)... StringTemplates で文法を取得するのに苦労しています。基本的に、私は小さな DSL を書こうとしています。思い通りの文法を取得できます (正しく解析されます) が、ターゲット コードの生成をテンプレートで動作させることができません。だからここに私の文法のスニペットがあります：

grammar Pfig;

options { 
    output=template;  
 language=CSharp2;
 }

conf 
    : globalName
    ;


globalName 
    : 'GlobalName:'  ID
     -> localConf(name ={$ID.text})
    ;

本質を理解するために、かなり単純化しました。基本的に、lex/parse が「GlobalName: Foo」に遭遇したときに、「localConf」と呼ばれる StringTemplate に基づいてテキストを吐き出したいのです。とても簡単です。

それでは、テスト アプリでパーサーを起動して、入力ファイルを処理してみましょう。

// C# processing a file with the lex/parser.
// the 'app.pfig' file just has one line that reads 'GlobalName: Bla'
using (FileStream fs = File.OpenRead("c:\\app.pfig"))
        {
            PfigParser parser = new PfigParser(new CommonTokenStream(
                new PfigLexer(new ANTLRInputStream(fs))));

            using (TextReader tr = File.OpenText("./Pfig.stg"))
            {
                parser.TemplateLib = new StringTemplateGroup(tr);
            }

            var parseResult = parser.conf();
            string code = parseResult.Template.ToString(); // Fail: template is null
        }

パーサー コードをステップ実行して、テキストが正しく識別され、stringTemplate が正しく適用されていることを確認できます。問題は、この 'globalName' ルールが 'conf' のサブルールであるため、直接実行されないことです。メソッドはそれを見つけて返すだけです。しかし、'Conf' メソッドの呼び出しは、サブルールからの戻り値を保持しません。これは、最終行の結果のテンプレートが null であることを意味します。

文法で「conf」ルールを取り除き、「globalName」を直接呼び出すと、機能します (スタック上の唯一のルールであるため)。しかし、明らかに複数のルールが必要です。Java でパーサーを生成しましたが、同じことを行います。

// antlr generated parser code
public PfigParser.conf_return conf() // throws RecognitionException [1]
{   
    PfigParser.conf_return retval = new PfigParser.conf_return();

    try 
 {
        {
         PushFollow(FOLLOW_globalName_in_conf30);
         globalName(); // <- it calls globalName() but doesn't keep the return.
         state.followingStackPointer--;

        }

        retval.Stop = input.LT(-1);

    }

// snip

テンプレート アプローチが Antlr でどのように機能するかについて、基本的な概念を理解していないことは簡単にわかります。これは私の問題だと確信していますが、私は自分が何を間違っているかを知るのが苦手です...私が見た例は、実際のコードのテンプレート出力を実際に示していません.

4

2 に答える 2

2

私は最終的にテンプレートのアイデアをキャッチしたようです:)テンプレートは、階層的に別のものに「ネスト」する必要があります。次の例は問題なく動作します。

TemplatesTest.g:

grammar TemplatesTest;

options
{
    output=template;
    language=CSharp2;
}

ID  :   ('a'..'z'|'A'..'Z'|'_') ('a'..'z'|'A'..'Z'|'0'..'9'|'_')*
    ;

INT :   '0'..'9'+
    ;

COMMENT
    :   '//' ~('\n'|'\r')* '\r'? '\n' {$channel=HIDDEN;}
    |   '/*' ( options {greedy=false;} : . )* '*/' {$channel=HIDDEN;}
    ;

WS  :   ( ' '
        | '\t'
        | '\r'
        | '\n'
        ) {$channel=HIDDEN;}
    ;

STRING
    :  '\'' ( ESC_SEQ | ~('\\'|'\'') )* '\''
    ;

fragment
HEX_DIGIT : ('0'..'9'|'a'..'f'|'A'..'F') ;

fragment
ESC_SEQ
    :   '\\' ('b'|'t'|'n'|'f'|'r'|'\"'|'\''|'\\')
    |   UNICODE_ESC
    |   OCTAL_ESC
    ;

fragment
OCTAL_ESC
    :   '\\' ('0'..'3') ('0'..'7') ('0'..'7')
    |   '\\' ('0'..'7') ('0'..'7')
    |   '\\' ('0'..'7')
    ;

fragment
UNICODE_ESC
    :   '\\' 'u' HEX_DIGIT HEX_DIGIT HEX_DIGIT HEX_DIGIT
    ;

doc
    : (e+=expr)+ -> doc(expressions={$e})
    ;

expr
    : ID '=' INT -> expression(id={$ID.text}, value={$INT.text})
    ;

TemplatesTest.stg:

group TemplatesTest;

doc(expressions) ::=
<<
srart expressions
<expressions; separator="\n">
end
>>

expression(id, value) ::= 
<<
<id> := <value>;
>>

C# コードをテストします。

var lexer = new TemplatesTestLexer(new ANTLRFileStream("sample.txt"));
var parser = new TemplatesTestParser(new CommonTokenStream(lexer));

using (var reader = new StreamReader("TemplatesTest.stg"))
{
  parser.TemplateLib = new StringTemplateGroup(reader);
}

var doc = parser.doc();
Console.WriteLine(doc.Template);

サンプル入力:

a = 5
b = 6
c = 7

出力は次のとおりです。

srart expressions
a := 5;
b := 6;
c := 7;
end
于 2011-01-10T14:00:19.803 に答える
2

基本的に、テンプレート出力をサブルールに明示的に転送する必要があります。

conf 
    : a=globalName -> {$a.st}
    ;

美しくはありませんが、機能します。

于 2010-08-29T08:15:54.300 に答える