17

ActionScript (特に ActionScript 3.0) で 2 つの並べ替えられた配列をマージする良い方法は何ですか? 結果の配列はソートされ、重複がないようにする必要があります。

4

5 に答える 5

25

配列をマージ (連結) するには、 を使用します.concat()。

以下は、配列を連結し、同時に重複を削除する方法の 2 つの例です。

より便利な方法: ( as3corelibArrayUtil.createUniqueCopy()から使用できます)

// from as3corelib:
import com.adobe.utils.ArrayUtil;

var a1:Array = ["a", "b", "c"];
var a2:Array = ["c", "b", "x", "y"];

var c:Array = ArrayUtil.createUniqueCopy(a1.concat(a2)); // result: ["a", "b", "c", "x", "y"]

少し速い方法：（自分で配列をループして、Array.indexOf()重複をチェックするために使用できます）

var a1:Array = ["a", "b", "c"];
var a2:Array = ["c", "b", "x", "y"];
var a3:Array = ["a", "x", "x", "y", "z"];

var c:Array = arrConcatUnique(a1, a2, a3); // result: ["a", "b", "c", "x", "y", "z"]

private function arrConcatUnique(...args):Array
{
    var retArr:Array = new Array();
    for each (var arg:* in args)
    {
        if (arg is Array)
        {
            for each (var value:* in arg)
            {
                if (retArr.indexOf(value) == -1)
                    retArr.push(value);
            }
        }
    }
    return retArr;
}
于 2008-12-03T00:49:39.297 に答える
4

Array.indexOf を使用して重複を検出すると、多数の要素を含むリストがある場合、非常に遅くなります。重複を削除するはるかに迅速な方法は、配列を連結した後に配列の内容をセットにスローすることです。

// Combine the two Arrays.
const combined : Array = a.concat(b);

// Convert them to a Set; this will knock out all duplicates.
const set : Object = {};  // use a Dictionary if combined contains complex types.

const len : uint = combined.length;
for (var i : uint = 0; i < len; i++) {
    set[combined[i]] = true;
}

// Extract all values from the Set to produce the final result.
const result : Array = [];
for (var prop : * in set) {
    result.push[prop];
}

プログラムでコレクションを頻繁に使用する場合は、データを操作するためのシンプルなインターフェイスを提供し、実装に関しては常に最適なアプローチを取る多くの AS3 コレクション フレームワークの 1 つを使用するのが賢明かもしれません。

于 2011-05-21T09:33:18.637 に答える
4

これは、書くのが一種の単純なアルゴリズムです。Actionscript でこれを行うためのより直接的な方法があれば、私は驚くでしょう。

function merge(a1:Array, a2:Array):Array {
    var result:Array = [];
    var i1:int = 0, i2:int = 0;

    while (i1 < a1.length && i2 < a2.length) {
        if (a1[i1] < a2[i2]) {
            result.push(a1[i1]);
            i1++;
        } else if (a2[i2] < a1[i1]) {
            result.push(a2[i2]);
            i2++;
        } else {
            result.push(a1[i1]);
            i1++;
            i2++;
        }
    }

    while (i1 < a1.length) result.push(a1[i1++]);
    while (i2 < a2.length) result.push(a2[i2++]);

    return result;
}
于 2008-12-10T19:25:45.170 に答える
2 
function remDuplicates(_array:Array):void{
    for (var i:int = 0; i < _array.length;++i) {
        var index:int = _array.indexOf(_array[i]);
        if (index != -1 && index != i) {
            _array.splice(i--, 1);
        }
    }
}

次に、「マージ」にはconcatを使用します。例：

var testArray:Array = [1, 1, 1, 5, 4, 5, 5, 4, 7, 2, 3, 3, 6, 5, 8, 5, 4, 2, 4, 5, 1, 2, 3, 65, 5, 5, 5, 5, 8, 4, 7];
var testArray2:Array = [1, 1, 1, 5, 4, 5, 5, 4, 7, 2, 3, 3, 6, 5, 8, 5, 4, 2, 4, 5, 1, 2, 3, 65, 5, 5, 5, 5, 8, 4, 7];

testArray.concat(testArray2);
trace(testArray);
remDuplicates(testArray);
trace(testArray);
于 2010-12-21T13:30:29.363 に答える
0

回答を得るには、次の手順に従ってください。

  1. "Concat" メソッドを使用して 2 つの配列を連結します。
  2. 配列クラスで API として提供される「Sort」メソッドを使用した新しい配列 (連結) ソート
  3. 重複を削除するユーザー定義関数を作成します（以下の関数を参照）
  4. > function removeDuplicates(p_arr:Array):Array { 
     var ansArr:Array = new Array();
 var len:uint = p_arr.length;
 var i:uint = 0;
 var j:uint = 0;
 ansArr[j] = p_arr[i];
 i++;
 j++;
 while(i<len)
 {
    if(ansArr[j] != p_arr[i])
    { 
      ansArr[j] = p_arr[i];
      j++;
    }
    i++;
 }
 return ansArr;

    }

返された "ansArr" は、2 つの配列のマージされた配列を複製せずに並べ替えられます。

于 2011-11-28T05:33:03.717 に答える