4

私は次のように修正された教科書の例を持っています（本はUnderstanding Ada --- Bray and Pokrassによるソフトウェアエンジニアリングアプローチです）：

PACKAGE SOLAR_SYSTEM IS

 TYPE PLANET IS (MERCURY, VENUS, MARS, JUPITER, SATURN, NEPTUNE);

 SUBTYPE TERRESTRIAL_PLANET IS PLANET RANGE MERCURY..MARS;
 SUBTYPE JOVIAN_PLANET IS PLANET RANGE JUPITER..NEPTUNE;

 TYPE MILES IS DIGITS 5 RANGE 0.0..5.0E9;
 TYPE PLANET_FACTS IS ARRAY (PLANET) OF MILES;

 DISTANCE_TO_SUN : CONSTANT PLANET_FACTS :=
  (MERCURY => 36.0E6, VENUS => 67.2E6, MARS => 141.7E6,
  JUPITER => 484.0E6, SATURN => 887.0E6, NEPTUNE => 2797.0E6);

 NUMBER_OF_MOONS: CONSTANT ARRAY (PLANET) OF NATURAL :=
  (MERCURY => 0, VENUS => 0, MARS => 2,
  JUPITER => 12, SATURN => 10, NEPTUNE => 2);

END SOLAR_SYSTEM;

次に、いくつかの変数とその内容にアクセスします。

WITH Ada.Float_Text_IO;
WITH Ada.Text_IO;
WITH Ada.Integer_Text_IO;
WITH SOLAR_SYSTEM;
USE SOLAR_SYSTEM;


PROCEDURE TEST2 IS

BEGIN -- main program
  Ada.Integer_Text_IO.Put(Item => NUMBER_OF_MOONS(Saturn));
  Ada.Text_IO.New_Line;
  Ada.Float_Text_IO.Put(Item => DISTANCE_TO_SUN(Saturn));
END TEST2;

NUMBER_OF_MOONS（土星）には問題なくアクセスできますが、DISTANCE_TO_SUN（土星）にアクセスできません。アクセスする方法は？

どうもありがとう...

これは私がステートメントでコンパイルするものです

Ada.Float_Text_IO.Put(Item => DISTANCE_TO_SUN(Saturn));

リストファイル：

1. WITH Ada.Float_Text_IO;
            |
    >>> warning: no entities of "FLOAT_TEXT_IO" are referenced

 2. WITH Ada.Text_IO;
 3. WITH Ada.Integer_Text_IO;
 4. WITH SOLAR_SYSTEM;
 5. USE SOLAR_SYSTEM;
 6.
 7.
 8. PROCEDURE TEST2 IS
 9.
10.    BEGIN -- main program
11.     Ada.Integer_Text_IO.Put(Item => NUMBER_OF_MOONS(Saturn));
12.     Ada.Text_IO.New_Line;
13.     Ada.Float_Text_IO.Put(Item => DISTANCE_TO_SUN(Saturn));
                         1            5
    >>> no candidate interpretations match the actuals:
    >>> missing argument for parameter "To" in call to "PUT" declared at a-tiflio.ads:81, instance at a-flteio.ads:20
    >>> missing argument for parameter "File" in call to "PUT" declared at a-tiflio.ads:63, instance at a-flteio.ads:20
    >>> possible missing instantiation of Text_IO.Float_IO
    >>> expected type "Standard.Float"
    >>> found type "MILES" defined at solar_system.ads:8
    >>>   ==> in call to "Put" at a-tiflio.ads:70, instance at a-flteio.ads:20

14.    END TEST2;

問題は、DISTANCE_TO_SUN（Saturn）が浮動小数点型の1つであるMILES型であるということです。したがって、Ada.Float_Text_IO.Putを使用するだけでは機能しません。

4

1 に答える 1

4

The problem is that you've declared a brand new type, MILES, which is "float-like", but is not the predefined float type. So when you try to Put an item of that type, i.e. DISTANCE_TO_SUN(Saturn), there's no Put procedure available for that type.

You have three primary choices:

1) Instantiate Float_Text_IO with the Miles type:

 package Miles_IO is new Ada.Text_IO.Float_IO(Solar_System.Miles);

and then use Miles_IO to output the value:

 Miles_IO.Put(DISTANCE_TO_SUN(Saturn));

2) Change the definition of miles to be a constrained subtype of Float:

SUBTYPE MILES IS FlOAT RANGE 0.0..5.0E9;

Then the original Float_Text_IO.Put will work just fine.

3) Since Miles is a floating point type, you can convert it before Putting it:

 Ada.Float_Text_IO.Put(Item => Float(DISTANCE_TO_SUN(Saturn)));
于 2010-07-11T20:14:27.883 に答える