perl - PerlでUTF8文字列を数値に変換する

Question

例えば、

my $str = '中國c'; # Chinese language of china

数値を印刷したい

20013,22283,99

Answer 1

unpack一時的な1文字の文字列を大量に作成する必要がないため、splitおよびよりも効率的です。ord

use utf8;

my $str = '中國c'; # Chinese language of china

my @codepoints = unpack 'U*', $str;

print join(',', @codepoints) . "\n"; # prints 20013,22283,99

簡単なベンチマークでは、次の約3倍の速度であることが示されていますsplit+ord。

use utf8;
use Benchmark 'cmpthese';

my $str = '中國中國中國中國中國中國中國中國中國中國中國中國中國中國c';

cmpthese(0, {
  'unpack'     => sub { my @codepoints = unpack 'U*', $str; },
  'split-map'  => sub { my @codepoints = map { ord } split //, $str },
  'split-for'  => sub { my @cp; for my $c (split(//, $str)) { push @cp, ord($c) } },
  'split-for2' => sub { my $cp; for my $c (split(//, $str)) { $cp = ord($c) } },
});

結果：

               Rate  split-map  split-for split-for2     unpack
split-map   85423/s         --        -7%       -32%       -67%
split-for   91950/s         8%         --       -27%       -64%
split-for2 125550/s        47%        37%         --       -51%
unpack     256941/s       201%       179%       105%         --

文字列が短いほど違いは目立たなくなりますが、unpackそれでも2倍以上高速です。（split-for2コードポイントのリストを作成しないため、他の分割よりも少し高速です。）

Answer 2

ソースコード内のutf8がそのように認識されるようにするには、use utf8;事前に次のことを行う必要があります。

$ perl
use utf8;
my $str = '中國c'; # Chinese language of china
foreach my $c (split(//, $str))
{
    print ord($c), "\n";
}
__END__
20013
22283
99

またはもっと簡潔に、

print join ',', map ord, split //, $str;

Answer 3

perldoc -f ord：を参照してください。

foreach my $c (split(//, $str))
{
    print ord($c), "\n";
}

または、1行に圧縮します。my @chars = map { ord } split //, $str;

Data :: Dumper ed、これは以下を生成します：

$VAR1 = [
          20013,
          22283,
          99
        ];

Answer 4

http://www.perl.com/pub/2012/04/perlunicook-standard-preamble.html

#!/usr/bin/env perl


 use utf8;      # so literals and identifiers can be in UTF-8
 use v5.12;     # or later to get "unicode_strings" feature
 use strict;    # quote strings, declare variables
 use warnings;  # on by default
 use warnings  qw(FATAL utf8);    # fatalize encoding glitches
 use open      qw(:std :utf8);    # undeclared streams in UTF-8
 # use charnames qw(:full :short);  # unneeded in v5.16

# http://perldoc.perl.org/functions/sprintf.html
# vector flag
# This flag tells Perl to interpret the supplied string as a vector of integers, one for each character in the string. 

my $str = '中國c';

printf "%*vd\n", ",", $str;