0

yAxis で TChart を使用すると、0 ～ 100,000 の整数値の範囲のデータがあります。現在のシリーズの範囲が 10,000 ～ 100,000 の場合、チャート上で 10k、50k、90、100k などと読み取れるように TChart のラベルをフォーマットするにはどうすればよいですか。これはモバイル アプリ用なので、これの目的は、携帯電話のスペースを節約してチャート表示を最大化することです。

Delphi Seattle の使用、FMX、iOS/Android 向けの開発

4

1 に答える 1

2

いくつかの可能性があるようですが、GetAxisLabel を使用したアプローチの 1 つを次に示します。私にとって重要なのは、ラベル スタイルを talText に設定することでした。

unit Unit1;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
  FMX.Types, FMX.Controls, FMX.Forms, FMX.Graphics, FMX.Dialogs, FMXTee.Engine,
  FMXTee.Series, FMXTee.Procs, FMXTee.Chart;

type
  TForm1 = class(TForm)
    Chart1: TChart;
    procedure Chart1GetAxisLabel(Sender: TChartAxis; Series: TChartSeries;
      ValueIndex: Integer; var LabelText: string);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    fSeries: TPointSeries;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.fmx}

procedure TForm1.Chart1GetAxisLabel(Sender: TChartAxis; Series: TChartSeries;
  ValueIndex: Integer; var LabelText: string);
begin
  if (fSeries = Series) then
  begin
    LabelText := IntToStr(Round(Series.YValue[ValueIndex] / 1000)) + 'K';
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
var
  i: NativeInt;
begin
  fSeries := TPointSeries.Create(self);
  fSeries.ParentChart := Chart1;
  for i := 1 to 10 do
  begin
    fSeries.Add(i * 10000);
  end;
  Chart1.Axes.Left.LabelStyle := talText;
end;

end.
于 2015-11-16T21:38:28.157 に答える