10

32 ビットでは完全に動作する呼び出しがありGetDIBitsますが、64 ビットでは失敗します。ハンドルの値は異なりますが、bitmapinfo構造体の内容は同じです。

これは、エラーを再現するために思いついた最小の (少なくともわずかに構造化された) コード例です。Delphi 10 Seattle Update 1でテストしましたが、他の Delphi バージョンでもエラーが発生するようです。

program Project1;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  Winapi.Windows,
  System.SysUtils,
  Vcl.Graphics;

type
  TRGBALine = array[Word] of TRGBQuad;
  PRGBALine = ^TRGBALine;

type
  { same structure as TBitmapInfo, but adds space for two more entries in bmiColors }
  TMyBitmapInfo = record
    bmiHeader: TBitmapInfoHeader;
    bmiColors: array[0..2] of TRGBQuad;
  public
    constructor Create(AWidth, AHeight: Integer);
  end;

constructor TMyBitmapInfo.Create(AWidth, AHeight: Integer);
begin
  FillChar(bmiHeader, Sizeof(bmiHeader), 0);
  bmiHeader.biSize := SizeOf(bmiHeader);
  bmiHeader.biWidth := AWidth;
  bmiHeader.biHeight := -AHeight;  //Otherwise the image is upside down.
  bmiHeader.biPlanes := 1;
  bmiHeader.biBitCount := 32;
  bmiHeader.biCompression := BI_BITFIELDS;
  bmiHeader.biSizeImage := 4*AWidth*AHeight; // 4 = 32 Bits/Pixel div 8 Bits/Byte
  bmiColors[0].rgbRed := 255;
  bmiColors[1].rgbGreen := 255;
  bmiColors[2].rgbBlue := 255;
end;

procedure Main;
var
  bitmap: TBitmap;
  res: Cardinal;
  Bits: PRGBALine;
  buffer: TMyBitmapInfo;
  BitmapInfo: TBitmapInfo absolute buffer;
  BitsSize: Cardinal;
  icon: TIcon;
  IconInfo: TIconInfo;
begin
  bitmap := TBitmap.Create;
  try
    icon := TIcon.Create;
    try
      icon.LoadFromResourceID(0, Integer(IDI_WINLOGO));
      if not GetIconInfo(icon.Handle, IconInfo) then begin
        Writeln('Error GetIconInfo: ', GetLastError);
        Exit;
      end;
      bitmap.PixelFormat := pf32bit;
      bitmap.Handle := IconInfo.hbmColor;
      BitsSize := BytesPerScanline(bitmap.Width, 32, 32) * bitmap.Height;
      Bits := AllocMem(BitsSize);
      try
        ZeroMemory(Bits, BitsSize);
        buffer := TMyBitmapInfo.Create(bitmap.Width, bitmap.Height);
        res := GetDIBits(bitmap.Canvas.Handle, bitmap.Handle, 0, bitmap.Height, Bits, BitmapInfo, DIB_RGB_COLORS);
        if res = 0 then begin
          Writeln('Error GetDIBits: ', GetLastError);
          Exit;
        end;
        Writeln('Succeed');
      finally
        FreeMem(Bits);
      end;
    finally
      icon.Free;
    end;
  finally
    bitmap.Free;
  end;
end;

begin
  try
    Main;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.
4

1 に答える 1

9

更新この回答へのコメントは、コードが失敗する理由を示しています。bitmap.Handleとの評価の順序がbitmap.Canvas.Handle重要です。パラメータの評価順序が定義されていないため、プログラムの動作は定義されていません。これで、x86 と x64 のプログラムの動作が異なる理由が説明できます。

したがって、ビットマップ ハンドルとデバイス コンテキストを適切な順序でローカル変数に割り当て、これらを引数として に渡すことで、問題を解決できますGetDIBits。TBitmapしかし、以下のコードのように、VCL クラスを避けて GDI 呼び出しを直接使用する方がはるかに優れていると思います。

あなたの間違いは、ビットマップ ハンドルとそのキャンバス ハンドルを渡すことだと思います。代わりに、たとえば、 を呼び出して取得したデバイス コンテキストを渡す必要がありますCreateCompatibleDC(0)。または に渡しIconInfo.hbmColorますGetDIBits。TBitmapただし、 のハンドルとそのキャンバスのハンドルを渡さないでください。

TBitmapまた、あなたが作成した の目的もわかりません。の幅と高さを取得するだけですIconInfo.hbmColor。そのために作成TBitmapする必要はありません。

したがって、私があなただったら、 を削除し、デバイス コンテキストを取得するためにTBitmap使用します。CreateCompatibleDC(0)これにより、コードが大幅に簡素化されます。

への呼び出しによって返されたビットマップも削除する必要がありますがGetIconInfo、これは既に知っているので、簡単にするために質問からそのコードを削除したと思います。

率直に言って、ここでは VCL オブジェクトが邪魔をしているだけです。実際には、GDI 関数を直接呼び出す方がはるかに簡単です。おそらく次のようなものです：

procedure Main;
var
  res: Cardinal;
  Bits: PRGBALine;
  bitmap: Winapi.Windows.TBitmap;
  DC: HDC;
  buffer: TMyBitmapInfo;
  BitmapInfo: TBitmapInfo absolute buffer;
  BitsSize: Cardinal;
  IconInfo: TIconInfo;
begin
  if not GetIconInfo(LoadIcon(0, IDI_WINLOGO), IconInfo) then begin
    Writeln('Error GetIconInfo: ', GetLastError);
    Exit;
  end;
  try
    if GetObject(IconInfo.hbmColor, SizeOf(bitmap), @bitmap) = 0 then begin
      Writeln('Error GetObject');
      Exit;
    end;

    BitsSize := BytesPerScanline(bitmap.bmWidth, 32, 32) * abs(bitmap.bmHeight);
    Bits := AllocMem(BitsSize);
    try
      buffer := TMyBitmapInfo.Create(bitmap.bmWidth, abs(bitmap.bmHeight));
      DC := CreateCompatibleDC(0);
      res := GetDIBits(DC, IconInfo.hbmColor, 0, abs(bitmap.bmHeight), Bits, BitmapInfo,
        DIB_RGB_COLORS);
      DeleteDC(DC);
      if res = 0 then begin
        Writeln('Error GetDIBits: ', GetLastError);
        Exit;
      end;
      Writeln('Succeed');
    finally
      FreeMem(Bits);
    end;
  finally
    DeleteObject(IconInfo.hbmMask);
    DeleteObject(IconInfo.hbmColor);
  end;
end;
于 2015-12-18T15:16:10.457 に答える