6

各行の 2 番目の値が日付であるログを解析する Perl スクリプトを作成しようとしています。このスクリプトは、入力ログ ファイル、開始時刻、および終了時刻の 3 つの引数を取ります。開始時間と終了時間は、これら 2 つの時間の間にある各行の特定の値を解析するために使用されます。しかし、これを適切に実行するために、開始時間と終了時間をエポック時間に変換しています。私が抱えている問題は、ループの「i」値を通常の時間に戻してログ ファイルと比較することです。実行後localtime($i)、値を印刷すると、実際の値ではなく参照が印刷されるだけです。

これが私がこれまでに持っているスクリプトです（進行中の作業です）：

#!/usr/bin/perl
use strict;
use warnings;
use Time::Local;
use Time::localtime;
use File::stat;

my $sec = 0;
my $min = 0;
my $hour = 0;
my $mday = 0;
my $mon = 0;
my $year = 0;
my $wday = 0;
my $yday = 0;
my $isdst = 0;

##########################
# Get the engine log date
##########################
my $date = `grep -m 1 'Metric' "$ARGV[0]" | awk '{print \$2}'`;
($year,$mon,$mday) = split('-', $date);
$mon--;

#########################################
# Calculate the start and end epoch time
#########################################
($hour,$min,$sec) = split(':', $ARGV[1]);
my $startTime = timelocal($sec,$min,$hour,$mday,$mon,$year);
($hour,$min,$sec) = split(':', $ARGV[2]);
my $endTime = timelocal($sec,$min,$hour,$mday,$mon,$year);


my $theTime = 0;
for (my $i = $startTime; $i <= $endTime + 29; $i++) {
        #print "$startTime   $i \n";

        $theTime = localtime($i);

        #my $DBInstance0 = `grep "$hour:$min:$sec" "$ARGV[0]"`;# | grep 'DBInstance-0' | awk '{print \$9}'`;
        #print "$DBInstance0\n";
        print "$theTime\n";
}
print "$startTime   $endTime \n";

出力は次のようになります。

Time::tm=ARRAY(0x8cbbd40)
Time::tm=ARRAY(0x8cbc1a0)
Time::tm=ARRAY(0x8cbbe80)
Time::tm=ARRAY(0x8cbc190)
Time::tm=ARRAY(0x8bbb170)
Time::tm=ARRAY(0x8cbc180)
Time::tm=ARRAY(0x8cbbf30)
Time::tm=ARRAY(0x8cbc170)
Time::tm=ARRAY(0x8cbc210)
Time::tm=ARRAY(0x8cbc160)
1275760356   1275760773

コア Perl モジュールにしかアクセスできず、他のモジュールをインストールできません。

4

2 に答える 2

3

ctime「通常時」の定義に応じて、を使用できます。

コード例:

use Time::Local; 
use Time::localtime; 
my $time=timelocal(1,2,3,24,6,2010);
print "$time\n"; 
$theTime = ctime($time); 
print "$theTime\n";

結果：

1279954921
Sat Jul 24 03:02:01 2010

また、 Time::Localtime を使用する必要はありません (これが、Perl の internal から標準の配列/文字列の代わりにTime::tm を取得する理由ですlocaltime):

use Time::Local; 
my $time=timelocal(1,2,3,24,6,2010); 
print "$time\n"; 
$theTime = localtime($time); 
print "$theTime\n";

1279954921
Sat Jul 24 03:02:01 2010
于 2010-06-25T21:10:11.107 に答える
2

年から 1900 を引くことを忘れないでください。

スカラー コンテキストでは、 がフォーマットされた文字列localtimeをgmtime返すことを思い出してくださいctime。したがって、次のように使用できます。それが不適切な場合はstrftime、POSIXモジュールから使用することをお勧めします。

#! /usr/bin/perl

use warnings;
use strict;

use Time::Local;

my $start = "01:02:03";
my $end   = "01:02:05";
my $date  = "2010-02-10";

my($year,$mon,$mday) = split /-/, $date;
$mon--;
$year -= 1900;

my($startTime,$endTime) =
  map { my($hour,$min,$sec) = split /:/;
        timelocal $sec,$min,$hour,$mday,$mon,$year }
  $start, $end;

for (my $i = $startTime; $i <= $endTime + 29; $i++) {
  print scalar localtime($i), "\n";
}

print "$startTime   $endTime \n";

出力の末尾:

水曜日 2 月 10 日 01:02:26 2010
水曜日 2 月 10 日 01:02:27 2010
水曜日 2 月 10 日 01:02:28 2010
水曜日 2 月 10 日 01:02:29 2010
水曜日 2 月 10 日 01:02:30 2010
水曜日 2 月 10 日 01:02:31 2010
水曜日 2 月 10 日 01:02:32 2010
水曜日 2 月 10 日 01:02:33 2010
水曜日 2 月 10 日 01:02:34 2010
1265785323 1265785325
于 2010-06-25T21:11:36.323 に答える