1

前任者から「継承」したASPコードがいくつかあります（いいえ、現時点では更新するオプションはありません...議会だけでなく、他のすべての外国の行為も必要になります）。ページの1つでメールを送信する際に問題が発生しました。他のページとほぼ同じコードスニペットですが、「送信」しようとするとエラーが発生します。

以下のコード：

Set myMail=CreateObject("CDO.Message")
myMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing")=2

'Name or IP of remote SMTP server
myMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver")="localhost"

'Server port
myMail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport")=25 
myMail.Configuration.Fields.Update

myMail.Subject="Subject"
myMail.From=from_email
myMail.To=email
myMail.TextBody= "Body Text of message"
myMail.Send

スローされるエラーは次のとおりです。エラータイプ：（0x8004020F）このサブスクリプションのイベントクラスは無効なパーティションにあります

助けていただければ幸いです!!!

ありがとう！JFV

4

2 に答える 2

2

CDO を機能させようとして同様の問題が発生しました。この Web サイトで非常に優れた記事を見つけましたCDO.Message で 8004020F エラーが表示されるのはなぜですか?

これが私が最終的に動作するようになったコードです。localhost を SMTP サーバーとして機能させることはできませんでした。メール サーバーの名前を確認し、その名前を使用してください。

<!--METADATA TYPE="typelib" UUID="CD000000-8B95-11D1-82DB-00C04FB1625D" NAME="CDO for Windows 2000 Type Library" -->
<!--METADATA TYPE="typelib" UUID="00000205-0000-0010-8000-00AA006D2EA4" NAME="ADODB Type Library" -->
<%
Set cdoConfig = CreateObject("CDO.Configuration")

With cdoConfig.Fields
        .Item(cdoSendUsingMethod) = cdoSendUsingPort
        .Item(cdoSMTPServer) = "nameofmailservergoeshere"
        .Update
End With


Set cdoMessage = CreateObject("CDO.Message")

With cdoMessage
        Set .Configuration = cdoConfig
        .From = "me@mywebsite.com"
        .To = "you@yourwebsite.com"
        .Subject = "Sample CDO Message"
        .TextBody = "This is a a test message using CDO."
        .Send
End With

Set cdoMessage = Nothing
Set cdoConfig = Nothing
%>
于 2010-06-09T23:48:01.647 に答える
1

これはSMTPサーバーの問題のようです...

http://forums.aspfree.com/asp-development-5/the-event-class-for-this-subscription-is-in-an-invalid-103189.htmlをご覧ください

そしてまた

http://www.powerasp.com/info/4558~General~info.htm

于 2010-06-09T21:36:41.260 に答える