2

これは私のノードのグリッドです:

代替テキスト

A* パスファインディング アルゴリズムを使用して、その上でオブジェクトを移動しています。通常は問題なく動作しますが、時々間違った動作をします:

  • 3 から 1 に移動するときは 2 を経由しますが、1 から 3 に移動するときは 4 を経由します。
  • 3 と 5 の間を移動する場合、6 を経由する短い方法ではなく、いずれかの方向に 4 を経由します。

何が間違っている可能性がありますか？これが私のコードです（AS3）：

    public static function getPath(from:Point, to:Point, grid:NodeGrid):PointLine {

        // get target node
        var target:NodeGridNode = grid.getClosestNodeObj(to.x, to.y);

        var backtrace:Map = new Map();
        var openList:LinkedSet = new LinkedSet();
        var closedList:LinkedSet = new LinkedSet();

        // begin with first node
        openList.add(grid.getClosestNodeObj(from.x, from.y));

        // start A*
        var curNode:NodeGridNode;
        while (openList.size != 0) {

            // pick a new current node
            if (openList.size == 1) {
                curNode = NodeGridNode(openList.first);
            }
            else {
                // find cheapest node in open list
                var minScore:Number = Number.MAX_VALUE;
                var minNext:NodeGridNode;
                openList.iterate(function(next:NodeGridNode, i:int):int {
                    var score:Number = curNode.distanceTo(next) + next.distanceTo(target);
                    if (score < minScore) {
                        minScore = score;
                        minNext = next;
                        return LinkedSet.BREAK;
                    }
                    return 0;
                });
                curNode = minNext;
            }

            // have not reached
            if (curNode == target) break;
            else {
                // move to closed
                openList.remove(curNode);
                closedList.add(curNode);

                // put connected nodes on open list
                for each (var adjNode:NodeGridNode in curNode.connects) {
                    if (!openList.contains(adjNode) && !closedList.contains(adjNode)) {
                        openList.add(adjNode);
                        backtrace.put(adjNode, curNode);
                    }
                }
            }
        }

        // make path
        var pathPoints:Vector.<Point> = new Vector.<Point>();
        pathPoints.push(to);
        while(curNode != null) {
            pathPoints.unshift(curNode.location);
            curNode = backtrace.read(curNode);
        }
        pathPoints.unshift(from);
        return new PointLine(pathPoints);

    }

NodeGridNode::distanceTo()

    public function distanceTo(o:NodeGridNode):Number {
        var dx:Number = location.x - o.location.x;
        var dy:Number = location.y - o.location.y;
        return Math.sqrt(dx*dx + dy*dy);
    }
4

2 に答える 2

1

私がここで見る問題は行です

if (!openList.contains(adjNode) && !closedList.contains(adjNode))

adjNode は、以前に別のノードから到達していたにもかかわらず、現在のノードを介して到達する方が簡単 (短い) 場合があります。これは、それが openList にあることを意味します。

于 2010-05-19T09:29:04.397 に答える
0

バグが見つかりました：

                openList.iterate(function(next:NodeGridNode, i:int):int {
                    var score:Number = curNode.distanceTo(next) + next.distanceTo(target);
                    if (score < minScore) {
                        minScore = score;
                        minNext = next;
                        return LinkedSet.BREAK;
                    }
                    return 0;
                });

(return LinkedSet.BREAK通常のループで break ステートメントのように機能する) は存在しないはずです。これにより、開いているリストの最初のノードが、最も安いノードではなく常に選択されます。

于 2010-05-19T09:32:03.697 に答える