0

こんにちは私のクエリは次のとおりで、その中にサブクエリが含まれています。

ALTER PROCEDURE [dbo].[POBalance] @PONumber NVARCHAR(50) 
AS
BEGIN
    SELECT CASE 
            WHEN X.STATUS = 'False'
                THEN (  SELECT A.Description
                            ,C.qty AS POqty
                            ,B.Qty AS PDQty
                            ,CASE 
                                WHEN A.partialflag = 'false'
                                    THEN '0'
                                ELSE A.qty
                                END AS Balance
                            ,A.Unit
                            ,A.Unitprice
                            ,A.Partialflag
                        FROM tblPOdetails AS A
                        INNER JOIN tblPDdetails AS B ON A.id = B.id
                        INNER JOIN tblpodetailshistory AS C ON A.id = C.id
                        WHERE A.PONo = @PONumber
                        )
            ELSE (  SELECT A.Description
                        ,C.qty AS POqty
                        ,B.Qty AS PDQty
                        ,C.qty AS Balance
                        ,A.Unit
                        ,A.Unitprice
                        ,A.Partialflag
                    FROM tblPOdetails AS A
                    INNER JOIN tblPDdetails AS B ON A.id = B.id
                    INNER JOIN tblpodetailshistory AS C ON A.id = C.id
                    WHERE A.PONo = @PONumber)
            END
    FROM tblPOHeader AS X
    WHERE x.PONo = @PONumber
END

私が得るエラーは次のとおりです。

サブクエリが EXISTS で導入されていない場合、選択リストに指定できる式は 1 つだけです。

私のクエリの何が問題なのですか..私のサブクエリは問題ないようです。

前もって感謝します

4

4 に答える 4

2

節句の場合は表を選択できません。そのようにすることができます（私はそれをテストしませんでした）：

    SELECT A.Description
                                ,C.qty AS POqty
                                ,B.Qty AS PDQty
                                ,CASE 
                                    WHEN A.partialflag = 'false'
                                        THEN '0'
                                    ELSE A.qty
                                    END AS Balance
                                ,A.Unit
                                ,A.Unitprice
                                ,A.Partialflag
                            FROM tblPOdetails AS A
                            INNER JOIN tblPDdetails AS B ON A.id = B.id
                            INNER JOIN tblpodetailshistory AS C ON A.id = C.id
                            INNER JOIN tblPOHeader X ON x.PONo = A.PONo
                            WHERE A.PONo = @PONumber and X.STATUS = 'False'

    UNION ALL

    SELECT A.Description
                            ,C.qty AS POqty
                            ,B.Qty AS PDQty
                            ,C.qty AS Balance
                            ,A.Unit
                            ,A.Unitprice
                            ,A.Partialflag
                            FROM tblPOdetails AS A
                            INNER JOIN tblPDdetails AS B ON A.id = B.id
                            INNER JOIN tblpodetailshistory AS C ON A.id = C.id
                            INNER JOIN tblPOHeader X ON x.PONo = A.PONo
                            WHERE A.PONo = @PONumber and X.STATUS <> 'False'

しかし、私は X.STATUS が少しだと思います - もしそうなら、あなたはそれをちょうどそのようにするべきです:

    SELECT A.Description
                                ,C.qty AS POqty
                                ,B.Qty AS PDQty
                                ,CASE 
                                    WHEN A.partialflag = 'false'
                                        THEN '0'
                                    ELSE A.qty
                                    END AS Balance
                                ,A.Unit
                                ,A.Unitprice
                                ,A.Partialflag
                            FROM tblPOdetails AS A
                            INNER JOIN tblPDdetails AS B ON A.id = B.id
                            INNER JOIN tblpodetailshistory AS C ON A.id = C.id
                            INNER JOIN tblPOHeader X ON x.PONo = A.PONo
                            WHERE A.PONo = @PONumber and X.STATUS = 0

    UNION ALL

    SELECT A.Description
                            ,C.qty AS POqty
                            ,B.Qty AS PDQty
                            ,C.qty AS Balance
                            ,A.Unit
                            ,A.Unitprice
                            ,A.Partialflag
                            FROM tblPOdetails AS A
                            INNER JOIN tblPDdetails AS B ON A.id = B.id
                            INNER JOIN tblpodetailshistory AS C ON A.id = C.id
                            INNER JOIN tblPOHeader X ON x.PONo = A.PONo
                            WHERE A.PONo = @PONumber and X.STATUS <> 0
于 2015-05-20T15:25:27.110 に答える
1

あなたは本当にこれを探していますか？

ALTER PROCEDURE [dbo].[POBalance] @PONumber NVARCHAR(50)
AS
BEGIN
    DECLARE @Status NVARCHAR(MAX)

    SELECT @Status = X.STATUS
    FROM tblPOHeader AS X WHEREx.PONo = @PONumber

    IF @Status = 'False'
    BEGIN
        SELECT A.Description
            ,C.qty AS POqty
            ,B.Qty AS PDQty
            ,CASE 
                WHEN A.partialflag = 'false'
                    THEN '0'
                ELSE A.qty
                END AS Balance
            ,A.Unit
            ,A.Unitprice
            ,A.Partialflag
        FROM tblPOdetails AS A
        INNER JOIN tblPDdetails AS B ON A.id = B.id
        INNER JOIN tblpodetailshistory AS C ON A.id = C.id
        WHERE A.PONo = @PONumber
    END
    ELSE
    BEGIN
        SELECT A.Description
            ,C.qty AS POqty
            ,B.Qty AS PDQty
            ,C.qty AS Balance
            ,A.Unit
            ,A.Unitprice
            ,A.Partialflag
        FROM tblPOdetails AS A
        INNER JOIN tblPDdetails AS B ON A.id = B.id
        INNER JOIN tblpodetailshistory AS C ON A.id = C.id
        WHERE A.PONo = @PONumber
    END
END

このコードは、値を格納してチェックし、値が@Status存在するかどうかに基づいてFalse、クエリの 1 つの結果セットを返します。

于 2015-05-20T15:25:35.660 に答える