0

3 つの入力ボックスと 3 つのラベル (ログイン名、パスワード、およびサーバー ノード) と、スクリプトを実行するためのボタンを備えた単純なウィンドウが必要です。Windows にサード パーティのプログラムをインストールする必要はありません。Cygwinにインストールできれば最高です。

4

2 に答える 2

2

Tcl/Tk と、スターキットとスターパックの概念を見たいと思うかもしれません。後者を使用すると、単一ファイルの Windows 実行可能ファイルを作成できるため、エンド ユーザーはこのプログラム以外のものをインストールする必要がありません。

tk 8.5 を使用すると、ネイティブの Windows ウィジェットの利点も得られるため、GUI は非常にプロフェッショナルに見えます。

コードは次のようになります。

package require Tk 8.5
proc main {} {
    ttk::frame .f
    ttk::label .l1 -text "Username:" -anchor e
    ttk::label .l2 -text "Password:" -anchor e
    ttk::label .l3 -text "Server:" -anchor e
    ttk::entry .e1 -textvariable data(username)
    ttk::entry .e2 -textvariable data(password) -show *
    ttk::entry .e3 -textvariable data(server)
    ttk::button .b1 -text "Submit" -command run

    grid .l1 .e1 -sticky ew -in .f -padx 4
    grid .l2 .e2 -sticky ew -in .f -padx 4
    grid .l3 .e3 -sticky ew -in .f -padx 4
    grid x   .b1 -sticky e -row 4 -in .f -padx 4 -pady 4

    grid rowconfigure .f 3 -weight 1
    grid columnconfigure .f 1 -weight 1

    pack .f -side top -fill both -expand true

    focus .e1
}

proc run {} {
    global data
    puts "username: $data(username)"
    puts "password: $data(password)"
    puts "server: $data(server)"
}

main
于 2008-11-22T20:54:43.297 に答える
1

多くの人が、この種の目的で (cygwin で) TCL/TK を使用していました。

Windows だけの場合、Winforms を使用する .NET 言語は簡単に使用できます (古いボックスがない限り、.NET を配布する必要はありません)。

于 2008-11-22T20:43:12.073 に答える