1

私は鯉を捕まえようとしました-警告：

 carp "$start is > $end" if (warnings::enabled()); )

eval {}を使用しましたが、機能しませんでした。evalドキュメントを調べたところ、eval構文エラー、実行時エラー、または実行されたダイステートメントのみが検出されることがわかりました。

どうすれば鯉の警告をキャッチできますか？

#!/usr/bin/env perl
use warnings;
use strict;
use 5.012;
use List::Util qw(max min);
use Number::Range;

my @array;
my $max = 20;
print "Input (max $max): ";
my $in = <>;

$in =~ s/\s+//g;
$in =~ s/(?<=\d)-/../g;

eval {
    my $range = new Number::Range( $in );
    @array = sort { $a <=> $b } $range->range;
};
if ( $@ =~ /\d+ is > \d+/ ) { die $@ }; # catch the carp-warning doesn't work 

die "Input greater than $max not allowed $!" if defined $max and max( @array ) > $max;
die "Input '0' or less not allowed $!" if min( @array ) < 1;
say "@array";
4

2 に答える 2

3

鯉は死ぬことはなく、警告を出すだけなので、evalなどで捕まえるものは何もありません。ただし、警告ハンドラーをローカルで上書きして、警告がstderrに送信されないようにすることができます。

#!/usr/bin/env perl

use warnings;
use strict;

use Carp;

carp "Oh noes!";

{
    local $SIG{__WARN__} = sub {
        my ($warning) = @_;

        # Replace some warnings:
        if($warning =~ /replaceme/) {
            print STDERR "My new warning.\n";
        }
        else {
            print STDERR $warning;
        }

        # Or do nothing to silence the warning.
    };

    carp "Wh00t!";
    carp "replaceme";
}

carp "Arrgh!";

出力：

Oh noes! at foo.pl line 8
Wh00t! at foo.pl line 25
My new warning.
Arrgh! at foo.pl line 29

ほとんどの場合、代わりにコイの原因を修正することをお勧めします。

于 2010-05-12T10:56:02.877 に答える
3

carpあなたのコメントに基づいて、私の理解はあなたが致命的な警告にしたいということです。

ターゲットパッケージ内のすべての警告を致命的なエラーにすることが許容される場合は、carpモンキーパッチを適用できますcarp。

カーピングパッケージ：

package Foo;
use Carp;

sub annoying_sub {
    carp "Whine whine whine";
}

メインプログラム：

use Foo;

*Foo::carp = \&Foo::croak;

Foo::annoying_sub();

モンキーパッチを動的スコープに制限する場合は、次を使用できますlocal。

use Foo;

Foo::annoying_sub();  # non-fatal

{   local *Foo::carp = \&Foo::croak;
    Foo::annoying_sub();  # Fatal
}
于 2010-05-12T16:06:01.323 に答える