scilab - Scilab：contourfの同じカラーマップ

Question

以下のプログラムを実行すると、同じ図になります。同じ色分けが欲しい。

x=-5:0.1:5;
y=-5:0.1:5;
[X,Y]=meshgrid(x,y);
z1=X.^2+Y.^2-25;
z2=X.^2+Y.^2-50;
clf();
f=gcf();
f.color_map=jetcolormap(32);
subplot(1,2,1);
contourf([],[],z1,32);
subplot(1,2,2);
contourf([],[],z2,32);

Answer 1

でそれを行う方法がわかりませんがcontourf、代わりに使用できる場合surfは、提案があります。

surfこれは 3D プロットを生成しますが、回転させて 2D プロットのように見えることに注意してください。また、表面として、実際に使用される範囲に応じて、からに変更してカラー マトリックス (各ファセットの色を定義する) をスケーリングcdata_mappingできるプロパティがあります。scaleddirect

x=-5:0.1:5;
y=-5:0.1:5;
[X,Y]=meshgrid(x,y);
z1=X.^2+Y.^2-25;
z2=X.^2+Y.^2-50;

Zmin=min(min(z1),min(z2));    //Absolut minimum of all data sets
Zmax=max(max(z1),max(z2));    //Absolut maximum of all data sets
nc=100;   //number of colors in colormap

clf();
f=gcf();
f.color_map=jetcolormap(nc);
subplot(1,2,1);
surf(X,Y,z1);
h=gce();
cm=h.data.color;   //color matrix
h.data.color=((cm-Zmin)./(Zmax-Zmin)).*(nc-1)+1;   //scale color matrix & convert to color number
h.cdata_mapping="direct";   //change color mapping from 'scaled' to 'direct'
h.color_mode=-1;  //don't draw mesh
a=gca();
a.view="2d";  //2D view instead of 3D
colorbar(Zmin,Zmax);

subplot(1,2,2);
surf(X,Y,z2);
h=gce();
cm=h.data.color;   //color matrix
h.data.color=((cm-Zmin)./(Zmax-Zmin)).*(nc-1)+1;   //scale color matrix & convert to color number
h.cdata_mapping="direct";   //change color mapping from 'scaled' to 'direct'
h.color_mode=-1;  //don't draw mesh
a=gca();
a.view="2d";  //2D view instead of 3D
colorbar(Zmin,Zmax);

これはあなたにとっての解決策ですか、それともcontourfあらゆる状況で使用する必要がありますか?