1

私は次のことをしようとしています:

bmp := TBitmap.Create;
bmp.Width := FWidth;
bmp.Height := FHeight;
for y := 0 to FHeight - 1 do
begin
   sl := bmp.ScanLine[y];
   for x := 0 to FWidth - 1 do
   begin
      //draw to the scanline, one pixel at a time
   end;
end;
//display the image
bmp.Free;

残念ながら、最終的には、適切に色付けされた最終行を除いて、完全に白い画像になります。ScanLine少しデバッグすると、プロパティにアクセスするたびにが呼び出さTBitmap.FreeImageれ、if (FHandle <> 0) and (FHandle <> FDIBHandle) thenブロックに入り、イメージ全体がリセットされるため、最後の行への変更のみが実際に適用されることがわかります。

を使用してこれまでに見たすべてのデモではTBitmap.ScanLine、画像をロードすることから始めます。(明らかに、これはさまざまなハンドルを正しく設定して、これが起こらないようにしますか?) しかし、私は画像を読み込んで作業しようとしているわけではありません。カメラから画像データをキャプチャしようとしています。

最初にイメージをロードしなくてもスキャンラインに描画できるようにビットマップを設定するにはどうすればよいですか?

4

1 に答える 1

2

PixelFormat描画を開始する前に明示的に設定する必要があります。例えば、

procedure TForm1.FormPaint(Sender: TObject);
var
  bm: TBitmap;
  y: Integer;
  sl: PRGBQuad;
  x: Integer;
begin

  bm := TBitmap.Create;
  try
    bm.SetSize(1024, 1024);
    bm.PixelFormat := pf32bit;
    for y := 0 to bm.Height - 1 do
    begin
      sl := bm.ScanLine[y];
      for x := 0 to bm.Width - 1 do
      begin
        sl.rgbBlue := 255 * x div bm.Width;
        sl.rgbRed := 255 * y div bm.Height;
        sl.rgbGreen := 255 * x div bm.Width;
        inc(sl);
      end;
    end;

    Canvas.Draw(0, 0, bm);
  finally
    bm.Free;
  end;

end;
于 2015-11-06T20:45:04.097 に答える