5

リンク先の「custom_lib」という名前のライブラリがインストールされています。

そのライブラリが特定のオプションでインストールされているかどうかを確認したい。

そのライブラリの options.h ヘッダー ファイルには、次のようなプリプロセッサ マクロのリストがあります。

#undef THIS
#define THIS

#undef THAT
#define THAT

#undef WE_WANT_THIS_ONE
#define WE_WANT_THIS_ONE

別のプロジェクトでは、configure.ac ファイルに次のテストがあります。

 OPTION_FOUND="no"
 AC_CHECK_HEADERS(custom_lib/options.h)                                             
 AC_MSG_CHECKING([is libary configured with --enable-we_want_this_one])

 #AC_EGREP_HEADER([ string to match ],                                            
 #                [ header file ],                                               
 #                [ action if found ],                                           
 #                [ action if not found ])

 AC_EGREP_HEADER([[WE_WANT_THIS_ONE]],                                                      
                 [custom_lib/options.h],                                          
                 [OPTION_FOUND="yes"],                                    
                 [OPTION_FOUND="no"])                                     

 if test "$OPTION_FOUND" = "yes"                                            
 then                                                                            
     # If we have WE_WANT_THIS_ONE check to see which compiler is being used                
     if test "$GCC" = "yes"                                                      
     then                                                                        
         if test "$CC" != "icc"                                                  
         then                                                                    
             #if compiler is not icc then add these flags                        
             CFLAGS="$CFLAGS -maes -msse4"                                       
         fi                                                                      
     fi                                                                          
     AC_MSG_RESULT([yes])                                                        
else                                                                            
     AC_MSG_RESULT([no])                                                         
fi

次に、autreconf を実行して ./configure を実行すると、常に次のメッセージが返されます。

checking custom_lib/options.h usability... yes                                     
checking custom_lib/options.h presence... yes                                      
checking for custom_lib/options.h... yes
checking is library configured with --enable-we_want_this_one... no

私は何か間違ったことをしていますか？autoconf が options.h のプリプロセッサ マクロを検出できるようにするには、configure.ac のテストで何を変更する必要がありますか?

4

1 に答える 1

8

AC_EGREP_HEADERマクロは、テストされたヘッダーのテキストに対して grep を実行しませんが、そのファイルで実行されているプリプロセッサの出力に対して実行します。

autoconfマニュアルから：

— マクロ: AC_EGREP_HEADER (パターン、ヘッダー ファイル、action-if-found、[action-if-not-found])

システム ヘッダー ファイル header-fileでプリプロセッサを実行した結果が拡張正規表現パターンと一致する場合は、シェル コマンド action-if-found を実行し、そうでない場合は action-if-not-found を実行します。

AC_COMPILE_IFELSE代わりにマクロを使用できます。例（テストされていません）：

AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
#include "custom_lib/options.h"
#ifndef WE_WANT_THIS_ONE
# error macro not defined
#endif
]])], [OPTION_FOUND="yes"], [OPTION_FOUND="no"])
于 2015-09-24T08:28:48.570 に答える