5

私はプロローグが初めてです。0 ～ 9 の数値を他の 0 ～ 9 の数値に加算し、0 ～ 18 の解を生成する整数加算器を作成する必要があります。これは私がやりたいことです：

% pseudo code
add(in1, in2, out) :-
    in1 < 10,
    in2 < 10,
    out < 18.

私はこのようにそれを呼び出すことができるようにしたいと思います:

有効な追加かどうかを確認するには:

?- add(1,2,3).
true.
?- add(1,2,4).
false.

1 つの変数が欠落している場合:

?- add(X,2,3).
X = 1.
?- add(1,4,X).
X = 5.

複数の変数が欠落している場合:

?- add(X,Y,Z).
% Some output that would make sense.  Some examples could be:
X=1, Y=1, Z=2 ;
X=2, Y=1, Z=3 ......

これはおそらく非常に単純な質問であり、おそらく非常に簡単なことだと思います。ただし、Prologチュートリアルによると、私は使用しています:

「統一とは異なり、算術比較演算子演算子は変数に値を与えるために使用できません。両側のすべての項がインスタンス化された場合にのみ評価できます。」

4

3 に答える 3

6

最新のPrologシステムはすべて、有限ドメイン制約を提供します。これは、（is/2や>/2などのより低レベルの算術述語とは対照的に）すべての方向で使用できる真の関係です。SWI-Prologの場合：

:- use_module(library(clpfd)).

plus(X, Y, Z) :-
        [X,Y] ins 0..9,
        X + Y #= Z.

あなたの例の結果：

?- plus(1,2,3).
true.

?- plus(1,2,4).
false.

?- plus(X,2,3).
X = 1.

?- plus(1,4,X).
X = 5.

?- plus(X,Y,Z).
X in 0..9,
X+Y#=Z,
Y in 0..9,
Z in 0..18.

述語はすべての方向で使用できるため、方向を意味するため、「add / 3」と呼ぶことはもはや意味がありませんが、述語は関係がいつ成立するかを正確に記述し、したがってより一般的です。

于 2010-06-06T01:40:52.800 に答える
1

これはどうですか？：

add(X,Y,Z) :-
        Z is X + Y,
        X < 10,
        Y < 10,
        Z < 19.

問題: これは、 が呼び出しの前にインスタンス化されるadd(1,1,X)ため、フォームのクエリではうまく機能しますが、 を尋ねると失敗します。クエリの種類を区別するために使用できます (変数がインスタンス化されていないかどうかを示します) が、それは大変な作業のように思えます。Z<add(X,1,2)var/1var/1

于 2010-06-05T20:22:44.657 に答える
0

解決：

lessThanTen(9).
lessThanTen(8).
lessThanTen(7).
lessThanTen(6).
lessThanTen(5).
lessThanTen(4).
lessThanTen(3).
lessThanTen(2).
lessThanTen(1).
lessThanTen(0).

addSimple(Add1,Add2,Sol) :-
    lessThanTen(Add1),
    lessThanTen(Add2),
    Sol is Add1+Add2.
于 2010-06-05T17:27:57.853 に答える