1

SQL Server 2008 データベース サーバーで診断レポートを実行したいと考えています。

すべてのデータベースをループしてから、各データベースについて、各テーブルを調べたいと思います。しかし、各テーブルを ( で) 見に行くとtbl_cursor、常にデータベース内のテーブルが選択されます'master'。

それは私のtbl_cursor選択によるものだと思います：

    SELECT table_name FROM information_schema.tables WHERE table_type = 'base table'

これを修正するにはどうすればよいですか?

コード全体は次のとおりです。

SET NOCOUNT ON

DECLARE @table_count INT
DECLARE @db_cursor VARCHAR(100)
DECLARE database_cursor CURSOR FOR
SELECT name FROM sys.databases where name<>N'master'
OPEN database_cursor
FETCH NEXT FROM database_cursor INTO @db_cursor
WHILE @@Fetch_status = 0
BEGIN

    PRINT @db_cursor    
    SET @table_count = 0

    DECLARE @table_cursor VARCHAR(100)
    DECLARE tbl_cursor CURSOR FOR
    SELECT table_name FROM information_schema.tables WHERE table_type = 'base table'
    OPEN tbl_cursor
    FETCH NEXT FROM tbl_cursor INTO @table_cursor
    WHILE @@Fetch_status = 0
    BEGIN

        DECLARE @table_cmd NVARCHAR(255)
        SET @table_cmd = N'IF NOT EXISTS( SELECT TOP(1) *  FROM ' + @table_cursor + ') PRINT N''     Table ''''' + @table_cursor + ''''' is empty'' '
        --PRINT @table_cmd --debug
        EXEC sp_executesql @table_cmd
        SET @table_count = @table_count + 1

    FETCH NEXT FROM tbl_cursor INTO @table_cursor
    END
    CLOSE tbl_cursor
    DEALLOCATE tbl_cursor

    PRINT @db_cursor + N' Total Tables : ' + CAST( @table_count as varchar(2) ) 
    PRINT N'' -- print another blank line   
    SET @table_count = 0    

FETCH NEXT FROM database_cursor INTO @db_cursor
END
CLOSE database_cursor
DEALLOCATE database_cursor




SET NOCOUNT OFF
4

3 に答える 3

2

テーブル変数を使用する方が簡単なので、別の動的 SQL ステートメントを使用して @tablist に行を追加できます

SET NOCOUNT ON

DECLARE @table_count INT
DECLARE @dblist TABLE (DBName VARCHAR(100))
DECLARE @tablist TABLE (TableName VARCHAR(100))
DECLARE @dbname varchar(100), @tabname varchar(100)

INSERT @dblist 
SELECT name FROM sys.databases where name<>N'master'

SELECT TOP 1 @dbname = DBName FROM @dblist
WHILE @@ROWCOUNT <> 0
BEGIN

    INSERT @tablist (tableName)
    EXEC ('SELECT table_name FROM ' + @dbname + '.information_schema.tables WHERE table_type = ''base table'' ')

    SELECT TOP 1 @tabname = tableName FROM @tablist
    WHILE @@ROWCOUNT <> 0
    BEGIN

--do my stuff

        DELETE @tablist WHERE tableName =  @tabname
        SELECT TOP 1 @tabname = tableName FROM @tablist
    END

    DELETE @dblist WHERE DBName =  @dbname
    SELECT TOP 1 @dbname = DBName FROM @dblist
END
于 2010-05-11T19:26:49.290 に答える
2

問題は、実際にはマスター データベース コンテキストで INFORMATION_SCHEMA.TABLES クエリを常に実行しているためです。

クエリを DB 名で完全に修飾するには、tbl_cursor ブロックを動的 SQL に変換する必要があります。

例えば

SELECT table_name FROM YourDatabase.INFORMATION_SCHEMA.TABLES WHERE....

基本的に、そのカーソルに対して実行する必要があるものです。

于 2010-05-11T19:30:51.157 に答える
0

動的 SQL を作成しなければならない場合があります。information_schema は、このクエリを実行している現在アクティブなデータベースからのみオブジェクトを取得するためです。

あなたはsys.objectsを試すことができます

于 2010-05-11T19:31:35.683 に答える