14

私はそのようなEctoモデルを持っています:

defmodule Project.Category do
  use Project.Web, :model

  schema "categories" do
    field :name, :string
    field :list_order, :integer
    field :parent_id, :integer
    belongs_to :menu, Project.Menu
    has_many :subcategories, Project.Category, foreign_key: :parent_id
    timestamps
  end

  @required_fields ~w(name list_order)
  @optional_fields ~w(menu_id parent_id)

  def changeset(model, params \\ :empty) do
    model
    |> cast(params, @required_fields, @optional_fields)
  end
end

ご覧のとおり、Category モデルは subcategories アトムを介して自身を参照できます。

このモデルに関連付けられたビューは次のとおりです。

defmodule Project.CategoryView do
  use Project.Web, :view

  def render("show.json", %{category: category}) do
    json = %{
      id: category.id,
      name: category.name,
      list_order: category.list_order
      parent_id: category.parent_id
    }
    if is_list(category.subcategories) do
      children = render_many(category.subcategories, Project.CategoryView, "show.json")
      Map.put(json, :subcategories, children)
    else
      json
    end
  end
end

サブカテゴリにif条件を設定して、プリロードされていない場合に Poison をうまく使用できるようにしています。

最後に、このビューを呼び出す 2 つのコントローラー関数を次に示します。

defmodule Project.CategoryController do
  use Project.Web, :controller

  alias Project.Category

  def show(conn, %{"id" => id}) do
    category = Repo.get!(Category, id)
    render conn, "show.json", category: category
  end

  def showWithChildren(conn, %{"id" => id}) do
    category = Repo.get!(Category, id)
               |> Repo.preload [:subcategories, subcategories: :subcategories]
    render conn, "show.json", category: category
  end
end

関数は正常にshow動作します：

{
  "parent_id": null,
  "name": "a",
  "list_order": 4,
  "id": 7
}

ただし、showWithChildrenプリロードの使用方法により、関数は 2 レベルのネストに制限されています。

{
  "subcategories": [
    {
      "subcategories": [
        {
          "parent_id": 10,
          "name": "d",
          "list_order": 4,
          "id": 11
        }
      ],
      "parent_id": 7,
      "name": "c",
      "list_order": 4,
      "id": 10
    },
    {
      "subcategories": [],
      "parent_id": 7,
      "name": "b",
      "list_order": 9,
      "id": 13
    }
  ],
  "parent_id": null,
  "name": "a",
  "list_order": 4,
  "id": 7
}

たとえば、上記のカテゴリ アイテム 11 にもサブカテゴリがありますが、それらにアクセスできません。これらのサブカテゴリはサブカテゴリ自体を持つこともできるため、階層の潜在的な深さはnです。

再帰的な魔法が必要であることは承知していますが、関数型プログラミングと Elixir の両方に慣れていないため、頭を悩ませることはできません。どんな助けでも大歓迎です。

4

1 に答える 1

9

ビューでプリロードを行うことを検討できるため、再帰的に機能します。

def render("show.json", %{category: category}) do
  %{id: category.id,
    name: category.name,
    list_order: category.list_order
    parent_id: category.parent_id}
  |> add_subcategories(category)
end

defp add_subcategories(json, %{subcategories: subcategories}) when is_list(subcategories) do
  children =
    subcategories
    |> Repo.preload(:subcategories)
    |> render_many(Project.CategoryView, "show.json")
  Map.put(json, :subcategories, children)
end

defp add_subcategories(json, _category) do
  json
end

これは次の 2 つの理由から理想的ではないことに注意してください。

  1. 理想的には、ビューでクエリを実行したくありません (ただし、これは再帰的であるため、ビューのレンダリングにピギーバックする方が簡単です)。

  2. サブカテゴリの第 2 レベルに対して複数のクエリを発行します。

SQL Antipatternsという本があり、私が間違っていなければ、ツリー構造の書き方について説明しています。あなたの例は、無料の章の 1 つでアンチパターンとして公開されています。これは優れた本であり、すべてのアンチパターンの解決策を探っています。

PS: あなたがしたいshow_with_childrenではありませんshowWithChildren。

于 2015-09-03T21:36:48.760 に答える