7

簡単な機能はありますか？私はそのようなものを探しています

Play（@data、44000、100 {time}）;

4

5 に答える 5

7

私は PCM オーディオ操作でかなり多くの作業を行ってきました。カスタム波形オーディオ データの短いシーケンスを再生するときは、常にこの関数を使用します。

var
  PlaySoundStopper: PBoolean;
  SoundPlayerActive: boolean = false;

procedure PlaySound(const Sound: TASSound);
var
  hWave: HWAVEOUT;
  hdr: TWaveHdr;
  buf: PAnsiChar;
  fmt: TWaveFormatEx;
  i: Integer;
  n: Integer;
begin

  try

    with fmt do
    begin
      wFormatTag := WAVE_FORMAT_PCM;
      nChannels := length(Sound.Channels);
      nSamplesPerSec := Sound.SampleRate;
      wBitsPerSample := 32;
      nAvgBytesPerSec := nChannels * nSamplesPerSec * wBitsPerSample div 8;
      nBlockAlign := nChannels * wBitsPerSample div 8;
      cbSize := 0;
    end;

    GetMem(buf, fmt.nChannels * length(Sound.Channels[0]) * sizeof(TASWaveformSample));
    if length(Sound.Channels) = 1 then
      CopyMemory(buf, @(Sound.Channels[0, 0]), length(Sound.Channels[0]) * sizeof(TASWaveformSample))
    else
      for i := 0 to high(Sound.Channels[0]) do
        for n := 0 to high(Sound.Channels) do
          CopyMemory(buf + sizeof(TASWaveformSample) * (i * fmt.nChannels + n), @(Sound.Channels[n, i]), sizeof(TASWaveformSample));

    if waveOutOpen(@hWave, WAVE_MAPPER, @fmt, 0, 0, CALLBACK_NULL) <> MMSYSERR_NOERROR then
      raise Exception.Create('SoundPlayerThread.Execute: waveOutOpen failed: ' + SysErrorMessage(GetLastError));

    ZeroMemory(@hdr, sizeof(hdr));
    with hdr do
    begin
      lpData := buf;
      dwBufferLength := fmt.nChannels * length(Sound.Channels[0]) * sizeof(TASWaveformSample);
      dwFlags := 0;
    end;

    try

      SoundPlayerActive := true;

      waveOutPrepareHeader(hWave, @hdr, sizeof(hdr));
      waveOutWrite(hWave, @hdr, sizeof(hdr));
      sleep(500);

      while waveOutUnprepareHeader(hWave, @hdr, sizeof(hdr)) = WAVERR_STILLPLAYING do
        if PlaySoundStopper^ then
        begin
          waveOutPause(hWave);
          waveOutUnprepareHeader(hWave, @hdr, sizeof(hdr));
          break;
        end
        else
          sleep(100);

    finally
      SoundPlayerActive := false;
      waveOutClose(hWave);
      FreeMem(buf);
    end;

  except
    on E: Exception do MessageBox(0, PChar(E.ClassName + ': ' + E.Message), 'Sound Playback Error', MB_ICONERROR);
  end;
end;

どこ

type
  TASWaveformSample = integer; // signed 32-bit; -2147483648..2147483647
  TASWaveformSamples = packed array of TASWaveformSample; // one channel
  PASSound = ^TASSound;
  TASSound = record
    Channels: packed array of TASWaveformSamples;
    SampleRate: cardinal;
  end;

おそらくより良い方法は、再生にスレッドを使用することです。それから私はします

var
  OwnerForm: HWND; // = 0;
  SndSource: PASSound; // = nil;
  ThreadPlaying: boolean; // = false;

type
  TSoundPlayerThread = class(TThread)
  private
    { Private declarations }
  protected
    procedure Execute; override;
  end;

として実装

procedure TSoundPlayerThread.Execute;
var
  hWave: HWAVEOUT;
  hdr: TWaveHdr;
  buf: PAnsiChar;
  fmt: TWaveFormatEx;
  i: Integer;
  n: Integer;
begin

  ThreadPlaying := true;
  try

   try

      if not Assigned(SndSource) then
        Exit;

      with fmt do
      begin
        wFormatTag := WAVE_FORMAT_PCM;
        nChannels := length(SndSource^.Channels);
        nSamplesPerSec := SndSource^.SampleRate;
        wBitsPerSample := 32;
        nAvgBytesPerSec := nChannels * nSamplesPerSec * wBitsPerSample div 8;
        nBlockAlign := nChannels * wBitsPerSample div 8;
        cbSize := 0;
      end;

      GetMem(buf, fmt.nChannels * length(SndSource^.Channels[0]) * sizeof(TASWaveformSample));
      if length(SndSource^.Channels) = 1 then
        CopyMemory(buf, @(SndSource^.Channels[0, 0]), length(SndSource^.Channels[0]) * sizeof(TASWaveformSample))
      else
        for i := 0 to high(SndSource^.Channels[0]) do
          for n := 0 to high(SndSource^.Channels) do
            CopyMemory(buf + sizeof(TASWaveformSample) * (i * fmt.nChannels + n), @(SndSource^.Channels[n, i]), sizeof(TASWaveformSample));

      if waveOutOpen(@hWave, WAVE_MAPPER, @fmt, 0, 0, CALLBACK_NULL) <> MMSYSERR_NOERROR then
        raise Exception.Create('SoundPlayerThread.Execute: waveOutOpen failed: ' + SysErrorMessage(GetLastError));

      ZeroMemory(@hdr, sizeof(hdr));
      with hdr do
      begin
        lpData := buf;
        dwBufferLength := fmt.nChannels * length(SndSource^.Channels[0]) * sizeof(TASWaveformSample);
        dwFlags := 0;
      end;

      waveOutPrepareHeader(hWave, @hdr, sizeof(hdr));
      waveOutWrite(hWave, @hdr, sizeof(hdr));
      sleep(500);

      while waveOutUnprepareHeader(hWave, @hdr, sizeof(hdr)) = WAVERR_STILLPLAYING do
      begin
        sleep(100);
        if Terminated then
          waveOutReset(hWave);
      end;

      waveOutClose(hWave);
      FreeMem(buf);

    except
      on E: Exception do MessageBox(0, PChar(E.ClassName + ': ' + E.Message), 'TSoundPlayerThread', MB_ICONERROR);
    end;

  finally
    ThreadPlaying := false;
  end;
end;
于 2010-08-11T20:51:29.700 に答える
4

Wave Audio Packageには TLiveAudioPlayer コンポーネントがあります。バッファからオーディオを再生します。

于 2010-08-11T09:25:02.873 に答える
3

Win32 API のPlaySoundSND_MEMORY関数は、そのフラグを使用してメモリ ブロックから標準の RIFF エンコード オーディオ (WAV オーディオなど) を再生できます。または、オーディオがアプリのリソースにある場合は、SND_RESOURCE代わりにフラグを使用できます。

于 2010-08-11T20:10:08.300 に答える
2

Microsoftには、MCIを使用してメモリからサウンドを再生する方法を説明するナレッジベースの記事があります。おそらく、配列にWaveファイルヘッダーを含めるか、最初の読み取り時に適切なデータをコピーする必要がありますが、それ以外の場合は、移植がかなり簡単である必要があります。

于 2010-08-11T08:55:02.033 に答える