2

PROC SGPLOTエラーバーが線で結ばれた散布図としてデータを表示し、凡例にステートメントの点とscatterステートメントの線の両方を使用させたいと思いseriesます。

ここにいくつかのデータがあります：

data dat;
  input x y high low grp $;
  cards;
1 2.50 2.90 2.00 A
2 1.90 2.35 1.45 A
3 1.75 2.25 1.25 A
1 2.10 2.50 1.70 B
2 2.00 2.40 1.60 B
3 1.80 2.20 1.40 B
;
run;

調整したいコード：

proc sgplot data=dat;
  scatter x=x y=y / yerrorupper=high yerrorlower=low group=grp
                    groupdisplay=cluster clusterwidth=0.1
                    markerattrs=(size=7 symbol=circlefilled);
  series x=x y=y / group=grp groupdisplay=cluster clusterwidth=0.1;
  xaxis label='Time' values=(1,2,3);
  yaxis label='Response' min=0 max=3.5;
  keylegend / location=inside position=topright title="Group";
run;

現在の出力:

ここに画像の説明を入力

プロットにあるように、記号が凡例の線の上にあるように、凡例にAとのそれぞれのインスタンスを 1 つだけ含めたいと思います。Bこれどうやってするの？

4

1 に答える 1

2

SERIES プロットにマーカーを追加し、凡例にのみシリーズを使用します。

proc sgplot data=dat;
  scatter x=x y=y / yerrorupper=high yerrorlower=low group=grp
                    groupdisplay=cluster clusterwidth=0.1
                    name="scatter";
  series x=x y=y / markers markerattrs=(size=7 symbol=circlefilled)
                   group=grp groupdisplay=cluster clusterwidth=0.1 name="series";
  xaxis label='Time' values=(1,2,3);
  yaxis label='Response' min=0 max=3.5;
  keylegend "series" / location=inside position=topright title="Group";
run;

これはあなたが望むものだと思います： ここに画像の説明を入力

于 2015-03-31T16:11:10.370 に答える