arrays - Groovy Simple JSON 配列ビルダー

Question

JSON で単純な JSON 配列を作成する必要がありますが、ループでは反復ごとに最初の値が上書きされます。

def jsonBuilder = new groovy.json.JsonBuilder()
contact.each {
            jsonBuilder.contact(
                    FirstName:  it.getFirstName(),
                    LastName:  it.getLastName(),
                    Title: it.getTitle(),       
            )
    }

単純な JSON だけを返し、すべての反復の値を上書きし、最後の値だけを保持します。GroovyでJSON配列を構築するための構文は何ですか?

score 18 · Accepted Answer

トリックはcollect、連絡先のリストからです。contractリストの構造が以下のようであると仮定すると、以下の方法jsonBuilderで使用されます。

def contact = [ 
    [ getFirstName : { 'A' }, getLastName : { 'B' }, getTitle : { 'C' } ], 
    [ getFirstName : { 'D' }, getLastName : { 'E' }, getTitle : { 'F' } ], 
    [ getFirstName : { 'G' }, getLastName : { 'H' }, getTitle : { 'I' } ]     
]

def jsonBuilder = new groovy.json.JsonBuilder()

jsonBuilder {
    contacts contact.collect { 
        [ 
            FirstName: it.getFirstName(), 
            LastName: it.getLastName(), 
            Title: it.getTitle() 
        ] 
    }
}

println jsonBuilder.toPrettyString()


// Prints
{
    "contacts": [
        {
            "FirstName": "A",
            "LastName": "B",
            "Title": "C"
        },
        {
            "FirstName": "D",
            "LastName": "E",
            "Title": "F"
        },
        {
            "FirstName": "G",
            "LastName": "H",
            "Title": "I"
        }
    ]
}

最終的な構造として JSONObject ではなく JSONArray を探している場合は、次を使用します。

jsonBuilder(
    contact.collect { 
        [ 
            FirstName: it.getFirstName(), 
            LastName: it.getLastName(), 
            Title: it.getTitle() 
        ]
    }
)

// OP
[
    {
        "FirstName": "A",
        "LastName": "B",
        "Title": "C"
    },
    {
        "FirstName": "D",
        "LastName": "E",
        "Title": "F"
    },
    {
        "FirstName": "G",
        "LastName": "H",
        "Title": "I"
    }
]

意味がありませんが、以下のような構造が必要な場合

[
    {
        "contact": {
            "FirstName": "A",
            "LastName": "B",
            "Title": "C"
        }
    },
    {
        "contact": {
            "FirstName": "D",
            "LastName": "E",
            "Title": "F"
        }
    },
    {
        "contact": {
            "FirstName": "G",
            "LastName": "H",
            "Title": "I"
        }
    }
]

次に使用します

jsonBuilder(
    contact.collect { 
        [ 
            contact : [ 
                FirstName: it.getFirstName(), 
                LastName: it.getLastName(), 
                Title: it.getTitle() 
            ] 
        ]
    }
)

score 2 · Accepted Answer

JsonBuilder を使用すると、うまく機能しません.each。こういうことに使っcollectてきました。以下は、あなたのケースでうまくいくはずの例です:

static class Contact {
    String firstName
    String lastName
    String title
}

Contact c1 = new Contact(firstName: "Tom", "lastName": "Potter", title: "Mr")
Contact c2 = new Contact(firstName: "Ryan", "lastName": "Olson", title: "Mr")

List<Contact> contactList = [c1,c2]
def jsonBuilder = new groovy.json.JsonBuilder()

jsonBuilder {
   contacts(contacts.collect{[firstName: it.firstName, lastName: it.lastName, title: it.title]})
}
println jsonBuilder.toPrettyString()

この結果は次のとおりです。

{
    "contacts": [
        {
            "firstName": "Tom"
        },
        {
            "firstName": "Ryan"
        }
    ]
}

arrays - Groovy Simple JSON 配列ビルダー

3 に答える 3

Related

Reference