70

Gradle - lib ディレクトリ (具体的には lib/enttoolkit.jar および lib/mail.jar) のビルド出力 jar 内に jar を埋め込むにはどうすればよいですか?

4

10 に答える 10

37

プロジェクトのディレクトリ内にすべての jar がある場合 (これを と呼びlibsましょう)、これだけが必要です。

jar {
    into('lib') {
        from 'libs'
    }
}

これらの jar は何らかの依存関係である可能性が高いと思います。次に、次のようにします。

configurations {
    // configuration that holds jars to copy into lib
    extraLibs
}
dependencies {
    extraLibs 'org.something:something-dep1:version'
    extraLibs 'org.something:something-dep2:version'
}

jar {
    into('lib') {
        from configurations.extraLibs
    }
}
于 2012-02-20T10:26:01.573 に答える
36

http://docs.codehaus.org/display/GRADLE/Cookbook#Cookbook-Creatingafatjarから逐語的に削除

Gradle 0.9：

jar {
    from configurations.compile.collect { it.isDirectory() ? it : zipTree(it) }
}

Gradle 0.8：

jar.doFirst {
    for(file in configurations.compile) {
        jar.merge(file)
    }
}

上記のスニペットには、そのプロジェクトのコンパイル依存関係のみが含まれ、推移的な実行時依存関係は含まれません。これらもマージする場合は、configurations.compileをconfigurations.runtimeに置き換えます。

編集：必要なjarファイルのみを選択

新しい構成を作成します。releaseJarsは多分

configurations {
    releaseJars
}

その構成に必要なjarを追加します

dependencies {
    releaseJars group: 'javax.mail', name: 'mail', version: '1.4'
    //etc
}

次に、上記のjarタスクでその構成を使用します。

于 2010-08-10T15:07:18.300 に答える
22

単純：

task copyToLib( type: Copy ) {
    into "$buildDir/libs/lib"
    from configurations.runtime
}

jar { dependsOn copyToLib }

それを実行します：

$ gradle jar
...
$ tree build/libs

build/libs
├── your-project-0.0.1.BUILD-SNAPSHOT.jar
└── lib
    ├── akka-actor-2.0.jar
    ├── akka-camel-2.0.jar
    ├── ... ... ...
    ├── spring-expression-3.1.0.RELEASE.jar
    └── zmq-2.1.9.jar

1 directory, 46 files
于 2012-03-19T15:18:11.567 に答える
8

私も同様のことをする必要があり、Guusとstigkjが提案したものをうまく機能させることができませんでしたが、これを機能させるために彼らの助けを借りて十分に近づきました（Guusの例はdependencies { compile { extendsFrom myLibs }}私のために閉鎖に爆発しました。

apply plugin: 'groovy'

repositories {
    mavenCentral()
}

configurations {
    // custom config of files we want to include in our fat jar that we send to hadoop
    includeInJar
}

dependencies {
    includeInJar 'org.codehaus.groovy:groovy:1.8.6'

    configurations.compile.extendsFrom(configurations.includeInJar)
}

jar {
    into('lib') {
        println "includeInJar: " + configurations.includeInJar.collect { File file -> file }
        from configurations.includeInJar
    }

}

次にgradle jar、作成したjarを実行して調べると、この出力が得られます。これは、jarファイルにgroovyと、「fatjar」内で依存しているすべてのjarが含まれていることを示しています。

%  gradle jar                                                                                                                         
includeInJar: [/Users/tnaleid/.gradle/caches/artifacts-8/filestore/org.codehaus.groovy/groovy/1.8.6/jar/553ca93e0407c94c89b058c482a404427ac7fc72/groovy-1.8.6.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/antlr/antlr/2.7.7/jar/83cd2cd674a217ade95a4bb83a8a14f351f48bd0/antlr-2.7.7.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/asm/asm/3.2/jar/9bc1511dec6adf302991ced13303e4140fdf9ab7/asm-3.2.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/asm/asm-tree/3.2/jar/cd792e29c79d170c5d0bdd05adf5807cf6875c90/asm-tree-3.2.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/asm/asm-commons/3.2/jar/e7a19b8c60589499e35f5d2068d09013030b8891/asm-commons-3.2.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/asm/asm-util/3.2/jar/37ebfdad34d5f1f45109981465f311bbfbe82dcf/asm-util-3.2.jar, /Users/tnaleid/.gradle/caches/artifacts-8/filestore/asm/asm-analysis/3.2/jar/c624956db93975b7197699dcd7de6145ca7cf2c8/asm-analysis-3.2.jar]
:compileJava UP-TO-DATE
:compileGroovy UP-TO-DATE
:processResources UP-TO-DATE
:classes UP-TO-DATE
:jar

