6

アプリケーション ログに多数の「ORA-00936: 式がありません」というエラーが表示されます。どのステートメントが失敗しているかを Oracle で判断する方法はありますか?

v$sql にクエリを実行しようとしましたが、構文チェックに合格しないため、これらのステートメントはそのビューに挿入されません。

私たちの C# アプリケーションは、Linq を使用して Oracle データベースへのクエリを生成しています。これにより、アプリケーションから sql クエリを取得するのが少し難しくなります。Oracleから簡単に入手できると思っていました。

4

4 に答える 4

7

すべてのエラーをログに記録するトリガーを Oracle で作成できます (またはほとんどすべて - NO_DATA_FOUND はエラーとは見なされません)。以下の例では、スキーマ内のすべてのエラーが TRACK_DETAIL テーブルに記録されます (1 つの行にエラーがあり、次の行に SQL の失敗)。シーケンス番号、日付/時刻などを使用して、より洗練されたものにすることができます。

create table track_detail (val varchar2(4000));

create or replace procedure track (p_text IN VARCHAR2) IS
  PRAGMA AUTONOMOUS_TRANSACTION;
begin
  insert into track_detail(val)
  values (p_text);
  commit;
end;
.
/
create or replace TRIGGER log_err after servererror on schema
DECLARE
  v_temp VARCHAR2(2000) := substr(dbms_utility.format_error_stack,1,2000);
  v_num NUMBER;
  v_sql_text ora_name_list_t;
begin
  v_temp := translate(v_temp,'''','"');
  track(v_temp);
  v_num  := ora_sql_txt(v_sql_text);
  v_temp := null;
  BEGIN
    FOR i IN 1..v_num LOOP
      v_temp := v_temp || v_sql_text(i);
    END LOOP;
  EXCEPTION
    WHEN VALUE_ERROR THEN NULL;
  END;
  v_temp := translate(v_temp,''''||chr(0)||chr(10),'"');
  track(v_temp);
end;
/

終了したら、忘れずにトリガーを削除 (または無効化) してください。

于 2010-08-12T23:27:09.147 に答える
2

何らかの方法でアプリケーション コードから SQL トレースを有効にできる場合 (alter session set sql_trace=true)、データベース ホストのトレース ファイルにステートメントが表示されます。

于 2010-08-12T13:48:36.933 に答える
1

Kris Vandermotten blogの SQL 監視ソリューションを試してください。

また、 DataContext.Log プロパティを使用してログをリダイレクトできます。

using (NorthwindDataContext context = new NorthwindDataContext())
{
  context.Log = Console.Out;
}

または、 LInQ to Entities Visualizerなどの他のデバッグ ツールを使用します。

于 2010-08-12T14:17:37.813 に答える
1

Oracle への接続に使用されるポートで Wireshark などを使用して、送信されている SQL ステートメントを確認できます。最善の答えではないかもしれませんが、必要な場所にすばやく移動できる可能性があります。

于 2010-08-12T13:39:38.950 に答える