2

私はこのようなXMLを持っています：

<assessment>
 <variables>
  <variable>
   <attributes>
    <variable_name value="FRED"/>
   </attributes>
  </variable>
 </variables>
 <variables>
  <variable>
   <attributes>
    <variable_name value="MORTIMER"/>
   </attributes>
  </variable>
 </variables>
 <variables>
  <variable>
   <attributes>
    <variable_name value="FRED"/>
   </attributes>
  </variable>
 </variables>
</assessment>

私はこのXSLTでそれを知っています：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
 <xsl:output method="html"/>

 <xsl:template match="assessment">
  <xsl:for-each select=".//variables/variable/attributes/variable_name">
   <xsl:value-of select="@value"/>
   <br/>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

次のように出力できます。

FRED 
MORTIMER 
FRED

しかし、私が本当に出力したいのはこれです：

FRED: 2 
MORTIMER: 1

つまり、個別の要素と、それぞれが発生する回数をリストしたいと思います。要素を最初に表示された順序で表示したいことに注意してください（これにより、並べ替えを使用する一部のソリューションが除外される可能性があります）。

どうすればよいですか？

4

1 に答える 1

3

この変換：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:key name="kValueByVal" match="variable_name/@value"
  use="."/>

 <xsl:template match="/">
  <xsl:for-each select="
   /*/*/variable/attributes/variable_name/@value
             [generate-id()
             =
              generate-id(key('kValueByVal', .)[1])
             ]
   ">
     <xsl:value-of select=
     "concat(., ' ', count(key('kValueByVal', .)), '&#xA;')"/>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

提供されたXMLドキュメントに適用すると、必要な正しい結果が生成されます。

FRED 2
MORTIMER 1
于 2010-07-14T20:52:28.833 に答える