0

カスタムImageCellベースのアイテムレンダラーを使用するタイルリストコンポーネントがあります。取得しようとしている画像の一部が見つからない場合があり、カスタムImageCellローダーのIEOrrorリスナーを介してこれを処理できることを私は知っています。

ただし、データプロバイダーを設定すると、すべての画像の読み込みまたはエラープロセスが完了する前にデータプロバイダーが変更され、フラッシュデバッグプレーヤーがFirefoxで未処理の＃2044エラーをスローし、画像が見つからなかったことを示します。デバッグプレーヤーを使用するオペラでは、ロードが完了しなかったことを示す＃2044がスローされます。

これらのエラーをトラップして無視する方法が見つからないため、デバッガープレーヤーのダイアログが表示されません。また、Flash Builder IDEを使用してデバッグする場合、デバッガーはこれらのエラーをまったく発生させません。他のエラーを問題なく発生させることができる間は、プレーヤー内にのみ存在します。

これは、データプロバイダーが変更されたときにエラーリスナーが破棄されているかのようですが、ローダーは続行し、未処理の＃2044をスローします。

効果的な処理方法に関するアイデアはありますか？あなたの時間と援助を前もって感謝します-

b

4

1 に答える 1

2

カスタムセルレンダラーのコンストラクターで、保護されたローダーインスタンスにイベントリスナーを追加し、IOErrorを処理する必要があります。

次に例を示します。

package
{
    import fl.controls.listClasses.ICellRenderer;
    import fl.controls.listClasses.ImageCell;
    import fl.controls.TileList;
    import fl.data.DataProvider;
    import fl.managers.StyleManager;
    import flash.events.EventDispatcher;
    import flash.events.*;
    import fl.containers.UILoader;

    public class CustomImageCell extends ImageCell implements ICellRenderer
    {  

        public function CustomImageCell() 
        {
            super();

            //do other stuff here

            loader.scaleContent = false;
            loader.addEventListener(IOErrorEvent.IO_ERROR, handleErrorEvent, false, 0, true);

            useHandCursor = true;
        }

        override protected function drawLayout():void
        {
            var imagePadding:Number = getStyleValue("imagePadding") as Number;
            loader.move(11, 5);

            var w:Number = width-(imagePadding*2);
            var h:Number = height-imagePadding*2;
            if (loader.width != w && loader.height != h)
            {
                loader.setSize(w,h);
            }
            loader.drawNow(); // Force validation!

        }
        override protected function handleErrorEvent(event:IOErrorEvent):void {
            trace('ioError: ' + event);
            //dispatchEvent(event);
        }
    }
}

これは、データプロバイダーが更新されたときに何が起こるかを確認するために行った簡単なテストです。

import fl.controls.*;
import fl.data.DataProvider;
import fl.controls.listClasses.CellRenderer;

stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;

var tileList:TileList = new TileList ();
tileList.move(220,40);
tileList.setSize(215, 400);
tileList.columnWidth = 215;
tileList.rowHeight = 86;
tileList.direction = ScrollBarDirection.VERTICAL;
tileList.setStyle("cellRenderer", CustomImageCell);
addChild(tileList);

tileList.dataProvider = getRandomDP(10);
setTimeout(resetDP,3000);

function resetDP():void {
    tileList.dataProvider = getRandomDP(10);
}
function getRandomDP(size:int):DataProvider {
    var result:DataProvider = new DataProvider();
    for(var i:int = 0; i < size; i++)   result.addItem({label:'item'+i,source:'wrong.url/'+Math.random()});
    return result;
}

HTH

于 2010-07-09T20:30:58.293 に答える