1

だから私は単純な C++ プログラムの文法を書こうとしています。

現在の文法は次のようになります。

PDefs. Program ::= [Def] ;
terminator Def "" ;
comment "//" ;
comment "/*" "*/" ;
comment "#" ;
DFun. Def ::= Type Id "(" [Arg] ")" "{" [Stm] "}" ;
separator Arg "," ;
terminator Stm "" ;
ADecl. Arg ::= Type Id ;
SExp. Stm ::= Exp ";" ;
SDecl. Stm ::= Type Id ";" ;
SDecls. Stm ::= Type Id "," [Id] ";" ;
SInit. Stm ::= Type Id "=" Exp ";" ;
SReturn. Stm ::= "return" Exp ";" ;
SWhile. Stm ::= "while" "(" Exp ")" Stm ;
SBlock. Stm ::= "{" [Stm] "}" ;
SIfElse. Stm ::= "if" "(" Exp ")" Stm "else" Stm ;


EInt. Exp15 ::= Integer ;
EDouble. Exp15 ::= Double ;
ETrue. Exp15 ::= "true" ;
EFalse. Exp15 ::= "false" ;
EId. Exp15 ::= Id ;
EApp. Exp15 ::= Id "(" [Exp] ")" ;
EPIncr. Exp14 ::= Exp15 "++" ;
EPDecr. Exp14 ::= Exp15 "--" ;
EIncr. Exp13 ::= "++" Exp14 ;
EDecr. Exp13 ::= "--" Exp14 ;
ETimes. Exp12 ::= Exp12 "*" Exp13 ;
EDiv. Exp12 ::= Exp12 "/" Exp13 ;
EPlus. Exp11 ::= Exp11 "+" Exp12 ;
EMinus. Exp11 ::= Exp11 "-" Exp12 ;
ELt. Exp9 ::= Exp9 "<" Exp10 ;
EGt. Exp9 ::= Exp9 ">" Exp10 ;
ELtEq. Exp9 ::= Exp9 "<=" Exp10 ;
EGtWq. Exp9 ::= Exp9 ">=" Exp10 ;
EEq. Exp8 ::= Exp8 "==" Exp9 ;
ENEq. Exp8 ::= Exp8 "!=" Exp9 ;
EAnd. Exp4 ::= Exp4 "&&" Exp5 ;
EOr. Exp3 ::= Exp3 "||" Exp4 ;
EAss. Exp2 ::= Exp3 "=" Exp2 ;

coercions Exp 15 ;
separator Exp "," ;
separator Id "," ;

Tbool. Type ::= "bool" ;
Tdouble. Type ::= "double" ;
Tint. Type ::= "int" ;
Tvoid. Type ::= "void" ;

token Id (letter (letter | digit | '_')*) ;

これは、解析する必要がある単純な C++ プログラムです。

// a small C++ program
#include <iostream>

int main()
{
    std::cout << "Hello, world!" << std::endl;
    return 0;
}

そのため、解析しようとすると、std::cout 行を意味する 6 行目にエラーが表示されます。私はbnfが初めてなので、これを解決するために「考える」方法がわかりません。誰かがこのような状況を解決する方法の例を挙げることができれば素晴らしいでしょう.!

ありがとうございました！

4

1 に答える 1

1

いくつかのルールが欠落しているため、失敗した行を解析できません:

  1. 修飾された idを解析するためのルールが必要です。
    修飾 ID は特殊なタイプの ID であり、(目的に合わせて) (非修飾) ID と同じ状況で使用できます。
    std::coutとstd::endlは修飾された ID であり、それらの (簡略化された) ルールは次のようになります。

    <qualified_id> ::= <nested_name_specifier> <unqualified_id>
<nested_name_specifier> ::= <namespace_name> "::" <nested_name_specifier>?

    （目的のために）<unqualified_id>と<namespace_name>を識別子として扱うことができます。

  2. <<operatorを使用して式を解析するためのルールが必要です。
    この追加のタイプの式の (簡略化された) ルールは、次のようになります。

    <shift_left_expression> ::= <other_expression>
<shift_left_expression> ::= <shift_left_expression> "<<" <other_expression>

    （あなたの目的のために）<other_expression>は、他のタイプの式を表します。

  3. 文字列リテラルを解析するための規則が必要です。
    文字列リテラルはリテラルの一種であり、識別子のように式の一部として (目的に応じて) 使用できます。
    "Hello, world!"は文字列リテラルであり、それらの (簡略化された) ルールは次のようになります。

    <string_literal> ::= "\"" <s_char_sequence>? "\""
<s_char_sequence> ::= <s_char>
<s_char_sequence> ::= <s_char_sequence> <s_char>

    <s_char>は、文字列リテラル内で許可する任意の文字です (単純にするために、その文字を許可しないでください")。

于 2015-01-30T10:50:26.940 に答える