BUILD SUCCESSFUL

Total time: 3.387 secs

%  jar tvf build/libs/gradletest.jar                                                                                                  
     0 Mon Mar 12 11:40:00 CDT 2012 META-INF/
    25 Mon Mar 12 11:40:00 CDT 2012 META-INF/MANIFEST.MF
     0 Mon Mar 12 11:40:00 CDT 2012 lib/
5546084 Mon Mar 05 13:13:32 CST 2012 lib/groovy-1.8.6.jar
445288 Mon Mar 05 13:13:38 CST 2012 lib/antlr-2.7.7.jar
 43398 Mon Mar 05 13:13:40 CST 2012 lib/asm-3.2.jar
 21878 Mon Mar 05 13:13:40 CST 2012 lib/asm-tree-3.2.jar
 33094 Mon Mar 05 13:13:40 CST 2012 lib/asm-commons-3.2.jar
 36551 Mon Mar 05 13:13:40 CST 2012 lib/asm-util-3.2.jar
 17985 Mon Mar 05 13:13:40 CST 2012 lib/asm-analysis-3.2.jar
于 2012-03-12T16:42:15.043 に答える
7

以下のコードを試すことができます。jar タスクに依存し、Jar タイプです。

task createJobJar(dependsOn:jar,type:Jar) {
    manifest {
        attributes(
                "Implementation-Title": 'Job '
                ,"Implementation-Version": version
        )
    }
    classifier 'job'
    destinationDir new File("$buildDir")
    into('libs'){
         from configurations.compile
    }
    into('classes'){
        from "$buildDir/classes"
    }
    into('resources'){
        from "$projectDir/src/main/resources"
    }
    into('scripts'){
        from "$projectDir/src/main/scripts"
    }
}

上記のコードは、異なるディレクトリ内に異なるコンテンツをパックします。Gradle 2.2でテスト済み

于 2014-12-18T16:20:12.517 に答える
6

私はあなたが尋ねたのと同じことが必要で、この方法を使用しました。カスタム構成宣言は必要ないかもしれませんが、ローカルで使用される jar ファイルをスーパービルド ファイルで宣言されたものから分離する必要がありました。

configurations{
    //declare custom config if necessary, otherwise just use compile
    myLibs
}
dependencies {
    //add lib/*.jar files to myLibs
    myLibs fileTree(dir: 'lib', include: '*.jar')
    compile {
        //set compile configuration to extend from myLibs
        extendsFrom myLibs
    }
}
// task to copy libs to output/lib dir
task copyToLib(type: Copy) {
    into "$buildDir/output/lib"
    from configurations.myLibs
}

jar {
    //include contents of output dir
    from "$buildDir/output"
    manifest {
        //...
    }
}

//set build task to depend on copyToLib
build.dependsOn(copyToLib)
于 2011-05-24T02:18:46.793 に答える
0

私の場合、ルート プロジェクト Jar の内容をサブプロジェクト Jar に含める必要がありました。したがって、それを機能させるには、次のテンプレートを使用できます。

jar{
  manifest{
    attributes 'Main-Class':'<main class>'
  }
  def conf= configurations.find {it.name.equals('compile') }
  File jar= conf.files.find {it.name.contains('<name or part of the name of produced Jar>')}

  FileTree fileTree=zipTree(jar)
  from fileTree
}

私の例：

jar{
   manifest{
       attributes 'Main-Class':'alexiy.jace.Jace'
   }
   description='Make a runnable API Jar'
   def conf= configurations.find {it.name.equals('compile') }
   File tools= conf.files.find {it.name.contains('Tools')}

   FileTree fileTree=zipTree(tools)
   from fileTree
}
于 2017-04-12T16:10:57.937 に答える