arrays - MS Access で配列の null 要素を除外する方法

Question

他のいくつかのフィールドからタイトルを生成していますが、「正しい」方法が必要です。

Me.Title.Value = Join(Array([Conference], [Speaker], partstr), " - ")

[conference]、[speaker]、または partstr のいずれかが null である可能性があることを除いて、余分な「-」は必要ありません。この仕事を簡単にする機能はありますか?

Answer 1

いいえ、それぞれをチェックして、最後にクリーンアップする必要があります

Dim Temp As String

If Not IsNull([Conference]) Then
  Temp = Temp & [Conference] & " - "
End If

If Not IsNull([Speaker]) Then
  Temp = Temp & [Speaker] & " - "
End If

If Not IsNull(partstr) Then
  Temp = Temp & partstr & " - "
End If

If Temp > "" then
  Me.Title.Value = Left(Temp, Len(Temp) - 3)
Else
  Me.Title.Value = Null
End If

ジェネリック関数で改訂：

Public Function JoinEx(ByVal pArray As Variant, ByVal pDelimiter As String) As String

  Dim sTemp As String
  Dim iCtr As Integer

  For iCtr = 0 To UBound(pArray)
    If Not IsNull(pArray(iCtr)) Then
      sTemp = sTemp & pArray(iCtr) & pDelimiter
    End If
  Next

  If sTemp > "" Then
   JoinEx = Left(sTemp, Len(sTemp) - Len(pDelimiter))
  End If

End Function

呼び出し例：

 JoinEx(Array("one","two","three"), " - ")  'Returns "One - Two - Three"
 JoinEx(Array(null,"two","three"), " - ")  'Returns "Two - Three"

Answer 2

完全な書き直し、そして今回は適切にテストされました：

 IIf(IsNull(Partstr), IIf(IsNull(Conference), Speaker, Conference & " - " + Speaker), Conference + " - " & Speaker + " - " & Partstr)