2

この入力 XML を使用します。

<?xml version="1.0" encoding="utf-8"?>
<Employees>
   <Employee ID="1">
      <FirstName>Klaus</FirstName>
      <LastName>Salchner</LastName>
   </Employee>
   <Employee ID="2">
      <FirstName>Peter</FirstName>
      <LastName>Pan</LastName>
   </Employee>
</Employees>

この出力をどのように取得しますか:

<Employees>
    <FirstName>
        <Employee>Klaus</Employee>
        <Employee>Peter</Employee>
    </FirstName>
    <LastName>
        <Employee>Salchner</Employee>
        <Employee>Pan</Employee>
    </LastName>
</Employees>

ただし、Employee 要素に含まれるフィールドの数がわからない場合は、同じ要素 (ここでは FirstName と LastnName) がすべての Employee 要素に確実に存在すると仮定します。

私が持っている最高のものは次のとおりです。

<Employees>
    <xsl:for-each select="*/Employee/.">
        <xsl:value-of select=".">
            <xsl:value-of select="./." />
        </xsl:value-of>
    </xsl:for-each>
</Employees>

そして、私はそれが間違っていることを知っています!

4

3 に答える 3

1

この変換:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kElsByName" match="Employee/*"
  use="name()"/>

 <xsl:template match="/*">
   <Employees>
     <xsl:for-each select=
      "Employee/*[generate-id()
                 =
                  generate-id(key('kElsByName', name())[1])
                  ]">
       <xsl:element name="{name()}">
         <xsl:for-each select="key('kElsByName', name())">
           <Employee>
             <xsl:value-of select="."/>
           </Employee>
         </xsl:for-each>
       </xsl:element>
     </xsl:for-each>
   </Employees>
 </xsl:template>
</xsl:stylesheet>

この XML ドキュメントに適用した場合 (<DOB>汎用にするために追加):

<Employees>
   <Employee ID="1">
      <FirstName>Klaus</FirstName>
      <LastName>Salchner</LastName>
      <DOB>19670823</DOB>
   </Employee>
   <Employee ID="2">
      <FirstName>Peter</FirstName>
      <LastName>Pan</LastName>
      <DOB>19881113</DOB>
   </Employee>
</Employees>

必要な結果を生成します：

<Employees>
   <FirstName>
      <Employee>Klaus</Employee>
      <Employee>Peter</Employee>
   </FirstName>
   <LastName>
      <Employee>Salchner</Employee>
      <Employee>Pan</Employee>
   </LastName>
   <DOB>
      <Employee>19670823</Employee>
      <Employee>19881113</Employee>
   </DOB>
</Employees>

注意してください:

  1. の子である要素のすべての異なる名前を見つけるために、キーを使用し、グループ化に Muenchian メソッドEmployeeを使用します。

  2. 属性に<xsl:element>AVT を使用しnameて、コンパイル時に不明な名前の要素を生成します。

于 2010-07-02T13:07:52.340 に答える
0

ノードを複数回処理する必要がある場合は、テンプレート モードを利用できます。次のようにします。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="Employees">
    <Employees>
      <FirstName>
        <xsl:apply-templates mode="firstname" />
      </FirstName>
      <LastName>
        <xsl:apply-templates mode="lastname" />
      </LastName>
    </Employees>
  </xsl:template>

  <xsl:template match="Employee" mode="firstname">
    <Employee>
      <xsl:value-of select="FirstName"/>
    </Employee>
  </xsl:template>

  <xsl:template match="Employee" mode="lastname">
    <Employee>
      <xsl:value-of select="LastName"/>
    </Employee>
  </xsl:template>

</xsl:stylesheet>
于 2010-07-02T09:35:10.000 に答える
0

さて、私は最終的にそれを解決しました - 基本的に、最初の Employee の要素に対して for-each が必要であり、for-each 内の変数を position() 値に割り当てます。

次に、ネストされた for-each で、外側の Employee 要素をループ処理します。

Employee 要素ごとに、変数 (内部要素の「行」を含む) を使用して、内部要素のインデックスを作成します。

何かのようなもの：

<xsl:for-each select="*/Employee[1]/.">
    <tr>
        <xsl:variable name="row" select="position()" />
        <xsl:for-each select="/*/Employee">
            <td>
                <xsl:value-of select=".[$row]/."/>
            </td>
        </xsl:for-each>
    </tr>
</xsl:for-each>

私は認めますが、私のものはもう少し簡潔ですが、それが要点です。

要するに (深呼吸) 最初の外側の要素の要素のリストをループします。それぞれについて、外側の要素をループし、内側の要素のインデックスを使用して内側の要素を順番に選択します。

于 2010-07-02T10:02:04.957 に答える