1

Win32CreateProcess関数を使用して、外部実行可能ファイルへの呼び出しを実行しています。実行可能ファイルは文字列を返します。

実行可能ファイルを呼び出した後、返された文字列をキャプチャして問い合わせる方法はありますか? それができない場合は、実行可能ファイルのファイルに文字列を書き出し、呼び出しが終了した後に呼び出し側プログラムでそれを読み取る必要があるかもしれません。それは不自由に思えますが。

4

4 に答える 4

8

Jediコードライブラリには、プロセスを実行し、入力ファイルと出力ファイルを提供する関数CreateDOSProcessRedirectedが含まれています。必要な入力（存在する場合）を入力ファイルに入れ、プロセス出力（存在する場合）を出力ファイルから読み取ることができます（プロセスが完了した後）。

これがJCLで実装される方法です。

function CreateDOSProcessRedirected(const CommandLine, InputFile, OutputFile: string): Boolean;
var
  StartupInfo: TStartupInfo;
  ProcessInfo: TProcessInformation;
  SecAtrrs: TSecurityAttributes;
  hInputFile, hOutputFile: THandle;
begin
  Result := False;
  hInputFile := CreateFile(PChar(InputFile), GENERIC_READ, FILE_SHARE_READ,
    CreateInheritable(SecAtrrs), OPEN_EXISTING, FILE_ATTRIBUTE_TEMPORARY, 0);
  if hInputFile <> INVALID_HANDLE_VALUE then
  begin
    hOutputFile := CreateFile(PChar(OutPutFile), GENERIC_READ or GENERIC_WRITE,
      FILE_SHARE_READ, CreateInheritable(SecAtrrs), CREATE_ALWAYS,
      FILE_ATTRIBUTE_TEMPORARY, 0);
    if hOutputFile <> INVALID_HANDLE_VALUE then
    begin
      FillChar(StartupInfo, SizeOf(StartupInfo), #0);
      StartupInfo.cb := SizeOf(StartupInfo);
      StartupInfo.dwFlags := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
      StartupInfo.wShowWindow := SW_HIDE;
      StartupInfo.hStdOutput := hOutputFile;
      StartupInfo.hStdInput := hInputFile;
      Result := CreateProcess(nil, PChar(CommandLine), nil, nil, True,
        CREATE_NEW_CONSOLE or NORMAL_PRIORITY_CLASS, nil, nil, StartupInfo,
        ProcessInfo);
      if Result then
      begin
        WaitForSingleObject(ProcessInfo.hProcess, INFINITE);
        CloseHandle(ProcessInfo.hProcess);
        CloseHandle(ProcessInfo.hThread);
      end;
      CloseHandle(hOutputFile);
    end;
    CloseHandle(hInputFile);
  end;
end;
于 2008-12-05T11:54:42.853 に答える
3

exeが標準出力に書き込んでいるものをキャプチャしたいと仮定すると、次のように開始できます

yourprog.exe > results.txt

これにより、出力が に書き込まれresults.txt、それを読み取って評価できます。

または、このスレッドで説明されている方法を試すことができます。生成されたプロセスからの出力用のパイプを作成し、そこから読み取ります。投稿番号 7 には、関連する WinApi 関数を C++ で使用する方法のソース例があり、Delphi に簡単に変換できます。

于 2008-12-05T11:28:38.943 に答える
2

実行可能ファイルはどのように文字列を返しますか? 実行可能ファイルが返すことができると私が知っているのは、単なる数字、つまり終了コードです。

于 2008-12-05T10:53:38.670 に答える
1

共有メモリを使用して、2 つのアプリケーション間で通信できます。

Win32 CreateFileMapping 関数を使用できます。おそらくミューテックスを使用して、メモリ マップされたファイルへの呼び出しを同期します。

次のコードは、ファイルを作成します。

var
  fMapping : THandle;
  pMapData : Pointer;

fMapping := CreateFileMapping($FFFFFFFF, nil, PAGE_READWRITE,
             0, MAPFILESIZE, pchar('MAP NAME GOES HERE'));

PMapData := MapViewOfFile(fMapping, FILE_MAP_ALL_ACCESS, 0, 0, 0);

次のコードはマップファイルを閉じます

if PMapData <> nil then
  UnMapViewOfFile(PMapData);
if fMapping <> 0 then
  CloseHandle(fMapping);
于 2008-12-05T10:56:47.900 に答える