3

XMLSlurper（groovy 1.7.4）を使用してXMLを解析しているので、タグを削除する必要があります（空にしないでください！）。これを示すコードサンプルは次のとおりです。

import groovy.xml.StreamingMarkupBuilder

def CAR_RECORDS = '''
    <records>
      <car name='HSV Maloo' make='Holden' year='2006'>
        <country>Australia</country>
        <record type='speed'>Production Pickup Truck with speed of 271kph</record>
      </car>
      <car name='P50' make='Peel' year='1962'>
        <country>Isle of Man</country>
        <record type='size'>Smallest Street-Legal Car at 99cm wide and 59 kg in weight</record>
      </car>
      <car name='Royale' make='Bugatti' year='1931'>
        <country>France</country>
        <record type='price'>Most Valuable Car at $15 million</record>
      </car>
    </records>
  '''

def records = new XmlSlurper().parseText(CAR_RECORDS)
def allRecords = records.car
assert 3 == allRecords.size()

def firstRecord = records.car[0]
assert 'car' == firstRecord.name()
println 'country before: ' + firstRecord.'country'.text()
firstRecord.'country'.replaceNode {}

println 'country after: ' + firstRecord.'country'.text()

このプリント

country before: Australia
country after: Australia

XMLSlurperには、firstRecord.remove（'country'）はありません。

私は本当に困惑しています。これはとても明白なことです...

4

2 に答える 2

7

ただし、replaceNodeを呼び出した後にSlurperからXMLを出力する場合は、次のようになります。

import groovy.xml.XmlUtil

// ... your code here, followed by: ...

println XmlUtil.serialize(new StreamingMarkupBuilder().bind {
  mkp.yield records
} )

国ノードがなくなったようです：

<?xml version="1.0" encoding="UTF-8"?>
<records>
  <car name="HSV Maloo" year="2006" make="Holden">
    <record type="speed">Production Pickup Truck with speed of 271kph</record>
  </car>
  <car name="P50" year="1962" make="Peel">
    <country>Isle of Man</country>
    <record type="size">Smallest Street-Legal Car at 99cm wide and 59 kg in weight</record>
  </car>
  <car name="Royale" year="1931" make="Bugatti">
    <country>France</country>
    <record type="price">Most Valuable Car at $15 million</record>
  </car>
</records>
于 2010-08-09T12:47:44.153 に答える
4

XMLSlurperは、必要になるまで基になるXMLに変更を加えません。XMlSlurperが必要な変更を行い、結果を出力するときに、StreamingMarkupBuilderを使用してシリアル化できます。

于 2011-07-27T06:08:37.237 に答える