9

以下のコードは機能します。しかし、行をコメントアウトして行Dim objRequest As MSXML2.XMLHTTPのコメントを外すDim objRequest As Objectと、エラーメッセージで失敗します:

パラメータが正しくありません

その理由と、(もしあれば) どうすればよいでしょうか?

Public Function GetSessionId(strApiId, strUserName, strPassword) As String

    Dim strPostData As String

    Dim objRequest As MSXML2.XMLHTTP
    'Dim objRequest As Object '

    strPostData = "api_id=" & strApiId & "&user=" & strUserName & "&password=" & strPassword

    Set objRequest = New MSXML2.XMLHTTP
    With objRequest
        .Open "POST", "https://api.clickatell.com/http/auth", False
        .setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
        .send strPostData
        GetSessionId = .responseText
    End With

End Function

Corey さん、はい、MSXML タイプ ライブラリへの参照なしでコードを機能させるには、そうしなければならないことはわかっています。それはここでは問題ではありません。Dim objRequest As Object使用するかどうかに関係なく、使用するとコードが失敗します

Set objRequest = NEW MSXML2.XMLHTTP参照付き、または

Set objRequest = CreateObject("MSXML2.XMLHTTP")参照なしで。

4

3 に答える 3

19

何らかの理由で、これは機能します：

Dim strPostData As String
Dim objRequest As Object

strPostData = "api_id=" & strApiId & "&user=" & strUserName & "&password=" & strPassword

Set objRequest = New MSXML2.XMLHTTP
With objRequest
  .Open "POST", "https://api.clickatell.com/http/auth", False
  .setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
  .send (strPostData)
   GetSessionId = .responseText
End With

strPostData文字列の連結によって URL エンコードされたものを作成する代わりに、URL エンコード関数を使用することを強くお勧めします。

strPostData = "api_id=" & URLEncode(strApiId) & _
              "&user=" & URLEncode(strUserName) & _
              "&password=" & URLEncode(strPassword)

VBAの関数のいくつかの選択肢URLEncode()がこのスレッドにあります: Excel VBA で文字列を URL エンコードするにはどうすればよいですか?

于 2008-11-21T14:24:52.743 に答える
3

Dim objRequest As Object を使用する場合は、次のようにコーディングする必要があります。
Set objRequest = CreateObject("MSXML2.XMLHTTP")

于 2008-11-21T13:54:28.653 に答える
0

これは上記のTomalekのコードとほぼ同じだと思います（すべてあなたのおかげです！）が、この質問は、私が抱えていた問題（ExcelがPHPサーバーに送信し、応答を処理する）の完全な解決策に役立ちました...したがって、これが他の誰かの助けになる場合:

Sub Button1_Click2()

Dim objXMLSendDoc As Object
Set objXMLSendDoc = New MSXML2.DOMDocument
objXMLSendDoc.async = False
Dim myxml As String
myxml = "<?xml version='1.0'?><Request>Do Something</Request>"
If Not objXMLSendDoc.LoadXML(myxml) Then
    Err.Raise objXMLSendDoc.parseError.ErrorCode, , objXMLSendDoc.parseError.reason
End If

Dim objRequest As MSXML2.XMLHTTP
Set objRequest = New MSXML2.XMLHTTP
With objRequest
    .Open "POST", "http://localhost/SISADraftCalcs/Test2.php", False
    .setRequestHeader "Content-Type", "application/xml;charset=UTF-16"
    .setRequestHeader "Cache-Control", "no-cache"
    .send objXMLSendDoc
End With

Dim objXMLDoc As MSXML2.DOMDocument
Set objXMLDoc = objRequest.responseXML
If objXMLDoc.XML = "" Then
    objXMLDoc.LoadXML objRequest.responseText
    If objXMLDoc.parseError.ErrorCode <> 0 Then
        MsgBox objXMLDoc.parseError.reason
    End If
End If

Dim rootNode As IXMLDOMElement
Set rootNode = objXMLDoc.DocumentElement

MsgBox rootNode.SelectNodes("text").Item(0).text

End Sub
于 2010-02-22T16:26:59.423 に答える