1

Fascicle 1 の Knuth のプログラム P を再実装しています: 最初の 500 個の素数を生成します。プログラムは最初の 25 個の素数を問題なく生成します。そのコードは以下のとおりです。

$ cat progp.S
/* print the first 500 primes */

#define n       %bx
#define j       %r12
#define k       %r13
#define pk      %r14d

        .data
fmt:    .asciz  "%d\n"
x:      .space 1000

        .text
        .globl  main
        .type   main, @function
main:
        pushq   %rbp
        movq    %rsp, %rbp
        xorq    %rbx, %rbx
        movw    $2, x
        movw    $3, n
        movq    $1, j
Mtwo:
        movw    n, x(,j,2)
        incq    j
Mthree:
        cmpq    $500, j
        je      end
Mfour:
        addw    $2, n
Mfive:
        movq    $1, k
Msix:
        movzwl  x(,k,2), pk
        movzwl  n, %eax
        xorq    %rdx, %rdx
        divl    pk
        cmpl    $0, %edx
        je      Mfour
Mseven:
        cmpl    pk, %eax
        jle     Mtwo
Meight:
        incq    k
        jmp     Msix
end:
        xorq    j, j
loop:
        leaq    fmt, %rdi
        movzwl  x(,j,2), %esi
        call    printf
        incq    j
        cmpq    $25, j
        je      bye
        jmp     loop
bye:
        movl    $0, %edi
        callq   exit
        leave
        ret
        .size   main,.-main
        .end

Mthree の比較を 25 に減らすと、プログラムは問題ありません。それ以上の場合、プログラムは失敗するか、printf でハングします。

私はそれを組み立てています：

cc -static progp.S

また、printf を呼び出さなくても、gdb の "end" にブレークポイントを設定するとわかるように、最初の 500 個の素数が正常に生成されることも付け加えることができます。

$ gdb ./a.out
(gdb) b end
Breakpoint 1 at 0x400531
(gdb) run
Starting program: /home/ben/src/hg/asm/knuth/a.out 

Breakpoint 1, 0x0000000000400531 in end ()
(gdb) p $rbx
$1 = 3571

printf を呼び出そうとするとすぐに失敗するので、スタックで何かばかげたことをしていると思います。

4

1 に答える 1

3

printfx86-64%raxでは、関数に浮動小数点引数の量を伝える値が期待されます。あなたの場合、そのような引数はないので、明確です%rax（クリア%eaxもクリアします%rax）。あなたのプログラムは、変更によって正常に動作するようです:

...
loop:
        leaq    fmt, %rdi
        movzwl  x(,j,2), %esi
        xor     %eax, %eax
        call    printf
...
于 2015-02-01T22:09:02.753 に答える