6

chromatic の最近のブログで Moose サブルーチンに興味を持ちましたhas。hasMoose のソース コードを調べていたところ、サブルーチン内に$metaから展開された変数があることに気付きました@_。どこ$metaから来たの？Moose と Class::MOP のさまざまなモジュールを調べ始めました。多くのサブルーチンでは、引数として特に渡されていなくても、$metaの最初の引数としてよく見られるようです。@_

has編集:サブルーチンの元のソース コードは次のとおりです。

sub has {
    my $meta = shift;
    my $name = shift;

    Moose->throw_error('Usage: has \'name\' => ( key => value, ... )')
        if @_ % 2 == 1;

    my %options = ( definition_context => Moose::Util::_caller_info(), @_ );
    my $attrs = ( ref($name) eq 'ARRAY' ) ? $name : [ ($name) ];
    $meta->add_attribute( $_, %options ) for @$attrs;
}
4

3 に答える 3

12

あなたが探している特定の魔法はMoose::Exporterにあります。hasこのコードからMoose.pmを介してメソッドを取得します。

Moose::Exporter->setup_import_methods(
    with_meta => [
        qw( extends with has before after around override augment )
    ],
    as_is => [
        qw( super inner ),
        \&Carp::confess,
        \&Scalar::Util::blessed,
    ],
);

--の「with_meta」オプションに注意してくださいsetup_import_methods。渡される最初の引数がメタクラスオブジェクトになるように、これらのメソッドを呼び出し元の名前空間にインポートします。

Mooseを拡張するさまざまなMooseXモジュールは、Moose :: Exporterを使用して、新しいシンボルを呼び出し元の名前空間にインポートします。このプロセスの詳細については、Moose :: Cookbook :: Extended::Recipe1から始まるクックブックを参照してください。

于 2010-07-02T16:07:53.790 に答える
6

パッケージに実際にインポートされるのは、名前付き has() サブルーチンではなく、メタ オブジェクトを挿入するクロージャーです。これがどのように起こるかを正確に見ることができます:

$ perl -we'use Data::Dump::Streamer; use Moose; Dump(\&has)'
my ($extra,$sub,@ex_args);
$extra = sub {
       package Moose::Exporter;
       use warnings;
       use strict 'refs';
       Class::MOP::class_of(shift @_);
     };
$sub = sub {
     package Moose;
     use warnings;
     use strict 'refs';
     my $meta = shift @_;
     my $name = shift @_;
     'Moose'->throw_error(q[Usage: has 'name' => ( key => value, ... )]) if @_ % 2 == 1;
     my(%options) = ('definition_context', Moose::Util::_caller_info(), @_);
     my $attrs = ref $name eq 'ARRAY' ? $name : [$name];
     $meta->add_attribute($_, %options) foreach (@$attrs);
   };
@ex_args = ( 'main' );
$CODE1 = sub {
       package Moose::Exporter;
       use warnings;
       use strict 'refs';
       my(@curry) = &$extra(@ex_args);
       return &$sub(@curry, @_);
     };

$CODE1クロージャーそのものです。上記は、その中で参照される変数です。

于 2010-07-02T18:16:46.200 に答える
2

moleculesys番目の回答のコメント:

has サブルーチンがこのクロージャーにどのように変換されるかはわかりませんが、これはインポートされた has のカリー化された性質を明確に示しています

これが（うまくいけば！）これを達成する方法の簡単な例です（しかし、私Mooseはそれをはるかに複雑でより良い方法で行うと思います！）

メタ.pm

package Meta;

sub new {
    my $class = shift;
    bless { @_ }, $class;
}

sub has {
    my $meta = shift;
    print "Given => @_ \n";
    print "meta $_ => ", $meta->{$_}, "\n" for keys %$meta;
}

1;

インポート.pm

package Import;
use strict;
use warnings;
use Meta;

# some arbitrary meta info!
our $Meta = Meta->new( a => 'A', b => 'B' );

sub import {
    my $caller = caller;

    # import 'has' into caller namespace
    no strict 'refs';
    *{$caller . '::has'} = sub { $Meta->has(@_) };
}

1;

meta_has.pl

use strict;
use warnings;
use Import;

has name => ( is => 'rw', isa => 'Int' );

実行meta_has.plすると、次のようになります。

# Given => name is rw isa Int 
# meta a => A
# meta b => B

それが役立つことを願っています。

/I3az/

于 2010-07-03T09:11:21.520 に答える