19

通常、Delphi では、'array of const' メソッドを使用して、可変数の引数を持つ関数を宣言します。ただし、C で記述されたコードとの互換性のために、関数宣言に追加できるあまり知られていない 'varargs' ディレクティブがあります (Rudy の優れた ' Pitfalls of convering ' ドキュメントを読んでいるときにこれを学びました)。

例として、次のように宣言された C の関数を使用できます。

void printf(const char *fmt, ...)

Delphi では、次のようになります。

procedure printf(const fmt: PChar); varargs;

私の質問は次のとおりです。「varargs」ディレクティブで定義されたメソッドを実装するときに、スタックの内容を取得するにはどうすればよいですか?

va_start()、va_arg()、および va_end() 関数の Dephi 翻訳など、このためのツールが存在することを期待しますが、これはどこにも見つかりません。

助けてください！

PS: 'why' や 'const の配列' の代替案についての議論から脱線しないでください - Xbox ゲーム内の関数用の C ライクなパッチを作成するためにこれが必要です (sourceforge の Delphi Xbox エミュレータ プロジェクト 'Dxbx' を参照してください)。詳細については）。

4

3 に答える 3

20

OK、あなたの質問の説明は、DelphiでCインポートを実装する必要があることを意味していると思います。その場合、varargsを自分で実装する必要があります。

必要な基本的な知識は、x86でのC呼び出し規約です。スタックは下向きに成長し、Cは引数を右から左にプッシュします。したがって、最後に宣言された引数のサイズだけインクリメントされた後、最後に宣言された引数へのポインタは、末尾の引数リストを指します。それ以降は、引数を読み取り、適切なサイズでポインターをインクリメントして、スタックの奥深くに移動するだけです。32ビットモードのx86スタックは、通常4バイトで整列されます。これは、バイトとワードが32ビット整数として渡されることも意味します。

とにかく、これはデータを読み取る方法を示すデモプログラムのヘルパーレコードです。Delphiは非常に奇妙な方法で拡張型を渡しているように見えることに注意してください。ただし、10バイトのフロートはCで一般的に広く使用されておらず、最新のMS CであるIIRCでも実装されていないため、心配する必要はありません。

{$apptype console}

type  
  TArgPtr = record
  private
    FArgPtr: PByte;
    class function Align(Ptr: Pointer; Align: Integer): Pointer; static;
  public
    constructor Create(LastArg: Pointer; Size: Integer);
    // Read bytes, signed words etc. using Int32
    // Make an unsigned version if necessary.
    function ReadInt32: Integer;
    // Exact floating-point semantics depend on C compiler.
    // Delphi compiler passes Extended as 10-byte float; most C
    // compilers pass all floating-point values as 8-byte floats.
    function ReadDouble: Double;
    function ReadExtended: Extended;
    function ReadPChar: PChar;
    procedure ReadArg(var Arg; Size: Integer);
  end;

constructor TArgPtr.Create(LastArg: Pointer; Size: Integer);
begin
  FArgPtr := LastArg;
  // 32-bit x86 stack is generally 4-byte aligned
  FArgPtr := Align(FArgPtr + Size, 4);
end;

class function TArgPtr.Align(Ptr: Pointer; Align: Integer): Pointer;
begin
  Integer(Result) := (Integer(Ptr) + Align - 1) and not (Align - 1);
end;

function TArgPtr.ReadInt32: Integer;
begin
  ReadArg(Result, SizeOf(Integer));
end;

function TArgPtr.ReadDouble: Double;
begin
  ReadArg(Result, SizeOf(Double));
end;

function TArgPtr.ReadExtended: Extended;
begin
  ReadArg(Result, SizeOf(Extended));
end;

function TArgPtr.ReadPChar: PChar;
begin
  ReadArg(Result, SizeOf(PChar));
end;

procedure TArgPtr.ReadArg(var Arg; Size: Integer);
begin
  Move(FArgPtr^, Arg, Size);
  FArgPtr := Align(FArgPtr + Size, 4);
end;

procedure Dump(const types: string); cdecl;
var
  ap: TArgPtr;
  cp: PChar;
begin
  cp := PChar(types);
  ap := TArgPtr.Create(@types, SizeOf(string));
  while True do
  begin
    case cp^ of
      #0: 
      begin
        Writeln;
        Exit;
      end;

      'i': Write(ap.ReadInt32, ' ');
      'd': Write(ap.ReadDouble, ' ');
      'e': Write(ap.ReadExtended, ' ');
      's': Write(ap.ReadPChar, ' ');
    else
      Writeln('Unknown format');
      Exit;
    end;
    Inc(cp);
  end;
end;

type
  PDump = procedure(const types: string) cdecl varargs;
var
  MyDump: PDump;

function AsDouble(e: Extended): Double;
begin
  Result := e;
end;

function AsSingle(e: Extended): Single;
begin
  Result := e;
end;

procedure Go;
begin
  MyDump := @Dump;

  MyDump('iii', 10, 20, 30);
  MyDump('sss', 'foo', 'bar', 'baz');

  // Looks like Delphi passes Extended in byte-aligned
  // stack offset, very strange; thus this doesn't work.
  MyDump('e', 2.0);
  // These two are more reliable.
  MyDump('d', AsDouble(2));
  // Singles passed as 8-byte floats.
  MyDump('d', AsSingle(2));
end;

begin
  Go;
end.
于 2008-11-18T12:32:14.017 に答える
2

私はこれを見つけました（私たちが知っている男から:)）

これを適切に記述するには、Delphi の組み込みアセンブラである BASM を使用し、呼び出しシーケンスを asm でコーディングする必要があります。うまくいけば、あなたは何をする必要があるかについての良い考えを持っています. 行き詰まった場合は、おそらく .basm グループの投稿が役立つでしょう。

于 2008-11-18T10:56:43.223 に答える
0

Delphi では、varargs ルーチンを実装できません。これを使用する外部 cdecl 関数をインポートする場合にのみ機能します。

varargs は cdecl 呼び出し規約に基づいているため、基本的には、アセンブリやさまざまな種類のポインター操作を使用して、Delphi で自分で再実装する必要があります。

于 2008-11-18T10:59:23.920 に答える